build.gradle

group = 'com.kotcrab.remark'
version = '1.2.1-SNAPSHOT'

buildscript {
    repositories {
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3"
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.3"
        classpath "biz.aQute.bnd:biz.aQute.bnd.gradle:5.1.2"
    }
}

repositories {
    mavenCentral()
    maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
    maven { url "https://oss.sonatype.org/content/repositories/releases/" }
}

apply plugin: 'io.codearte.nexus-staging'
apply plugin: "eclipse"
apply plugin: "idea"
apply plugin: "java"
apply plugin: 'maven'
apply plugin: "nebula.optional-base"
apply plugin: "biz.aQute.bnd.builder"
apply from: 'deploy.gradle'

archivesBaseName = "remark"
sourceCompatibility = 1.6
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

ext {
    appName = 'remark'
}

eclipse.project {
    name = appName
}

uploadArchives {
    repositories {
        mavenDeployer {
            pom.project {
                name 'remark'
                artifactId 'remark'
                packaging 'jar'
                description 'Remark is a library for taking (X)HTML input and outputting clean Markdown, Markdown Extra, or MultiMarkdown compatible text.'
            }
        }
    }
}

dependencies {
    compile "org.jsoup:jsoup:1.9.2"
    compile "org.apache.commons:commons-lang3:3.4"
    compile "commons-cli:commons-cli:1.2", optional
    testCompile "commons-io:commons-io:2.4"
    testCompile group: 'junit', name: 'junit', version: '4.11'
}

nexusStaging {
    packageGroup = "com.kotcrab"
    username = ossrhUsername
    password = ossrhPassword
}

tasks.eclipse.doLast {
    delete ".project"
}