build.gradle

buildscript {
	repositories {
		mavenCentral()
		jcenter()
		maven {
			name = "forge"
			url = "http://files.minecraftforge.net/maven"
		}
		maven {
			name = "sonatype"
			url = "https://oss.sonatype.org/content/repositories/snapshots/"
		}
	}
	dependencies {
		classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
		classpath 'me.tatarka:gradle-retrolambda:3.2.0'
	}
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'me.tatarka.retrolambda'
apply plugin: 'maven'

group = "com.unascribed"
archivesBaseName = "BlockRenderer"
version = "1.0.0"

sourceCompatibility = 1.8
targetCompatibility = 1.8

retrolambda {
	javaVersion JavaVersion.VERSION_1_6
	defaultMethods true
}

repositories {
	maven {
		name = 'sonatype-nexus'
		url = 'https://oss.sonatype.org/content/repositories/public/'
	}
}

configurations {
	deploy
	noEclipse
	compile.extendsFrom noEclipse
}

eclipse {
	classpath {
		minusConfigurations += [ configurations.noEclipse ]
	}
}

dependencies {
	deploy 'org.apache.maven.wagon:wagon-ssh:2.10'
}

jar {
	manifest {
		attributes (
			'FMLAT': 'blockrenderer_at.cfg'
		)
	}
}

minecraft {
	version = "1.12-14.21.0.2342"
	mappings = "snapshot_20170621"

	runDir = "eclipse"

	makeObfSourceJar = false
}

processResources {
	// this will ensure that this task is redone when the versions change.
	inputs.property "version", project.version
	inputs.property "mcversion", project.minecraft.version

	// replace stuff in mcmod.info, nothing else
	from(sourceSets.main.resources.srcDirs) {
		include 'mcmod.info'

		// replace version and mcversion
		expand 'version':project.version, 'mcversion':project.minecraft.version
	}

	// copy everything else, thats not the mcmod.info
	from(sourceSets.main.resources.srcDirs) {
		exclude 'mcmod.info'
	}
}