build.gradle

buildscript {
    repositories {
        // These repositories are only for Gradle plugins, put any other repositories in the repository block further below
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://maven.parchmentmc.org' }
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath 'org.spongepowered:mixingradle:0.7-SNAPSHOT'
        classpath group: 'org.parchmentmc', name: 'librarian', version: '1.+'
    }
}

apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'org.parchmentmc.librarian.forgegradle'
apply plugin: 'org.spongepowered.mixin'

apply from: 'gradle/teacon-forge.gradle'

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
}

teacon {
    modId = 'powertool'
    modVersion = '1.2.10'
    modLicense = 'GPL-3.0'
    modGitHubRepo = 'teaconmc/PowerTool'
    modAuthors = ['IzzelAliz']
    modDescription = 'PowerTool by TeaCon'
    platform = 'forge-1.19.4-45.0.64'

    // uncomment these lines if you need
    modName = 'PowerTool' // default to repo name
    // modGitHubBranch = 1.18-forge // for referring the license
    modifyMemberAccess = true // for access transformer
    // useDataGeneration = true // for data generation
    // publishTask = shadowJar // for shadow jar or other usages
    // lazyTokens = ['minecraft_classpath': { project.configurations.shadow.asPath }] // for runtime tokens

    // use './gradlew -q printModMeta > src/main/resources/META-INF/mods.toml' to generate mod meta
}

mixin {
    add sourceSets.main, "powertool.refmap.json"

    config "powertool.mixins.json"
}

repositories {
    maven {
        name = "Curse maven"
        url = "https://cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
}

dependencies {
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'
    implementation fg.deobf("curse.maven:the-one-probe-245211:4442439")
}