build.gradle

plugins {
  id 'com.github.johnrengelman.shadow' version '1.2.4'
  id 'com.github.maiflai.scalatest' version '0.14'
  id 'org.unbroken-dome.test-sets' version '1.3.2'
}

allprojects {
  apply plugin: 'scala'
  apply plugin: 'com.github.maiflai.scalatest'
  apply plugin: 'java'
  apply plugin: 'maven'
  apply plugin: 'maven-publish'
  apply plugin: 'org.unbroken-dome.test-sets'

  sourceCompatibility = '1.8'
  targetCompatibility = '1.8'

  ext.jacksonVersion = '2.8.6'
  ext.springVersion = '4.3.6.RELEASE'
  ext.datastaxVersion = '3.1.3'

  group = 'com.github.leifker'

  repositories {
    flatDir {
      dirs 'libs'
    }
    mavenCentral()
    maven {
      url "https://dl.bintray.com/peoplepattern/maven"
    }
  }

  compileJava {
    options.compilerArgs << '-Xlint:all'
  }

  testSets {
    integrationTest { dirName = 'integration-test' }
    integrationTest { createArtifact = true }
  }
  integrationTest.dependsOn test

  dependencies {
    testCompile 'junit:junit:4.12'
    testCompile "org.springframework:spring-test:$springVersion"
    testCompile "org.springframework:spring-context:$springVersion"
    testCompile 'org.hamcrest:hamcrest-all:1.3'
  }

  sourceSets {
    integrationTest {
      scala {
        compileClasspath += main.output + configurations.integrationTestCompile + test.output
        runtimeClasspath += main.output + configurations.integrationTestRuntime + test.output
        srcDir file('src/integration-test/scala')
      }
      resources.srcDir file('src/integration-test/resources')
    }
  }
}