-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCMakeLists.txt
89 lines (78 loc) · 3.7 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
cmake_minimum_required(VERSION 3.15)
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
project(BoardGameAI CXX)
# ========== Enable link time optimization if supported ==========
include(CheckIPOSupported)
check_ipo_supported(RESULT CHECK_IPO_RESULT)
if(CHECK_IPO_RESULT)
message("Link time optimization is enabled")
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
endif()
# ========== Compiler & linker options ==========
# Enable the highest level of warning
set(WARNING_OPTIONS
$<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>: -Wall -Wextra -Wpedantic>
$<$<CXX_COMPILER_ID:MSVC>: /Wall >
)
# Enable code coverage analysis
set(COVERAGE_OPTIONS
$<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>: -coverage -fprofile-abs-path>
)
# Enable profiling
set(PROFILE_OPTIONS
$<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>: -pg>
)
# ========== Third-party libraries ==========
# pthread
find_package(Threads REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES Threads::Threads)
# nlohmann/json
find_package(nlohmann_json CONFIG REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES nlohmann_json nlohmann_json::nlohmann_json)
# pboettch/json-schema-validator
find_package(nlohmann_json_schema_validator REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES nlohmann_json_schema_validator)
# gcem
find_package(gcem CONFIG REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES gcem)
# oneTBB
find_package(TBB CONFIG REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES TBB::tbb)
# ========== Third-party libraries for test ==========
# google/test
find_package(GTest CONFIG REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES_FOR_TEST GTest::gtest GTest::gtest_main)
# ========== Third-party libraries for benchmark ==========
# google/benchmark
find_package(benchmark CONFIG REQUIRED)
list(APPEND THRID_PARTY_LIBRARIES_FOR_BENCHMARK benchmark::benchmark benchmark::benchmark_main)
# ========== Targets ==========
# Main executable
file(GLOB_RECURSE SRC_FILES CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/src/*.cpp)
add_executable(${PROJECT_NAME} ${SRC_FILES})
list(REMOVE_ITEM SRC_FILES ${CMAKE_SOURCE_DIR}/src/Main.cpp)
target_compile_options(${PROJECT_NAME} PRIVATE ${WARNING_OPTIONS})
target_link_libraries(${PROJECT_NAME} PRIVATE ${THRID_PARTY_LIBRARIES})
# Test
file(GLOB_RECURSE TEST_FILES CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/test/*.cpp)
add_executable(${PROJECT_NAME}Test ${SRC_FILES} ${TEST_FILES})
target_compile_options(${PROJECT_NAME}Test PRIVATE ${WARNING_OPTIONS} ${COVERAGE_OPTIONS})
target_link_options(${PROJECT_NAME}Test PRIVATE ${COVERAGE_OPTIONS})
target_link_libraries(${PROJECT_NAME}Test PRIVATE ${THRID_PARTY_LIBRARIES} ${THRID_PARTY_LIBRARIES_FOR_TEST})
# Benchmark
file(GLOB_RECURSE BENCHMARK_FILES CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/benchmark/*.cpp)
add_executable(${PROJECT_NAME}Benchmark ${SRC_FILES} ${BENCHMARK_FILES})
target_compile_options(${PROJECT_NAME}Benchmark PRIVATE ${WARNING_OPTIONS})
target_link_libraries(${PROJECT_NAME}Benchmark PRIVATE ${THRID_PARTY_LIBRARIES} ${THRID_PARTY_LIBRARIES_FOR_BENCHMARK})
# Profile
add_executable(${PROJECT_NAME}Profile ${SRC_FILES} ${BENCHMARK_FILES})
target_compile_options(${PROJECT_NAME}Profile PRIVATE ${WARNING_OPTIONS} ${PROFILE_OPTIONS})
target_link_options(${PROJECT_NAME}Profile PRIVATE ${PROFILE_OPTIONS})
target_link_libraries(${PROJECT_NAME}Profile PRIVATE ${THRID_PARTY_LIBRARIES} ${THRID_PARTY_LIBRARIES_FOR_BENCHMARK})
# ========== Copy files ==========
# schema
set(CUSTOM_COMMAND COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/schema/ ${CMAKE_BINARY_DIR}/schema/)
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD ${CUSTOM_COMMAND})
add_custom_command(TARGET ${PROJECT_NAME}Test POST_BUILD ${CUSTOM_COMMAND})
add_custom_command(TARGET ${PROJECT_NAME}Benchmark POST_BUILD ${CUSTOM_COMMAND})