deploy.gradle

apply plugin: 'maven'
apply plugin: 'signing'

ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

javadoc {
    def generateJavadoc = project.hasProperty("generateJavadoc");
    onlyIf { (isReleaseVersion || gradle.taskGraph.hasTask("uploadArchives")) || generateJavadoc }

    options.encoding = 'UTF-8'
    options.addStringOption('Xdoclint:none', '-quiet')
}

signing {
    required { isReleaseVersion || gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                url 'https://github.com/kotcrab/remark-java/'

                scm {
                    connection 'scm:git:git@github.com:kotcrab/remark-java.git'
                    developerConnection 'scm:git:git@github.com:kotcrab/remark-java.git'
                    url 'git@github.com:kotcrab/remark-java.git'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
				    developer {
                        name 'Phil DeJarnett'
                        url 'http://www.overzealous.com'
                    }
					developer {
                        name 'Guilherme I F L Weizenmann'
                        url 'http://itquasar.com'
                    }
                    developer {
                        id 'kotcrab'
                        name 'Pawel Pastuszak'
                        url 'https://kotcrab.com'
                    }
                }
            }
        }
    }
}