build.gradle

group = "com.github.kratorius.jelf"

def javaVersion = JavaVersion.VERSION_1_8

task wrapper(type: Wrapper) {
    gradleVersion = '2.3'
}

apply plugin: 'idea'
apply plugin: 'java'
apply plugin: 'application'


compileJava {
    options.encoding = 'UTF-8'
    options.compilerArgs << '-XDignore.symbol.file'
    options.fork = true
    options.forkOptions.executable = 'javac'

    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
}

repositories {
    mavenCentral()
    mavenLocal()
}

sourceSets {
    perf
}

dependencies {
    compile 'com.google.code.findbugs:jsr305:3.0.0'
    testCompile 'junit:junit:4.11'

    perfCompile project
    perfCompile 'org.openjdk.jmh:jmh-core:1.8'
    perfCompile 'org.openjdk.jmh:jmh-generator-annprocess:1.8'
}

idea {
    module {
        scopes.PROVIDED.plus  += [ configurations.perfCompile ]
    }
}

task perf(type: JavaExec, dependsOn: [classes, perfClasses]) {
    description 'Execute the benchmark timing of this project'
    maxHeapSize '2g'
    main 'org.openjdk.jmh.Main'
    if (project.hasProperty('args')) {
        args project.args.split('\\s+')
    }
    classpath = sourceSets.perf.runtimeClasspath
}