build.gradle

import static java.nio.charset.StandardCharsets.UTF_8

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id "ch.ergon.gradle.goodies.versioning" version "1.0.0"
    id 'com.github.jk1.dependency-license-report' version '1.16'
    id 'io.github.gradle-nexus.publish-plugin' version '1.1.0'
}

apply from: "${rootProject.projectDir}/common.gradle"

group 'ch.ergon.adam'

licenseReport {
    allowedLicensesFile = new File("$projectDir/allowed-licenses.json")

    checkLicense {
        outputs.upToDateWhen { false }
    }

    generateLicenseReport {
        outputs.upToDateWhen { false }
    }

}

nexusPublishing {
    repositories {
        sonatype {
            stagingProfileId = project.findProperty('ossrhStagingProfileId')
            username = project.findProperty('ossrhUsername')
            password = project.findProperty('ossrhPassword')
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
        }
    }
}

ext.getLocalProperty = { key, file = "local.properties" ->
    def properties = new Properties()
    def localProperties = new File(rootProject.rootDir, file)
    if (localProperties.isFile()) {
        new InputStreamReader(new FileInputStream(localProperties), UTF_8).with {properties.load(it)}
        return properties.getProperty(key, "")
    } else {
        return null
    }
}