problem with wordcloud svg with fabric js

[nvadgama]

Hi,
Fabric is fabulous product thanks for giving support to us for create such a great t-shirt designer tool.
All SVG is working fine and i can add any SVG on canvas but have an issue with wordcloud svg. when i try to add wordcloud svg by loadSVGFromString then its disturb svg's styles. I have attached a screenshot and also check your demo.

Its only with tag in svg element. Can you please advise ?

SVG code find in .txt file.

test.txt

Thanks
Rajeev

[asturur]

the problem is missing space between rotate and translate transformation.
I mark it as a svgimport bug. if i have time to read the svg spec and be sure the space is optional i will fix this. Chrome open the svg correctly.

IF you add the spaces fabricjs can open it too.

i did not add them all.

[asturur]

space looks mandatory by w3c spec

transform-list:
    wsp* transforms? wsp*
transforms:
    transform
    | transform comma-wsp+ transforms
transform:
    matrix
    | translate
    | scale
    | rotate
    | skewX
    | skewY
matrix:
    "matrix" wsp* "(" wsp*
       number comma-wsp
       number comma-wsp
       number comma-wsp
       number comma-wsp
       number comma-wsp
       number wsp* ")"
translate:
    "translate" wsp* "(" wsp* number ( comma-wsp number )? wsp* ")"
scale:
    "scale" wsp* "(" wsp* number ( comma-wsp number )? wsp* ")"
rotate:
    "rotate" wsp* "(" wsp* number ( comma-wsp number comma-wsp number )? wsp* ")"
skewX:
    "skewX" wsp* "(" wsp* number wsp* ")"
skewY:
    "skewY" wsp* "(" wsp* number wsp* ")"
number:
    sign? integer-constant
    | sign? floating-point-constant
comma-wsp:
    (wsp+ comma? wsp*) | (comma wsp*)
comma:
    ","
integer-constant:
    digit-sequence
floating-point-constant:
    fractional-constant exponent?
    | digit-sequence exponent
fractional-constant:
    digit-sequence? "." digit-sequence
    | digit-sequence "."
exponent:
    ( "e" | "E" ) sign? digit-sequence
sign:
    "+" | "-"
digit-sequence:
    digit
    | digit digit-sequence
digit:
    "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
wsp:
    (#x20 | #x9 | #xD | #xA)

on the other side, adding and asterisk in the regExp solve the problem.
What do you think kangax?