build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "Forge Maven"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "Gradle Plugins"
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT"
        classpath "com.wynprice.cursemaven:CurseMaven:2.1.0"
    }
}
apply plugin: "net.minecraftforge.gradle.forge"
apply plugin: "com.wynprice.cursemaven"

version = "${version_the}"
group = "thaumicenergistics"
archivesBaseName = "thaumicenergistics"

sourceCompatibility = targetCompatibility = '1.8'
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "${version_mc}-${version_forge}"
    runDir = "run"
    mappings = "stable_39"
}

repositories {
    maven {
        name = "progwml6"
        url = "http://dvs1.progwml6.com/files/maven"
    }
    maven {
        name = "covers1624"
        url = "https://maven.covers1624.net"
    }
    maven {
        name 'CB Maven'
        url "http://chickenbones.net/maven/"
    }
}

dependencies {
    provided "mezz.jei:jei_${version_jei}:api"
    deobfCompile("curse.maven:baubles:${version_ba}")
    deobfCompile("curse.maven:thaumcraft:${version_tc}")
    deobfCompile("appeng:appliedenergistics2:${version_ae2}") {
        transitive = false
    }
    // Testing mods
    runtime "mezz.jei:jei_${version_jei}"
    runtime("curse.maven:thaumic-jei:${version_tjei}") {
        transitive = false
    }
    runtime("cofh:RedstoneFlux:${version_rf}:universal") {
        transitive = false;
    }
    runtime("com.brandon3055.brandonscore:BrandonsCore:${version_bc}:universal") {
        transitive = false
    }
    runtime("curse.maven:codechickenlib:${version_ccl}") {
        transitive = false
    }
    runtime("com.brandon3055.projectintelligence:ProjectIntelligence:${version_pi}:universal") {
        transitive = false
    }
}

jar {
    manifest {
        attributes 'FMLAT': 'theeng_at.cfg'
    }
    from sourceSets.api.output
}

task apiJar(type: Jar) {
    from sourceSets.api.output
    from sourceSets.api.java
    classifier = "api"
}

task deobfJar(type: Jar, dependsOn: 'jar') {
    from "build/sources/main/java"
    from "build/resources/main"
    classifier "dev"
}

task javadocJar(type: Jar, dependsOn: 'javadoc') {
    from "build/docs/javadoc"
    classifier "javadoc"
}

task sourcesJar(type: Jar) {
    from sourceSets.api.java
    from sourceSets.main.java
    classifier = 'sources'
}

sourceSets {
    api
    main
}

artifacts {
    archives apiJar
    archives deobfJar
    archives sourcesJar
    archives javadocJar
}

// TODO: Publish in a maven repo

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }

    rename '(.+_at.cfg)', 'META-INF/$1'
}