-
-
Notifications
You must be signed in to change notification settings - Fork 270
/
Copy pathOperations.jl
1800 lines (1666 loc) · 70.2 KB
/
Operations.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# This file is a part of Julia. License is MIT: https://julialang.org/license
module Operations
using UUIDs
using Random: randstring
import LibGit2, Dates, TOML
import REPL
using REPL.TerminalMenus
using ..Types, ..Resolve, ..PlatformEngines, ..GitTools, ..MiniProgressBars
import ..depots, ..depots1, ..devdir, ..set_readonly, ..Types.PackageEntry
import ..Artifacts: ensure_all_artifacts_installed, artifact_names, extract_all_hashes, artifact_exists
using Base.BinaryPlatforms
import ...Pkg
import ...Pkg: pkg_server, RegistryHandling.Registry
import ..Pkg: can_fancyprint
#########
# Utils #
#########
const PkgUUID = "44cfe95a-1eb2-52ea-b672-e2afdf69b78f"
pkg_scratchpath() = joinpath(depots1(), "scratchspaces", PkgUUID)
function find_installed(name::String, uuid::UUID, sha1::SHA1)
slug_default = Base.version_slug(uuid, sha1)
# 4 used to be the default so look there first
for slug in (slug_default, Base.version_slug(uuid, sha1, 4))
for depot in depots()
path = abspath(depot, "packages", name, slug)
ispath(path) && return path
end
end
return abspath(depots1(), "packages", name, slug_default)
end
# more accurate name is `should_be_tracking_registered_version`
# the only way to know for sure is to key into the registries
tracking_registered_version(pkg) =
!is_stdlib(pkg.uuid) && pkg.path === nothing && pkg.repo.source === nothing
function source_path(project_file::String, pkg::PackageSpec)
return is_stdlib(pkg.uuid) ? Types.stdlib_path(pkg.name) :
pkg.path !== nothing ? joinpath(dirname(project_file), pkg.path) :
pkg.repo.source !== nothing ? find_installed(pkg.name, pkg.uuid, pkg.tree_hash) :
pkg.tree_hash !== nothing ? find_installed(pkg.name, pkg.uuid, pkg.tree_hash) :
nothing
end
#TODO rename
function load_version(version, fixed, preserve::PreserveLevel)
if version === nothing
return VersionSpec() # some stdlibs dont have a version
elseif fixed
return version # dont change state if a package is fixed
elseif preserve == PRESERVE_ALL || preserve == PRESERVE_DIRECT
return something(version, VersionSpec())
elseif preserve == PRESERVE_SEMVER && version != VersionSpec()
return Types.semver_spec("$(version.major).$(version.minor).$(version.patch)")
elseif preserve == PRESERVE_NONE
return VersionSpec()
end
end
function load_direct_deps(env::EnvCache, pkgs::Vector{PackageSpec}=PackageSpec[];
preserve::PreserveLevel=PRESERVE_DIRECT)
pkgs = copy(pkgs)
for (name::String, uuid::UUID) in env.project.deps
findfirst(pkg -> pkg.uuid == uuid, pkgs) === nothing || continue # do not duplicate packages
entry = manifest_info(env.manifest, uuid)
push!(pkgs, entry === nothing ?
PackageSpec(;uuid=uuid, name=name) :
PackageSpec(;
uuid = uuid,
name = name,
path = entry.path,
repo = entry.repo,
pinned = entry.pinned,
tree_hash = entry.tree_hash, # TODO should tree_hash be changed too?
version = load_version(entry.version, isfixed(entry), preserve),
))
end
return pkgs
end
function load_manifest_deps(manifest::Manifest, pkgs::Vector{PackageSpec}=PackageSpec[];
preserve::PreserveLevel=PRESERVE_ALL)
pkgs = copy(pkgs)
for (uuid, entry) in manifest
findfirst(pkg -> pkg.uuid == uuid, pkgs) === nothing || continue # do not duplicate packages
push!(pkgs, PackageSpec(
uuid = uuid,
name = entry.name,
path = entry.path,
pinned = entry.pinned,
repo = entry.repo,
tree_hash = entry.tree_hash, # TODO should tree_hash be changed too?
version = load_version(entry.version, isfixed(entry), preserve),
))
end
return pkgs
end
function load_all_deps(env::EnvCache, pkgs::Vector{PackageSpec}=PackageSpec[];
preserve::PreserveLevel=PRESERVE_ALL)
pkgs = load_manifest_deps(env.manifest, pkgs; preserve=preserve)
return load_direct_deps(env, pkgs; preserve=preserve)
end
function is_instantiated(env::EnvCache)::Bool
# Load everything
pkgs = load_all_deps(env)
# Make sure all paths exist
return all(pkg -> is_package_downloaded(env.project_file, pkg), pkgs)
end
function update_manifest!(env::EnvCache, pkgs::Vector{PackageSpec}, deps_map)
manifest_before = deepcopy(env.manifest)
manifest = env.manifest
empty!(manifest)
if env.pkg !== nothing
pkgs = push!(copy(pkgs), env.pkg::PackageSpec)
end
for pkg in pkgs
entry = PackageEntry(;name = pkg.name, version = pkg.version, pinned = pkg.pinned,
tree_hash = pkg.tree_hash, path = pkg.path, repo = pkg.repo)
is_stdlib(pkg.uuid) && (entry.version = nothing) # do not set version for stdlibs
if Types.is_project(env, pkg)
entry.deps = env.project.deps
else
entry.deps = deps_map[pkg.uuid]
end
env.manifest[pkg.uuid] = entry
end
prune_manifest(env)
end
# TODO: Should be included in Base
function signal_name(signal::Integer)
if signal == Base.SIGHUP
"HUP"
elseif signal == Base.SIGINT
"INT"
elseif signal == Base.SIGQUIT
"QUIT"
elseif signal == Base.SIGKILL
"KILL"
elseif signal == Base.SIGPIPE
"PIPE"
elseif signal == Base.SIGTERM
"TERM"
else
string(signal)
end
end
####################
# Registry Loading #
####################
function load_tree_hash!(registries::Vector{Registry}, pkg::PackageSpec)
tracking_registered_version(pkg) || return pkg
hash = nothing
for reg in registries
reg_pkg = get(reg, pkg.uuid, nothing)
reg_pkg === nothing && continue
pkg_info = Pkg.RegistryHandling.registry_info(reg_pkg)
version_info = get(pkg_info.version_info, pkg.version, nothing)
version_info === nothing && continue
hash′ = version_info.git_tree_sha1
if hash !== nothing
hash == hash′ || pkgerror("hash mismatch in registries for $(pkg.name) at version $(pkg.version)")
end
hash = hash′
end
pkg.tree_hash = hash
return pkg
end
#######################################
# Dependency gathering and resolution #
#######################################
function collect_project!(pkg::PackageSpec, path::String,
deps_map::Dict{UUID,Vector{PackageSpec}})
deps_map[pkg.uuid] = PackageSpec[]
project_file = projectfile_path(path; strict=true)
if project_file === nothing
pkgerror("could not find project file for package $(err_rep(pkg)) at `$path`")
end
project = read_package(project_file)
julia_compat = get(project.compat, "julia", nothing)
#=
# TODO, this should either error or be quiet
if julia_compat !== nothing && !(VERSION in Types.semver_spec(julia_compat))
println(io, "julia version requirement for package $(err_rep(pkg)) not satisfied")
end
=#
for (name, uuid) in project.deps
vspec = Types.semver_spec(get(project.compat, name, ">= 0"))
push!(deps_map[pkg.uuid], PackageSpec(name, uuid, vspec))
end
if project.version !== nothing
pkg.version = project.version
else
# @warn("project file for $(pkg.name) is missing a `version` entry")
pkg.version = VersionNumber(0)
end
return
end
is_tracking_path(pkg) = pkg.path !== nothing
is_tracking_repo(pkg) = pkg.repo.source !== nothing
is_tracking_registry(pkg) = !is_tracking_path(pkg) && !is_tracking_repo(pkg)
isfixed(pkg) = !is_tracking_registry(pkg) || pkg.pinned
function collect_developed!(env::EnvCache, pkg::PackageSpec, developed::Vector{PackageSpec})
source = project_rel_path(env, source_path(env.project_file, pkg))
source_env = EnvCache(projectfile_path(source))
pkgs = load_all_deps(source_env)
for pkg in filter(is_tracking_path, pkgs)
if any(x -> x.uuid == pkg.uuid, developed)
continue
end
# normalize path
pkg.path = Types.relative_project_path(env.project_file,
project_rel_path(source_env,
source_path(source_env.project_file, pkg)))
push!(developed, pkg)
collect_developed!(env, pkg, developed)
end
end
function collect_developed(env::EnvCache, pkgs::Vector{PackageSpec})
developed = PackageSpec[]
for pkg in filter(is_tracking_path, pkgs)
collect_developed!(env, pkg, developed)
end
return developed
end
function collect_fixed!(env::EnvCache, pkgs::Vector{PackageSpec}, names::Dict{UUID, String})
deps_map = Dict{UUID,Vector{PackageSpec}}()
if env.pkg !== nothing
pkg = env.pkg
collect_project!(pkg, dirname(env.project_file), deps_map)
names[pkg.uuid] = pkg.name
end
for pkg in pkgs
path = project_rel_path(env, source_path(env.project_file, pkg))
if !isdir(path)
pkgerror("expected package $(err_rep(pkg)) to exist at path `$path`")
end
collect_project!(pkg, path, deps_map)
end
fixed = Dict{UUID,Resolve.Fixed}()
# Collect the dependencies for the fixed packages
for (uuid, deps) in deps_map
q = Dict{UUID, VersionSpec}()
for dep in deps
names[dep.uuid] = dep.name
q[dep.uuid] = dep.version
end
if Types.is_project_uuid(env, uuid)
fix_pkg = env.pkg
else
idx = findfirst(pkg -> pkg.uuid == uuid, pkgs)
fix_pkg = pkgs[idx]
end
fixed[uuid] = Resolve.Fixed(fix_pkg.version, q)
end
return fixed
end
function project_compatibility(env::EnvCache, name::String)
return VersionSpec(Types.semver_spec(get(env.project.compat, name, ">= 0")))
end
# Resolve a set of versions given package version specs
# looks at uuid, version, repo/path,
# sets version to a VersionNumber
# adds any other packages which may be in the dependency graph
# all versioned packges should have a `tree_hash`
function resolve_versions!(env::EnvCache, registries::Vector{Registry}, pkgs::Vector{PackageSpec}, julia_version)
# compatibility
if julia_version !== nothing
v = intersect(julia_version, project_compatibility(env, "julia"))
if isempty(v)
@warn "julia version requirement for project not satisfied" _module=nothing _file=nothing
end
end
names = Dict{UUID, String}(uuid => stdlib for (uuid, stdlib) in stdlibs())
# recursive search for packages which are tracking a path
developed = collect_developed(env, pkgs)
# But we only want to use information for those packages that we don't know about
for pkg in developed
if !any(x -> x.uuid == pkg.uuid, pkgs)
push!(pkgs, pkg)
end
end
# this also sets pkg.version for fixed packages
fixed = collect_fixed!(env, filter(!is_tracking_registry, pkgs), names)
# non fixed packages are `add`ed by version: their version is either restricted or free
# fixed packages are `dev`ed or `add`ed by repo
# at this point, fixed packages have a version and `deps`
@assert length(Set(pkg.uuid::UUID for pkg in pkgs)) == length(pkgs)
# check compat
for pkg in pkgs
compat = project_compatibility(env, pkg.name)
v = intersect(pkg.version, compat)
if isempty(v)
throw(Resolve.ResolverError(
"empty intersection between $(pkg.name)@$(pkg.version) and project compatibility $(compat)"))
end
# Work around not clobbering 0.x.y+ for checked out old type of packages
if !(pkg.version isa VersionNumber)
pkg.version = v
end
end
for pkg in pkgs
names[pkg.uuid] = pkg.name
end
reqs = Resolve.Requires(pkg.uuid => VersionSpec(pkg.version) for pkg in pkgs)
graph, compat_map = deps_graph(env, registries, names, reqs, fixed, julia_version)
Resolve.simplify_graph!(graph)
vers = Resolve.resolve(graph)
# update vector of package versions
for (uuid, ver) in vers
idx = findfirst(p -> p.uuid == uuid, pkgs)
if idx !== nothing
pkg = pkgs[idx]
# Fixed packages are not returned by resolve (they already have their version set)
pkg.version = vers[pkg.uuid]
else
name = is_stdlib(uuid) ? stdlibs()[uuid] : registered_name(registries, uuid)
push!(pkgs, PackageSpec(;name=name, uuid=uuid, version=ver))
end
end
final_deps_map = Dict{UUID, Dict{String, UUID}}()
for pkg in pkgs
load_tree_hash!(registries, pkg)
deps = begin
if pkg.uuid in keys(fixed)
deps_fixed = Dict{String, UUID}()
for dep in keys(fixed[pkg.uuid].requires)
deps_fixed[names[dep]] = dep
end
deps_fixed
else
d = Dict{String, UUID}()
for (uuid, _) in compat_map[pkg.uuid][pkg.version]
d[names[uuid]] = uuid
end
d
end
end
# julia is an implicit dependency
filter!(d -> d.first != "julia", deps)
final_deps_map[pkg.uuid] = deps
end
return final_deps_map
end
get_or_make!(d::Dict{K,V}, k::K) where {K,V} = get!(d, k) do; V() end
const JULIA_UUID = UUID("1222c4b2-2114-5bfd-aeef-88e4692bbb3e")
function deps_graph(env::EnvCache, registries::Vector{Registry}, uuid_to_name::Dict{UUID,String},
reqs::Resolve.Requires, fixed::Dict{UUID,Resolve.Fixed}, julia_version)
uuids = Set{UUID}()
union!(uuids, keys(reqs))
union!(uuids, keys(fixed))
for fixed_uuids in map(fx->keys(fx.requires), values(fixed))
union!(uuids, fixed_uuids)
end
seen = Set{UUID}()
all_versions = Dict{UUID,Set{VersionNumber}}()
# pkg -> version -> (dependency => compat):
all_compat = Dict{UUID,Dict{VersionNumber,Dict{UUID,VersionSpec}}}()
for (fp, fx) in fixed
all_versions[fp] = Set([fx.version])
all_compat[fp] = Dict(fx.version => Dict{UUID,VersionSpec}())
end
while true
unseen = setdiff(uuids, seen)
isempty(unseen) && break
for uuid in unseen
push!(seen, uuid)
uuid in keys(fixed) && continue
all_versions_u = get_or_make!(all_versions, uuid)
all_compat_u = get_or_make!(all_compat, uuid)
# Collect deps + compat for stdlib
if is_stdlib(uuid)
path = Types.stdlib_path(stdlibs()[uuid])
proj_file = projectfile_path(path; strict=true)
@assert proj_file !== nothing
proj = read_package(proj_file)
v = something(proj.version, VERSION)
push!(all_versions_u, v)
# TODO look at compat section for stdlibs?
all_compat_u_vr = get_or_make!(all_compat_u, v)
for (_, other_uuid) in proj.deps
push!(uuids, other_uuid)
all_compat_u_vr[other_uuid] = VersionSpec()
end
else
for reg in registries
pkg = get(reg, uuid, nothing)
pkg === nothing && continue
info = Pkg.RegistryHandling.registry_info(pkg)
for (v, uncompressed_data) in Pkg.RegistryHandling.uncompressed_data(info)
# Filter yanked and if we are in offline mode also downloaded packages
# TODO, pull this into a function
Pkg.RegistryHandling.isyanked(info, v) && continue
if Pkg.OFFLINE_MODE[]
pkg_spec = PackageSpec(name=pkg.name, uuid=pkg.uuid, version=v, tree_hash=Pkg.RegistryHandling.treehash(info, v))
is_package_downloaded(env.project_file, pkg_spec) || continue
end
push!(all_versions_u, v)
all_compat_u[v] = uncompressed_data
union!(uuids, keys(uncompressed_data))
end
end
end
end
end
for uuid in uuids
uuid == JULIA_UUID && continue
if !haskey(uuid_to_name, uuid)
name = registered_name(registries, uuid)
name === nothing && pkgerror("cannot find name corresponding to UUID $(uuid) in a registry")
uuid_to_name[uuid] = name
entry = manifest_info(env.manifest, uuid)
entry ≡ nothing && continue
uuid_to_name[uuid] = entry.name
end
end
return Resolve.Graph(all_versions, all_compat, uuid_to_name, reqs, fixed, false, julia_version),
all_compat
end
function load_urls(registries::Vector{Registry}, pkgs::Vector{PackageSpec})
urls = Dict{UUID,Set{String}}()
for pkg in pkgs
uuid = pkg.uuid
urls[uuid] = Set{String}()
for reg in registries
reg_pkg = get(reg, uuid, nothing)
reg_pkg === nothing && continue
info = Pkg.RegistryHandling.registry_info(reg_pkg)
repo = info.repo
repo === nothing && continue
push!(urls[uuid], repo)
end
end
return urls
end
########################
# Package installation #
########################
function get_archive_url_for_version(url::String, ref)
if (m = match(r"https://github.com/(.*?)/(.*?).git", url)) !== nothing
return "https://api.github.com/repos/$(m.captures[1])/$(m.captures[2])/tarball/$(ref)"
end
return nothing
end
# Returns if archive successfully installed
function install_archive(
urls::Vector{Pair{String,Bool}},
hash::SHA1,
version_path::String
)::Bool
tmp_objects = String[]
url_success = false
for (url, top) in urls
path = tempname() * randstring(6)
push!(tmp_objects, path) # for cleanup
url_success = true
try
PlatformEngines.download(url, path; verbose=false)
catch e
e isa InterruptException && rethrow()
url_success = false
end
url_success || continue
dir = joinpath(tempdir(), randstring(12))
push!(tmp_objects, dir) # for cleanup
# Might fail to extract an archive (Pkg#190)
try
unpack(path, dir; verbose=false)
catch e
e isa InterruptException && rethrow()
@warn "failed to extract archive downloaded from $(url)"
url_success = false
end
url_success || continue
if top
unpacked = dir
else
dirs = readdir(dir)
# 7z on Win might create this spurious file
filter!(x -> x != "pax_global_header", dirs)
@assert length(dirs) == 1
unpacked = joinpath(dir, dirs[1])
end
# Assert that the tarball unpacked to the tree sha we wanted
# TODO: Enable on Windows when tree_hash handles
# executable bits correctly, see JuliaLang/julia #33212.
if !Sys.iswindows()
if SHA1(GitTools.tree_hash(unpacked)) != hash
@warn "tarball content does not match git-tree-sha1"
url_success = false
end
url_success || continue
end
# Move content to version path
!isdir(version_path) && mkpath(version_path)
mv(unpacked, version_path; force=true)
break # successful install
end
# Clean up and exit
foreach(x -> Base.rm(x; force=true, recursive=true), tmp_objects)
return url_success
end
const refspecs = ["+refs/*:refs/remotes/cache/*"]
function install_git(
io::IO,
uuid::UUID,
name::String,
hash::SHA1,
urls::Set{String},
version::Union{VersionNumber,Nothing},
version_path::String
)::Nothing
repo = nothing
tree = nothing
# TODO: Consolodate this with some of the repo handling in Types.jl
try
clones_dir = joinpath(depots1(), "clones")
ispath(clones_dir) || mkpath(clones_dir)
repo_path = joinpath(clones_dir, string(uuid))
repo = GitTools.ensure_clone(io, repo_path, first(urls); isbare=true,
header = "[$uuid] $name from $(first(urls))")
git_hash = LibGit2.GitHash(hash.bytes)
for url in urls
try LibGit2.with(LibGit2.GitObject, repo, git_hash) do g
end
break # object was found, we can stop
catch err
err isa LibGit2.GitError && err.code == LibGit2.Error.ENOTFOUND || rethrow()
end
GitTools.fetch(io, repo, url, refspecs=refspecs)
end
tree = try
LibGit2.GitObject(repo, git_hash)
catch err
err isa LibGit2.GitError && err.code == LibGit2.Error.ENOTFOUND || rethrow()
error("$name: git object $(string(hash)) could not be found")
end
tree isa LibGit2.GitTree ||
error("$name: git object $(string(hash)) should be a tree, not $(typeof(tree))")
mkpath(version_path)
GitTools.checkout_tree_to_path(repo, tree, version_path)
return
finally
repo !== nothing && LibGit2.close(repo)
tree !== nothing && LibGit2.close(tree)
end
end
function download_artifacts(env::EnvCache, pkgs::Vector{PackageSpec}; platform::AbstractPlatform=HostPlatform(),
verbose::Bool=false)
# Filter out packages that have no source_path()
# pkg_roots = String[p for p in source_path.((env.project_file,), pkgs) if p !== nothing] # this runs up against inference limits?
pkg_roots = String[]
for pkg in pkgs
p = source_path(env.project_file, pkg)
p !== nothing && push!(pkg_roots, p)
end
return download_artifacts(pkg_roots; platform=platform, verbose=verbose)
end
function download_artifacts(pkg_roots::Vector{String}; platform::AbstractPlatform=HostPlatform(),
verbose::Bool=false)
# List of Artifacts.toml files that we're going to download from
artifacts_tomls = String[]
for path in pkg_roots
# Check to see if this package has an (Julia)Artifacts.toml
for f in artifact_names
artifacts_toml = joinpath(path, f)
if isfile(artifacts_toml)
push!(artifacts_tomls, artifacts_toml)
break
end
end
end
if !isempty(artifacts_tomls)
for artifacts_toml in artifacts_tomls
ensure_all_artifacts_installed(artifacts_toml; platform=platform, verbose=verbose, quiet_download=!(stderr isa Base.TTY))
write_env_usage(artifacts_toml, "artifact_usage.toml")
end
end
end
function check_artifacts_downloaded(pkg_root::String; platform::AbstractPlatform=HostPlatform())
for f in artifact_names
artifacts_toml = joinpath(pkg_root, f)
if isfile(artifacts_toml)
hashes = extract_all_hashes(artifacts_toml)
if !all(artifact_exists.(hashes))
return false
end
break
end
end
return true
end
# install & update manifest
function download_source(ctx::Context, pkgs::Vector{PackageSpec}; readonly=true)
pkgs = filter(tracking_registered_version, pkgs)
urls = load_urls(ctx.registries, pkgs)
return download_source(ctx, pkgs, urls; readonly=readonly)
end
function download_source(ctx::Context, pkgs::Vector{PackageSpec},
urls::Dict{UUID, Set{String}}; readonly=true)
probe_platform_engines!()
new_pkgs = PackageSpec[]
pkgs_to_install = Tuple{PackageSpec, String}[]
for pkg in pkgs
path = source_path(ctx.env.project_file, pkg)
ispath(path) && continue
push!(pkgs_to_install, (pkg, path))
push!(new_pkgs, pkg)
end
widths = [textwidth(pkg.name) for (pkg, _) in pkgs_to_install]
max_name = maximum(widths; init=0)
########################################
# Install from archives asynchronously #
########################################
missed_packages = Tuple{PackageSpec, String}[]
@sync begin
jobs = Channel{eltype(pkgs_to_install)}(ctx.num_concurrent_downloads)
results = Channel(ctx.num_concurrent_downloads)
@async begin
for pkg in pkgs_to_install
put!(jobs, pkg)
end
end
for i in 1:ctx.num_concurrent_downloads
@async begin
for (pkg, path) in jobs
if ctx.use_libgit2_for_all_downloads
put!(results, (pkg, false, path))
continue
end
try
archive_urls = Pair{String,Bool}[]
if (server = pkg_server()) !== nothing
url = "$server/package/$(pkg.uuid)/$(pkg.tree_hash)"
push!(archive_urls, url => true)
end
for repo_url in urls[pkg.uuid]
url = get_archive_url_for_version(repo_url, pkg.tree_hash)
url !== nothing && push!(archive_urls, url => false)
end
success = install_archive(archive_urls, pkg.tree_hash, path)
if success && readonly
set_readonly(path) # In add mode, files should be read-only
end
if ctx.use_only_tarballs_for_downloads && !success
pkgerror("failed to get tarball from $(urls[pkg.uuid])")
end
put!(results, (pkg, success, path))
catch err
put!(results, (pkg, err, catch_backtrace()))
end
end
end
end
bar = MiniProgressBar(; indent=2, header = "Progress", color = Base.info_color(),
percentage=false, always_reprint=true)
bar.max = length(pkgs_to_install)
fancyprint = can_fancyprint(ctx.io)
try
for i in 1:length(pkgs_to_install)
pkg::PackageSpec, exc_or_success, bt_or_path = take!(results)
exc_or_success isa Exception && pkgerror("Error when installing package $(pkg.name):\n",
sprint(Base.showerror, exc_or_success, bt_or_path))
success, path = exc_or_success, bt_or_path
success || push!(missed_packages, (pkg, path))
bar.current = i
str = sprint(; context=ctx.io) do io
if success
fancyprint && print_progress_bottom(io)
vstr = pkg.version !== nothing ? "v$(pkg.version)" : "[$h]"
printpkgstyle(io, :Installed, string(rpad(pkg.name * " ", max_name + 2, "─"), " ", vstr))
fancyprint && show_progress(io, bar)
end
end
print(ctx.io, str)
end
finally
fancyprint && end_progress(ctx.io, bar)
close(jobs)
end
end
##################################################
# Use LibGit2 to download any remaining packages #
##################################################
for (pkg, path) in missed_packages
uuid = pkg.uuid
install_git(ctx.io, pkg.uuid, pkg.name, pkg.tree_hash, urls[uuid], pkg.version::VersionNumber, path)
readonly && set_readonly(path)
vstr = pkg.version !== nothing ? "v$(pkg.version)" : "[$h]"
printpkgstyle(ctx.io, :Installed, string(rpad(pkg.name * " ", max_name + 2, "─"), " ", vstr))
end
return new_pkgs
end
################################
# Manifest update and pruning #
################################
project_rel_path(env::EnvCache, path::String) = normpath(joinpath(dirname(env.project_file), path))
function prune_manifest(env::EnvCache)
keep = collect(values(env.project.deps))
env.manifest = prune_manifest(env.manifest, keep)
end
function prune_manifest(manifest::Dict, keep::Vector{UUID})
while !isempty(keep)
clean = true
for (uuid, entry) in manifest
uuid in keep || continue
for dep in values(entry.deps)
dep in keep && continue
push!(keep, dep)
clean = false
end
end
clean && break
end
return Dict(uuid => entry for (uuid, entry) in manifest if uuid in keep)
end
function any_package_not_installed(manifest::Manifest)
for (uuid, entry) in manifest
if Base.locate_package(Base.PkgId(uuid, entry.name)) === nothing
return true
end
end
return false
end
#########
# Build #
#########
function _get_deps!(env::EnvCache, pkgs::Vector{PackageSpec}, uuids::Vector{UUID})
for pkg in pkgs
is_stdlib(pkg.uuid) && continue
pkg.uuid in uuids && continue
push!(uuids, pkg.uuid)
if Types.is_project(env, pkg)
pkgs = [PackageSpec(name, uuid) for (name, uuid) in env.project.deps]
else
info = manifest_info(env.manifest, pkg.uuid)
if info === nothing
pkgerror("could not find manifest entry for package $(err_rep(pkg))")
end
pkgs = [PackageSpec(name, uuid) for (name, uuid) in info.deps]
end
_get_deps!(env, pkgs, uuids)
end
return
end
function build(ctx::Context, pkgs::Vector{PackageSpec}, verbose::Bool)
if any_package_not_installed(ctx.env.manifest) || !isfile(ctx.env.manifest_file)
Pkg.instantiate(ctx)
end
uuids = UUID[]
_get_deps!(ctx.env, pkgs, uuids)
build_versions(ctx, uuids; verbose)
end
function dependency_order_uuids(env::EnvCache, uuids::Vector{UUID})::Dict{UUID,Int}
order = Dict{UUID,Int}()
seen = UUID[]
k = 0
function visit(uuid::UUID)
is_stdlib(uuid) && return
uuid in seen &&
return @warn("Dependency graph not a DAG, linearizing anyway")
haskey(order, uuid) && return
push!(seen, uuid)
if Types.is_project_uuid(env, uuid)
deps = values(env.project.deps)
else
entry = manifest_info(env.manifest, uuid)
deps = values(entry.deps)
end
foreach(visit, deps)
pop!(seen)
order[uuid] = k += 1
end
visit(uuid::String) = visit(UUID(uuid))
foreach(visit, uuids)
return order
end
function gen_build_code(build_file::String)
code = """
$(Base.load_path_setup_code(false))
cd($(repr(dirname(build_file))))
include($(repr(build_file)))
"""
return ```
$(Base.julia_cmd()) -O0 --color=no --history-file=no
--startup-file=$(Base.JLOptions().startupfile == 1 ? "yes" : "no")
--compiled-modules=$(Bool(Base.JLOptions().use_compiled_modules) ? "yes" : "no")
--eval $code
```
end
builddir(source_path::String) = joinpath(source_path, "deps")
buildfile(source_path::String) = joinpath(builddir(source_path), "build.jl")
function build_versions(ctx::Context, uuids::Vector{UUID}; verbose=false)
# collect builds for UUIDs with `deps/build.jl` files
builds = Tuple{UUID,String,String,VersionNumber}[]
for uuid in uuids
is_stdlib(uuid) && continue
if Types.is_project_uuid(ctx.env, uuid)
path = dirname(ctx.env.project_file)
name = ctx.env.pkg.name
version = ctx.env.pkg.version
else
entry = manifest_info(ctx.env.manifest, uuid)
if entry === nothing
error("could not find entry with uuid $uuid in manifest $(ctx.env.manifest_file)")
end
name = entry.name
if entry.tree_hash !== nothing
path = find_installed(name, uuid, entry.tree_hash)
elseif entry.path !== nothing
path = project_rel_path(ctx.env, entry.path)
else
pkgerror("Could not find either `git-tree-sha1` or `path` for package $name")
end
version = something(entry.version, v"0.0")
end
ispath(path) || error("Build path for $name does not exist: $path")
ispath(buildfile(path)) && push!(builds, (uuid, name, path, version))
end
# toposort builds by dependencies
order = dependency_order_uuids(ctx.env, map(first, builds))
sort!(builds, by = build -> order[first(build)])
max_name = maximum(build->textwidth(build[2]), builds; init=0)
bar = MiniProgressBar(; indent=2, header = "Progress", color = Base.info_color(),
percentage=false, always_reprint=true)
bar.max = length(builds)
fancyprint = can_fancyprint(ctx.io)
fancyprint && start_progress(ctx.io, bar)
# build each package versions in a child process
try
for (n, (uuid, name, source_path, version)) in enumerate(builds)
pkg = PackageSpec(;uuid=uuid, name=name, version=version)
build_file = buildfile(source_path)
# compatibility shim
build_project_override = isfile(projectfile_path(builddir(source_path))) ?
nothing :
gen_target_project(ctx.env, ctx.registries, pkg, source_path, "build")
# Put log output in Pkg's scratchspace if the package is content adressed
# by tree sha and in the build directory if it is tracked by path etc.
entry = manifest_info(ctx.env.manifest, uuid)
if entry !== nothing && entry.tree_hash !== nothing
key = string(entry.tree_hash)
scratch = joinpath(pkg_scratchpath(), key)
mkpath(scratch)
log_file = joinpath(scratch, "build.log")
# Associate the logfile with the package beeing built
dict = Dict{String,Any}(scratch => [
Dict{String,Any}("time" => Dates.now(), "parent_projects" => [projectfile_path(source_path)])
])
open(joinpath(depots1(), "logs", "scratch_usage.toml"), "a") do io
TOML.print(io, dict)
end
else
log_file = splitext(build_file)[1] * ".log"
end
fancyprint && print_progress_bottom(ctx.io)
printpkgstyle(ctx.io, :Building,
rpad(name * " ", max_name + 1, "─") * "→ " * Types.pathrepr(log_file))
bar.current = n-1
fancyprint && show_progress(ctx.io, bar)
sandbox(ctx, pkg, source_path, builddir(source_path), build_project_override) do
flush(stdout)
ok = open(log_file, "w") do log
std = verbose ? ctx.io : log
success(pipeline(gen_build_code(buildfile(source_path)),
stdout=std, stderr=std))
end
ok && return
n_lines = isinteractive() ? 100 : 5000
# TODO: Extract last n lines more efficiently
log_lines = readlines(log_file)
log_show = join(log_lines[max(1, length(log_lines) - n_lines):end], '\n')
full_log_at, last_lines =
if length(log_lines) > n_lines
"\n\nFull log at $log_file",
", showing the last $n_lines of log"
else
"", ""
end
pkgerror("Error building `$(pkg.name)`$last_lines: \n$log_show$full_log_at")
end
end
finally
fancyprint && end_progress(ctx.io, bar)
end
return
end
##############
# Operations #
##############
function rm(ctx::Context, pkgs::Vector{PackageSpec})
drop = UUID[]
# find manifest-mode drops
for pkg in pkgs
pkg.mode == PKGMODE_MANIFEST || continue
info = manifest_info(ctx.env.manifest, pkg.uuid)
if info !== nothing
pkg.uuid in drop || push!(drop, pkg.uuid)
else
str = has_name(pkg) ? pkg.name : string(pkg.uuid)
@warn("`$str` not in manifest, ignoring")
end
end
# drop reverse dependencies
while !isempty(drop)
clean = true
for (uuid, entry) in ctx.env.manifest
deps = values(entry.deps)
isempty(drop ∩ deps) && continue
uuid ∉ drop || continue
push!(drop, uuid)
clean = false
end
clean && break
end
# find project-mode drops
for pkg in pkgs
pkg.mode == PKGMODE_PROJECT || continue
found = false
for (name::String, uuid::UUID) in ctx.env.project.deps
pkg.name == name || pkg.uuid == uuid || continue
pkg.name == name ||
error("project file name mismatch for `$uuid`: $(pkg.name) ≠ $name")
pkg.uuid == uuid ||
error("project file UUID mismatch for `$name`: $(pkg.uuid) ≠ $uuid")