publish.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'

task javadocJar(type: Jar) {
    archiveClassifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

publishing {
    publications {
        release(MavenPublication) {

            from components.java
            artifact sourcesJar
            artifact javadocJar

            pom {
                name = "${project.group}:${project.name}"
                description = project.description
                url = 'https://github.com/ergon/adam'

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }

                developers {
                    developer {
                        id = 'rbuehlma'
                        name = 'René Bühlmann'
                        email = 'rene.buehlmann@ergon.ch'
                        organization = 'Ergon Informatik AG'
                        organizationUrl = 'https://www.ergon.ch'
                    }
                }

                scm {
                    connection = 'scm:git:https://github.com/ergon/adam.git'
                    developerConnection = 'scm:git:git://github.com/ergon/adam.git'
                    url = 'https://github.com/ergon/adam'
                }
            }
        }
    }
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    sign publishing.publications
}