Generating test data for 'real-world' APIs.

[cueckoo]

Originally opened by @kalexmills in cuelang/cue#791

As part of taking Cue out for a spin, I implemented a (very) simple script to generate validated test data. I'm having to integrate with the Adyen webhooks API at work and creating and signing their Mock data is (slightly) non-trivial. I was glad to see Cue can handle it. Curious if there are better ways to do this.

It also serves as a test for the crypto/hmac package. ;)

import "crypto/hmac" // added as part of https://github.com/cuelang/cue/issues/788 (not merged)
import "encoding/hex"

#HMACKey: hex.Decode("44782DEF547AAA06C910C43932B1EB0C71FC68D9D0C057550C48EC2ACF6BA056")

#Amount: {
  currency: =~"^[A-Z]{3}$", // 3 character ISO currency code -- could be much more specific
  value: int
}

#NotificationRequest: {
  live: "true" | "false"
  notificationItems: [...#NotificationRequestItem]
}

// YYYY-MM-DDThh:mm:ssTZD
#ISODate: =~"^\\d{4}-\\d{2}-\\d{2}T\\d{2}:\\d{2}:\\d{2}\\+\\d{2}:\\d{2}$"

#NotificationRequestItem: {
  "NotificationRequestItem": {
    additionalData: #AdditionalData & {
      hmacSignature: bytes & hmac.Sign(hmac.SHA256, "\(pspReference):\(originalReference | ''):\(merchantAccountCode):\(merchantReference):\(amount.value):\(amount.currency):\(eventCode):\(success)", #HMACKey)
    }
    amount: #Amount
    pspReference: =~"^.{16}$"
    eventCode: string
    eventDate: #ISODate
    merchantAccountCode: string
    merchantReference: string
    originalReference?: string
    paymentMethod?: string
    operations?: [...string]
    reason?: string
    success: string
  }
}

#AdditionalData: {
  shopperReference?: string
  shopperEmail?: string
  authCode?: string
  cardSummary?: string
  expiryDate?: string
  authorisedAmountValue?: string
  authorisedAmountCurrency?: string
  hmacSignature?: bytes
  ...
}

#NotificationRequest & {
   "live":"false",
   "notificationItems":[
      {
         "NotificationRequestItem":{
            "amount":{
               "value":1130,
               "currency":"EUR"
            },
            "pspReference":"7914073381342284",
            "eventCode":"AUTHORISATION",
            "eventDate": "2019-05-06T17:15:34+02:00",
            "merchantAccountCode":"TestMerchant",
            "operations": [
               "CANCEL",
               "CAPTURE",
               "REFUND",
            ],
            "merchantReference":"TestPayment-1407325143704",
            "paymentMethod":"visa",
            "success":"true"
         }
      }
   ]
}

Output (matches the example provided in the Adyen docs.)

$ cue export .\adyen-notifications.cue 
{
    "live": "false",
    "notificationItems": [
        {
            "NotificationRequestItem": {
                "additionalData": {
                    "hmacSignature": "coqCmt/IZ4E3CzPvMY8zTjQVL5hYJUiBRg8UU+iCWo0="
                },
                "amount": {
                    "value": 1130,
                    "currency": "EUR"
                },
                "pspReference": "7914073381342284",
                "eventCode": "AUTHORISATION",
                "eventDate": "2019-05-06T17:15:34+02:00",
                "merchantAccountCode": "TestMerchant",
                "operations": [
                    "CANCEL",
                    "CAPTURE",
                    "REFUND"
                ],
                "merchantReference": "TestPayment-1407325143704",
                "paymentMethod": "visa",
                "success": "true"
            }
        }
    ]
}

[cueckoo]

Original reply by @mpvl in cuelang/cue#791 (comment)

Looks pretty neat to me!:

Good point, I'll look at the PR. :)