build.gradle

plugins {
	id 'maven-publish'
	alias(libs.plugins.quilt.loom)
	alias(libs.plugins.machete)
}

archivesBaseName = project.archives_base_name
version = System.env.GITHUB_ACTIONS == "true"
	? "${project.version}.github.${System.env.GITHUB_RUN_NUMBER}"
	: project.version
group = project.maven_group

repositories {
	mavenCentral()
	maven { url "https://maven.gegy.dev" }
	maven { url "https://maven.shedaniel.me/" }
	maven { url "https://maven.terraformersmc.com/releases/" }
	maven { url "https://jitpack.io" }
}

// All the dependencies are declared at gradle/libs.version.toml and referenced with "libs.<id>"
// See https://docs.gradle.org/current/userguide/platforms.html for information on how version catalogs work.
dependencies {
	// To change the versions, see the gradle.properties file
	minecraft libs.minecraft
	mappings loom.layered {
		addLayer quiltMappings.mappings("org.quiltmc:quilt-mappings:${libs.versions.quilt.mappings.get()}:v2")
	}
	modImplementation libs.quilt.loader

	modImplementation libs.quilted.fabric.api
	modImplementation(libs.mod.menu) {
		transitive = false
	}
	modImplementation(libs.libzoomer) {
		transitive = false
	}
	modImplementation(libs.spruceui) {
		transitive = false
	}
	implementation libs.mixin.extras
	annotationProcessor libs.mixin.extras

	include libs.libzoomer
	include libs.spruceui
	include libs.mixin.extras
}

processResources {
	inputs.property "version", version

	// Oh, for building, do the switcharoo
	filesMatching('quilt.mod.json') {
		expand "version": version
	}

	filesMatching('fabric.mod.json') {
		expand "version": version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Still required by IDEs such as Eclipse and Visual Studio Code
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17

	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	// If this mod is going to be a library, then it should also generate Javadocs in order to aid with developement.
	// Uncomment this line to generate them.
	// withJavadocJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${archivesBaseName}" }
	}
}

machete {
	// JSON minification isn't effective on this scale and sacrifices readability
	optimizations.json = false
}

// Configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}