disjunction with default value behind two definitions doesn't work as expected

[uhthomas]

What version of CUE are you using (cue version)?

$ cue version
0.5.0

Also happens when built from HEAD.

Does this issue reproduce with the latest stable release?

Yes.

What did you do?

#Main: {
    name: string
    objects: {
        for v in ["some key"] {
            "\(v)": #Other & { name: name }
        }
    }
}

#Other: {
    name: string | *"unset"
    value: "Hi, \(name)!"
}

out: #Main & { name: "some name" }

https://cuelang.org/play/?id=Sgruw0xqHao#cue@export@json

What did you expect to see?

{
    "out": {
        "name": "some name",
        "objects": {
            "some key": {
                "name": "unset",
                "value": "Hi, some name!"
            }
        }
    }
}

What did you see instead?

{
    "out": {
        "name": "some name",
        "objects": {
            "some key": {
                "name": "unset",
                "value": "Hi, unset!"
            }
        }
    }
}

---

Strangely, this issue is resolved if an alias is used...

#Main: {
    name: string
    objects: {
        for v in ["some key"] {
            let _name = name
            "\(v)": #Other & { name: _name }
        }
    }
}

#Other: {
    name: string | *"unset"
    value: "Hi, \(name)!"
}

out: #Main & { name: "some name" }

https://cuelang.org/play/?id=J3sMaBR5eJ2#cue@export@json

[mvdan]

Smaller repro: https://cuelang.org/play/?id=yFTOsLExm5T#cue@export@json

$ cat f.cue
#D1 & {in: "explicit"}

#D1: {
	in:  string
	out: #D2 & {in: in}
}

#D2: {
	in: string | *"default"
}
$ cue export f.cue
{
    "in": "explicit",
    "out": {
        "in": "default"
    }
}

I would expect out.in to be "explicit", not "default". It starts working if you simplify the definitions a bit, such as making the second definition a string rather than a struct: https://cuelang.org/play/?id=wp1TUDMikIK#cue@export@json

At least this is not a recent regression; I see the same behavior with v0.4.3.

[mvdan]

I completely missed that you were using #Other & {name: name}. Note that the second name refers to the name: field in the same line, not the original one near the top at #Main.name. Similar to Go, you are shadowing the original name declaration with another one.

You can work around this with a let field, for example: https://cuelang.org/play/?id=dibAxjMilmf#cue@export@json

An alternative would be to try to avoid repeating field names in types which will be nested like this, to prevent issues with shadowing.

#466 tracks doing something to warn about this kind of shadowing. It almost never makes sense to declare a field like foo: foo, especially not if the parent scope already has a foo that the user likely meant to reference.

[uhthomas]

I think you're right, thank you for investigating!