-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathconfigure.ac
2062 lines (1756 loc) · 64.2 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#**************************************************************************
#* *
#* OCaml *
#* *
#* Sebastien Hinderer, projet Gallium, INRIA Paris *
#* *
#* Copyright 2018 Institut National de Recherche en Informatique et *
#* en Automatique. *
#* *
#* All rights reserved. This file is distributed under the terms of *
#* the GNU Lesser General Public License version 2.1, with the *
#* special exception on linking described in the file LICENSE. *
#* *
#**************************************************************************
# Process this file with autoconf to produce a configure script.
# Require Autoconf 2.69 for repeatability in CI
AC_PREREQ([2.69])
AC_INIT([OCaml],
[OCAML__VERSION],
[ocaml],
[http://www.ocaml.org])
AC_MSG_NOTICE([Configuring OCaml version AC_PACKAGE_VERSION])
# Configuration variables
## Command-line arguments passed to configure
CONFIGURE_ARGS="$*"
# Command to build executalbes
# In general this command is supposed to use the CFLAGs- and LDFLAGS-
# related variables (OC_CFLAGS and OC_LDFLAGS for ocaml-specific
# flags, CFLAGS and LDFLAGS for generic flags chosen by the user), but
# at the moment they are not taken into account on Windows, because
# flexlink, which is used to build executables on this platform, can
# not handle them.
mkexe="\$(CC) \$(OC_CFLAGS) \$(CFLAGS) \$(OC_LDFLAGS) \$(LDFLAGS)"
# Flags for building executable files with debugging symbols
mkexedebugflag="-g"
common_cflags=""
common_cppflags=""
internal_cflags=""
internal_cppflags=""
ocamlc_cflags=""
ocamlc_cppflags=""
oc_ldflags=""
oc_dll_ldflags=""
ostype="Unix"
SO="so"
toolchain="cc"
profinfo=false
profinfo_width=0
extralibs=
instrumented_runtime=false
instrumented_runtime_libs=""
bootstrapping_flexdll=false
# Information about the package
## Source directory
AC_CONFIG_SRCDIR([runtime/interp.c])
## Directory containing auxiliary scripts used during build
AC_CONFIG_AUX_DIR([build-aux])
## Output variables
AC_SUBST([CONFIGURE_ARGS])
AC_SUBST([native_compiler])
AC_SUBST([VERSION], [AC_PACKAGE_VERSION])
AC_SUBST([OCAML_DEVELOPMENT_VERSION], [OCAML__DEVELOPMENT_VERSION])
AC_SUBST([OCAML_RELEASE_EXTRA], [OCAML__RELEASE_EXTRA])
AC_SUBST([OCAML_VERSION_MAJOR], [OCAML__VERSION_MAJOR])
AC_SUBST([OCAML_VERSION_MINOR], [OCAML__VERSION_MINOR])
AC_SUBST([OCAML_VERSION_PATCHLEVEL], [OCAML__VERSION_PATCHLEVEL])
AC_SUBST([OCAML_VERSION_EXTRA], [OCAML__VERSION_EXTRA])
AC_SUBST([OCAML_VERSION_SHORT], [OCAML__VERSION_SHORT])
AC_SUBST([CC])
# Note: This is present for the flexdll bootstrap where it exposed as the old
# TOOLPREF variable. It would be better if flexdll where updated to require
# WINDRES instead.
AC_SUBST([DIRECT_CPP])
AC_SUBST([ac_tool_prefix])
AC_SUBST([exeext])
AC_SUBST([OBJEXT])
AC_SUBST([libext])
AC_SUBST([S])
AC_SUBST([SO])
AC_SUBST([arch])
AC_SUBST([arch64])
AC_SUBST([model])
AC_SUBST([system])
AC_SUBST([systhread_support])
AC_SUBST([unix_or_win32])
AC_SUBST([unixlib])
AC_SUBST([outputexe])
AC_SUBST([outputobj])
AC_SUBST([syslib])
AC_SUBST([extralibs])
AC_SUBST([fpic])
AC_SUBST([mkexe])
AC_SUBST([mkexedebugflag])
AC_SUBST([ccomptype])
AC_SUBST([toolchain])
AC_SUBST([oc_cflags])
AC_SUBST([oc_cppflags])
AC_SUBST([oc_ldflags])
AC_SUBST([oc_dll_ldflags])
AC_SUBST([bytecclibs])
AC_SUBST([nativecclibs])
AC_SUBST([ocamlc_cflags])
AC_SUBST([ocamlc_cppflags])
AC_SUBST([flexdir])
AC_SUBST([bootstrapping_flexdll])
AC_SUBST([long_shebang])
AC_SUBST([shebangscripts])
AC_SUBST([AR])
AC_SUBST([mklib])
AC_SUBST([supports_shared_libraries])
AC_SUBST([natdynlink])
AC_SUBST([natdynlinkopts])
AC_SUBST([cmxs])
AC_SUBST([debug_runtime])
AC_SUBST([instrumented_runtime])
AC_SUBST([instrumented_runtime_libs])
AC_SUBST([has_monotonic_clock])
AC_SUBST([otherlibraries])
AC_SUBST([cc_has_debug_prefix_map])
AC_SUBST([as_has_debug_prefix_map])
AC_SUBST([with_debugger]) # TODO: rename this variable
AC_SUBST([with_camltex])
AC_SUBST([ocamldoc])
AC_SUBST([documentation_tool])
AC_SUBST([documentation_tool_cmd])
AC_SUBST([ocamltest])
AC_SUBST([ASPP])
AC_SUBST([endianness])
AC_SUBST([AS])
AC_SUBST([asm_cfi_supported])
AC_SUBST([sharedlib_cflags])
AC_SUBST([rpath])
AC_SUBST([mksharedlib])
AC_SUBST([mkmaindll])
AC_SUBST([mksharedlibrpath])
AC_SUBST([install_bytecode_programs])
AC_SUBST([install_source_artifacts])
AC_SUBST([install_ocamlnat])
AC_SUBST([profinfo])
AC_SUBST([profinfo_width])
AC_SUBST([frame_pointers])
AC_SUBST([flambda])
AC_SUBST([flambda_invariants])
AC_SUBST([cmm_invariants])
AC_SUBST([windows_unicode])
AC_SUBST([flat_float_array])
AC_SUBST([function_sections])
AC_SUBST([afl])
AC_SUBST([force_safe_string])
AC_SUBST([default_safe_string])
AC_SUBST([flexdll_chain])
AC_SUBST([flexlink_flags])
AC_SUBST([PACKLD])
AC_SUBST([stdlib_manpages])
AC_SUBST([compute_deps])
AC_SUBST([naked_pointers])
AC_SUBST([naked_pointers_checker])
## Generated files
AC_CONFIG_FILES([Makefile.build_config])
AC_CONFIG_FILES([Makefile.config])
AC_CONFIG_FILES([stdlib/sys.ml])
AC_CONFIG_FILES([manual/src/version.tex])
AC_CONFIG_FILES([manual/src/html_processing/src/common.ml])
AC_CONFIG_FILES([tools/eventlog_metadata])
AC_CONFIG_HEADERS([runtime/caml/m.h])
AC_CONFIG_HEADERS([runtime/caml/s.h])
AC_CONFIG_HEADERS([runtime/caml/version.h])
# Definitions related to the version of OCaml
AC_DEFINE([OCAML_VERSION_MAJOR], [OCAML__VERSION_MAJOR])
AC_DEFINE([OCAML_VERSION_MINOR], [OCAML__VERSION_MINOR])
AC_DEFINE([OCAML_VERSION_PATCHLEVEL], [OCAML__VERSION_PATCHLEVEL])
m4_if([OCAML__VERSION_EXTRA],[], [],
[AC_DEFINE([OCAML_VERSION_ADDITIONAL], ["][OCAML__VERSION_EXTRA]["])
AC_DEFINE([OCAML_VERSION_EXTRA], ["][OCAML__VERSION_EXTRA]["])])
AC_DEFINE([OCAML_VERSION], [OCAML__VERSION_NUMBER])
AC_DEFINE([OCAML_VERSION_STRING], ["][OCAML__VERSION]["])
# Checks for system types
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AS_CASE([$host],
[*-pc-windows],
[CC=cl
ccomptype=msvc
S=asm
SO=dll
outputexe=-Fe
syslib='$(1).lib'],
[i386-*-solaris*],
[AC_MSG_ERROR([Building for 32 bits target is not supported. \
If your host is 64 bits, you can try with './configure CC="gcc -m64"' \
(or "cc -m64" if you don't have GCC).])],
[ccomptype=cc
S=s
SO=so
outputexe='-o $(EMPTY)'
syslib='-l$(1)'])
# Environment variables that are taken into account
AC_ARG_VAR([AS], [which assembler to use])
AC_ARG_VAR([ASPP], [which assembler (with preprocessor) to use])
AC_ARG_VAR([PARTIALLD], [how to build partial (relocatable) object files])
# Command-line arguments to configure
AC_ARG_ENABLE([debug-runtime],
[AS_HELP_STRING([--disable-debug-runtime],
[do not build runtime with debugging support])])
AC_ARG_ENABLE([debugger],
[AS_HELP_STRING([--enable-debugger],
[build the debugger @<:@default=auto@:>@])],
[],
[enable_debugger=auto])
AC_ARG_ENABLE([dependency-generation],
[AS_HELP_STRING([--disable-dependency-generation],
[do not compute dependency information for C sources])],
[],
[enable_dependency_generation=auto])
AC_ARG_VAR([DLLIBS],
[which libraries to use (in addition to -ldl) to load dynamic libs])
AC_ARG_ENABLE([instrumented-runtime],
[AS_HELP_STRING([--enable-instrumented-runtime],
[build the instrumented runtime @<:@default=auto@:>@])],
[],
[enable_instrumented_runtime=auto])
AC_ARG_ENABLE([vmthreads], [],
[AC_MSG_ERROR([The vmthreads library is no longer available. \
It was deleted in OCaml 4.09.])],
[])
AC_ARG_ENABLE([systhreads],
[AS_HELP_STRING([--disable-systhreads],
[disable the Win32/POSIX threads library])])
AC_ARG_ENABLE([graph-lib], [],
[AC_MSG_ERROR([The graphics library is no longer distributed with OCaml \
since version 4.09. It is now distributed as a separate "graphics" package: \
https://github.com/ocaml/graphics])],
[])
AC_ARG_ENABLE([str-lib],
[AS_HELP_STRING([--disable-str-lib],
[do not build the str library])])
AC_ARG_ENABLE([unix-lib],
[AS_HELP_STRING([--disable-unix-lib],
[do not build the unix library])])
AC_ARG_ENABLE([bigarray-lib],
[AS_HELP_STRING([--disable-bigarray-lib],
[do not build the legacy separate bigarray library])])
AC_ARG_ENABLE([ocamldoc],
[AS_HELP_STRING([--disable-ocamldoc],
[do not build the ocamldoc documentation system])],
[],
[ocamldoc=auto])
AC_ARG_WITH([odoc],
[AS_HELP_STRING([--with-odoc],
[build documentation with odoc])])
AC_ARG_ENABLE([ocamltest],
[AS_HELP_STRING([--disable-ocamltest],
[do not build the ocamltest driver])])
AC_ARG_ENABLE([native-toplevel],
[AS_HELP_STRING([--enable-native-toplevel],
[build the native toplevel])])
AC_ARG_ENABLE([frame-pointers],
[AS_HELP_STRING([--enable-frame-pointers],
[use frame pointers in runtime and generated code])])
AC_ARG_ENABLE([naked-pointers],
[AS_HELP_STRING([--disable-naked-pointers],
[do not allow naked pointers])])
AC_ARG_ENABLE([naked-pointers-checker],
[AS_HELP_STRING([--enable-naked-pointers-checker],
[enable the naked pointers checker])])
AC_ARG_ENABLE([spacetime], [],
[AC_MSG_ERROR([spacetime profiling was deleted in OCaml 4.12.])],
[])
AC_ARG_ENABLE([cfi],
[AS_HELP_STRING([--disable-cfi],
[disable the CFI directives in assembly files])])
AC_ARG_ENABLE([imprecise-c99-float-ops],
[AS_HELP_STRING([--enable-imprecise-c99-float-ops],
[enables potentially imprecise replacement implementations
of C99 float ops if unavailable on this platform])])
AC_ARG_ENABLE([installing-source-artifacts],
[AS_HELP_STRING([--enable-installing-source-artifacts],
[install *.cmt* and *.mli files])])
AC_ARG_ENABLE([installing-bytecode-programs],
[AS_HELP_STRING([--enable-installing-bytecode-programs],
[also install the bytecode versions of programs])])
AC_ARG_ENABLE([native-compiler],
[AS_HELP_STRING([--disable-native-compiler],
[do not build the native compiler])])
AC_ARG_ENABLE([flambda],
[AS_HELP_STRING([--enable-flambda],
[enable flambda optimizations])])
AC_ARG_ENABLE([flambda-invariants],
[AS_HELP_STRING([--enable-flambda-invariants],
[enable invariants checks in flambda])])
AC_ARG_ENABLE([cmm-invariants],
[AS_HELP_STRING([--enable-cmm-invariants],
[enable invariants checks in Cmm])])
AC_ARG_WITH([target-bindir],
[AS_HELP_STRING([--with-target-bindir],
[location of binary programs on target system])])
AC_ARG_ENABLE([reserved-header-bits],
[AS_HELP_STRING([--enable-reserved-header-bits=BITS],
[reserve BITS (between 0 and 31) bits in block headers for profiling info])],
[AS_CASE([$enable_reserved_header_bits],
[0],
[with_profinfo=false
profinfo_width=0],
[[[1-9]]|[[1-2]][[0-9]]|3[[0-1]]],
[with_profinfo=true
profinfo_width="$enable_reserved_header_bits"],
[AC_MSG_ERROR([invalid argument to --enable-reserved-header-bits])])])
AC_ARG_ENABLE([stdlib-manpages],
[AS_HELP_STRING([--disable-stdlib-manpages],
[do not build or install the library man pages])])
AC_ARG_ENABLE([warn-error],
[AS_HELP_STRING([--enable-warn-error],
[treat C compiler warnings as errors])])
AC_ARG_VAR([WINDOWS_UNICODE_MODE],
[how to handle Unicode under Windows: ansi, compatible])
# There are two configure-time string safety options,
# --(enable|disable)-force-safe-string and
# DEFAULT_STRING=safe|unsafe that
# interact with a compile-time (un)safe-string option.
#
# If --enable-force-safe-string is set at configure time, then the compiler
# will always enforce that string and bytes are distinct: the
# compile-time -unsafe-string option is disabled. This lets us
# assume pervasive string immutability, for code optimizations and
# in the C layer.
#
# If --disable-force-safe-string is set at configure-time, the compiler
# will use the compile-time (un)safe-string option to decide whether
# string and bytes are compatible on a per-file basis. The
# configuration variable DEFAULT_STRING=safe|unsafe decides which
# setting will be chosen by default, if no compile-time option is
# explicitly passed.
#
# The configure-time behavior of OCaml 4.05 and older was equivalent
# to --disable-force-safe-string DEFAULT_STRING=unsafe. With OCaml 4.06
# and older was equivalent to --disable-force-safe-string DEFAULT_STRING=safe.
# With OCaml 4.10 and later use --enable-force-safe-string DEFAULT_STRING=safe.
# We expect the --disable-force-safe-string and DEFAULT_STRING=unsafe options
# to be removed in the future.
AC_ARG_ENABLE([force-safe-string],
[AS_HELP_STRING([--disable-force-safe-string],
[do not force strings to be safe])])
AC_ARG_VAR([DEFAULT_STRING],
[whether strings should be safe (default) or unsafe])
AC_ARG_ENABLE([flat-float-array],
[AS_HELP_STRING([--disable-flat-float-array],
[do not use flat float arrays])])
AC_ARG_ENABLE([function-sections],
[AS_HELP_STRING([--disable-function-sections],
[do not emit each function in a separate section])],
[],
[enable_function_sections=auto])
AC_ARG_WITH([afl],
[AS_HELP_STRING([--with-afl],
[use the AFL fuzzer])])
AC_ARG_WITH([flexdll],
[AS_HELP_STRING([--with-flexdll],
[bootstrap FlexDLL from the given sources])],
[AS_IF([test x"$withval" = 'xyes'],[with_flexdll=flexdll])])
AS_IF([test x"$enable_unix_lib" = "xno"],
[AS_IF([test x"$enable_debugger" = "xyes"],
[AC_MSG_ERROR([replay debugger requires the unix library])],
[enable_debugger="no"])
AS_IF([test x"$enable_bigarray_lib" = "xyes"],
[AC_MSG_ERROR([legacy bigarray library requires the unix library])])])
AS_IF([test x"$enable_unix_lib" = "xno" -o x"$enable_str_lib" = "xno"],
[AS_IF([test x"$enable_ocamldoc" = "xyes"],
[AC_MSG_ERROR([ocamldoc requires the unix and str libraries])],
[enable_ocamldoc="no"
with_camltex=""])],
[with_camltex="true"])
# Initialization of libtool
# Allow the MSVC linker to be found even if ld isn't installed.
# User-specified LD still takes precedence.
AC_CHECK_TOOLS([LD],[ld link])
# libtool expects host_os=mingw for native Windows
# Also, it has been observed that, on some platforms (e.g. msvc) LT_INIT
# alters the CFLAGS variable, so we save its value before calling the macro
# and restore it after the call
old_host_os=$host_os
AS_IF([test x"$host_os" = "xwindows"],[host_os=mingw])
saved_CFLAGS="$CFLAGS"
LT_INIT
CFLAGS="$saved_CFLAGS"
host_os=$old_host_os
AS_CASE([$host],
[sparc-sun-solaris*],
[DEP_CC="false"],
[*-pc-windows],
[AC_CHECK_TOOLS(
[DEP_CC],
[$DEP_CC gcc cc x86_64-w64-mingw32-gcc i686-w64-mingw32-gcc],
[false])],
[DEP_CC="$CC"])
AS_CASE([$enable_dependency_generation],
[yes],
[AS_IF([test "$DEP_CC" = "false"],
[AC_MSG_ERROR(m4_normalize([The MSVC ports cannot generate dependency
information. Install gcc (or another CC-like compiler)]))],
[compute_deps=true])],
[no], [compute_deps=false],
[AS_IF([test -e .git],
[AS_IF([test "$DEP_CC" = "false"],
[compute_deps=false],
[compute_deps=true])],
[compute_deps=false])])
AS_CASE([$host],
# In config/Makefile.mingw*, we had:
# TARGET=i686-w64-mingw32 and x86_64-w64-mingw32
# TOOLPREF=$(TARGET)-
# ARCMD=$(TOOLPREF)ar
# However autoconf and libtool seem to use ar
# So we let them do, at the moment
[*-pc-windows],
[
libext=lib
AR=""
AS_IF([test "$host_cpu" = "x86_64" ],
[machine="-machine:AMD64 "],
[machine=""])
mklib="link -lib -nologo $machine /out:\$(1) \$(2)"
],
[
mklib="rm -f \$(1) && ${AR} rc \$(1) \$(2)"
])
## Find vendor of the C compiler
OCAML_CC_VENDOR
## In cross-compilation mode, can we run executables produced?
# At the moment, it's required, but the fact is used in C99 function detection
OCAML_HOST_IS_EXECUTABLE
# Determine how to call the C preprocessor directly.
# Most of the time, calling the C preprocessor through the C compiler is
# desirable and even important.
# In some cases, though, we want to use the C preprocessor only to
# expand macros. In such cases, it is much more convenient to be able
# to invoke it directly rather than through the C compiler, for instance
# because, when invoked directly, the C preprocessor does not require
# to be invoked on a file with a '.c' extension
# We thus figure out how to invoke the C preprocessor directly but
# let the CPP variable untouched, except for the MSVC port where we set it
# manually to make sure the backward compatibility is preserved
AS_CASE([$ocaml_cv_cc_vendor],
[xlc-*],
[CPP="$CC -E -qnoppline"], # suppress incompatible XLC line directives
[sunc-*],
[CPP="$CC -E -Qn"], # suppress generation of Sun PRO ident string
[msvc-*],
[CPP="$CC -nologo -EP"])
# Libraries to build depending on the host
AS_CASE([$host],
[*-*-mingw32|*-pc-windows],
[unix_or_win32="win32"
unixlib="win32unix"
],
[unix_or_win32="unix"
unixlib="unix"])
AS_CASE([$host],
[*-*-cygwin*|*-*-mingw32|*-pc-windows],
[exeext=".exe"],
[exeext=''])
otherlibraries="dynlink"
AS_IF([test x"$enable_unix_lib" != "xno"],
[enable_unix_lib=yes
AS_IF([test x"$enable_bigarray_lib" != "xno"],
[otherlibraries="$otherlibraries $unixlib bigarray"],
[otherlibraries="$otherlibraries $unixlib"])])
AS_IF([test x"$enable_str_lib" != "xno"],
[otherlibraries="$otherlibraries str"])
# Checks for system services
## Test whether #! scripts are supported
## TODO: have two values, one for host and one for target
AC_SYS_INTERPRETER
long_shebang=false
AS_IF(
[test "x$interpval" = "xyes"],
[AS_CASE([$host],
[*-cygwin|*-*-mingw32|*-pc-windows],
[shebangscripts=false],
[shebangscripts=true
prev_exec_prefix="$exec_prefix"
AS_IF([test "x$exec_prefix" = "xNONE"],[exec_prefix="$prefix"])
eval "expanded_bindir=\"$bindir\""
exec_prefix="$prev_exec_prefix"
# Assume maximum shebang is 128 chars; less #!, /ocamlrun, an optional
# 1 char suffix and the \0 leaving 115 characters
AS_IF([test "${#expanded_bindir}" -gt 115],[long_shebang=true])
]
)],
[shebangscripts=false]
)
# Are we building a cross-compiler
AS_IF(
[test x"$host" = x"$target"],
[cross_compiler=false],
[cross_compiler=true])
# Checks for programs
## Check for the C compiler: done by libtool
## AC_PROG_CC
## Check for C99 support: done by libtool
## AC_PROG_CC_C99
## Determine which flags to use for the C compiler
AS_CASE([$ocaml_cv_cc_vendor],
[xlc-*],
[outputobj='-o $(EMPTY)'
warn_error_flag=''
cc_warnings='-qflag=i:i'], # all warnings enabled
[sunc-*],
[outputobj='-o $(EMPTY)'; cc_warnings=""],
[msvc-*],
[outputobj='-Fo'
warn_error_flag='-WX'
cc_warnings=''],
[outputobj='-o $(EMPTY)'
warn_error_flag='-Werror'
cc_warnings='-Wall -Wdeclaration-after-statement'])
AS_CASE([$enable_warn_error,OCAML__DEVELOPMENT_VERSION],
[yes,*|,true],
[cc_warnings="$cc_warnings $warn_error_flag"])
# We select high optimization levels, provided we can turn off:
# - strict type-based aliasing analysis (too risky for the OCaml runtime)
# - strict no-overflow conditions on signed integer arithmetic
# (the OCaml runtime assumes Java-style behavior of signed integer arith.)
# Concerning optimization level, -O3 is somewhat risky, so take -O2.
# Concerning language version, gnu99 is ISO C99 plus GNU extensions
# that are often used in standard headers. Older GCC versions
# defaults to gnu89, which is not C99. Clang defaults to gnu99 or
# gnu11, which is fine.
# Note: the vendor macro can not recognize MinGW because it calls the
# C preprocessor directly so no compiler specific macro like __MING32__
# is defined. We thus catch MinGW first by looking at host and examine
# the vendor only as a fall-back. We could put tis part of the logic
# in the macro itself, too
AS_CASE([$host],
[*-*-mingw32],
[AS_CASE([$ocaml_cv_cc_vendor],
[gcc-[[01234]]-*],
[AC_MSG_ERROR(m4_normalize([This version of Mingw GCC is too old.
Please use GCC version 5 or above.]))],
[gcc-*],
[internal_cflags="-Wno-unused $cc_warnings \
-fexcess-precision=standard"
# TODO: see whether the code can be fixed to avoid -Wno-unused
common_cflags="-O2 -fno-strict-aliasing -fwrapv -mms-bitfields"
internal_cppflags='-D__USE_MINGW_ANSI_STDIO=0 -DUNICODE -D_UNICODE'
internal_cppflags="$internal_cppflags -DWINDOWS_UNICODE="
internal_cppflags="${internal_cppflags}\$(WINDOWS_UNICODE)"],
[AC_MSG_ERROR([Unsupported C compiler for a Mingw build])])],
[AS_CASE([$ocaml_cv_cc_vendor],
[clang-*],
[common_cflags="-O2 -fno-strict-aliasing -fwrapv";
internal_cflags="$cc_warnings -fno-common"],
[gcc-[[012]]-*],
# Some versions known to miscompile OCaml, e,g, 2.7.2.1, some 2.96.
# Plus: C99 support unknown.
[AC_MSG_ERROR(m4_normalize([This version of GCC is too old.
Please use GCC version 4.2 or above.]))],
[gcc-3-*|gcc-4-[[01]]],
# No -fwrapv option before GCC 3.4.
# Known problems with -fwrapv fixed in 4.2 only.
[AC_MSG_WARN(m4_normalize([This version of GCC is rather old.
Reducing optimization level."]));
AC_MSG_WARN([Consider using GCC version 4.2 or above.]);
common_cflags="-std=gnu99 -O";
internal_cflags="$cc_warnings"],
[gcc-4-[[234]]],
# No -fexcess-precision option before GCC 4.5
[common_cflags="-std=gnu99 -O2 -fno-strict-aliasing -fwrapv \
-fno-builtin-memcmp";
internal_cflags="$cc_warnings"],
[gcc-4-*],
[common_cflags="-std=gnu99 -O2 -fno-strict-aliasing -fwrapv \
-fno-builtin-memcmp";
internal_cflags="$cc_warnings -fexcess-precision=standard"],
[gcc-*],
[common_cflags="-O2 -fno-strict-aliasing -fwrapv";
internal_cflags="$cc_warnings -fno-common \
-fexcess-precision=standard"],
[msvc-*],
[common_cflags="-nologo -O2 -Gy- -MD $cc_warnings"
common_cppflags="-D_CRT_SECURE_NO_DEPRECATE"
internal_cppflags='-DUNICODE -D_UNICODE'
OCAML_CL_HAS_VOLATILE_METADATA
AS_IF([test "x$cl_has_volatile_metadata" = "xtrue"],
[internal_cflags='-d2VolatileMetadata-'])
internal_cppflags="$internal_cppflags -DWINDOWS_UNICODE="
internal_cppflags="${internal_cppflags}\$(WINDOWS_UNICODE)"],
[xlc-*],
[common_cflags="-O5 -qtune=balanced -qnoipa -qinline";
internal_cflags="$cc_warnings"],
[sunc-*], # Optimization should be >= O4 to inline functions
# and prevent unresolved externals
[common_cflags="-O4 -xc99=all -D_XPG6 $CFLAGS";
internal_cflags="$cc_warnings"],
[common_cflags="-O"])])
internal_cppflags="-DCAML_NAME_SPACE $internal_cppflags"
# Enable SSE2 on x86 mingw to avoid using 80-bit registers.
AS_CASE([$host],
[i686-*-mingw32],
[internal_cflags="$internal_cflags -mfpmath=sse -msse2"])
# Use 64-bit file offset if possible
# See also AC_SYS_LARGEFILE
# Problem: flags are added to CC rather than CPPFLAGS
AS_CASE([$host],
[*-*-mingw32|*-pc-windows], [],
[common_cppflags="$common_cppflags -D_FILE_OFFSET_BITS=64"])
# Adjust according to target
# On Windows we do not take $enable_shared because it does not seem
# to work. This should be better understood later
#AS_CASE([$target],
# [*-pc-windows],
# [enable_shared=yes])
AS_IF([test x"$enable_shared" = "xno"],
[supports_shared_libraries=false
AS_CASE([$host],
[*-pc-windows|*-w64-mingw32],
[AC_MSG_ERROR([Cannot build native Win32 with --disable-shared])])],
[supports_shared_libraries=true])
# Define flexlink chain and flags correctly for the different Windows ports
AS_CASE([$host],
[i686-*-cygwin],
[flexdll_chain='cygwin'
flexlink_flags="-chain $flexdll_chain -merge-manifest -stack 16777216"],
[x86_64-*-cygwin],
[flexdll_chain='cygwin64'
flexlink_flags="-chain $flexdll_chain -merge-manifest -stack 16777216"],
[*-*-cygwin*],
[AC_MSG_ERROR([unknown cygwin variant])],
[i686-w64-mingw32],
[flexdll_chain='mingw'
flexlink_flags="-chain $flexdll_chain -stack 16777216"],
[x86_64-w64-mingw32],
[flexdll_chain='mingw64'
flexlink_flags="-chain $flexdll_chain -stack 33554432"],
[i686-pc-windows],
[flexdll_chain='msvc'
flexlink_flags="-merge-manifest -stack 16777216"],
[x86_64-pc-windows],
[flexdll_chain='msvc64'
flexlink_flags="-x64 -merge-manifest -stack 33554432"])
AS_IF([test x"$supports_shared_libraries" != 'xfalse'], [
AC_MSG_CHECKING([for flexdll sources])
AS_IF([test x"$with_flexdll" = "xno"],
[flexdir=''
AC_MSG_RESULT([disabled])],
[flexmsg=''
AS_CASE([$target],
[*-*-cygwin*|*-w64-mingw32|*-pc-windows],
[AS_IF([test x"$with_flexdll" = 'x' -o x"$with_flexdll" = 'xflexdll'],
[AS_IF([test -f 'flexdll/flexdll.h'],
[flexdir=flexdll
iflexdir='$(ROOTDIR)/flexdll'
with_flexdll="$iflexdir"],
[AS_IF([test x"$with_flexdll" != 'x'],
[AC_MSG_RESULT([requested but not available])
AC_MSG_ERROR([exiting])])])],
[rm -rf flexdll-sources
AS_IF([test -f "$with_flexdll/flexdll.h"],
[mkdir -p flexdll-sources
cp -r "$with_flexdll"/* flexdll-sources/
flexdir='flexdll-sources'
iflexdir='$(ROOTDIR)/flexdll-sources'
flexmsg=" (from $with_flexdll)"],
[AC_MSG_RESULT([requested but not available])
AC_MSG_ERROR([exiting])])])
AS_IF([test x"$flexdir" = 'x'],
[AC_MSG_RESULT([no])],
[AC_MSG_RESULT([$iflexdir$flexmsg])
bootstrapping_flexdll=true
# The submodule should be searched *before* any other -I paths
internal_cppflags="-I $iflexdir $internal_cppflags"])],
[AS_IF([test x"$with_flexdll" != 'x'],
[AC_MSG_RESULT([requested but not supported])
AC_MSG_ERROR([exiting])])])])
AC_CHECK_PROG([flexlink],[flexlink],[flexlink])
AS_IF([test -n "$flexlink" -a -z "$flexdir"],[
OCAML_TEST_FLEXLINK([$flexlink], [$flexdll_chain],
[$internal_cppflags], [$host])
AS_CASE([$host],
[*-w64-mingw32|*-pc-windows],
[flexlink_where="$(cmd /c "$flexlink" -where 2>/dev/null)"
AS_IF([test -z "$flexlink_where"],
[AC_MSG_ERROR([$flexlink is not executable from a native Win32 process])
])])
])
OCAML_TEST_FLEXDLL_H([$flexdir])
AS_IF([test -n "$flexlink" -a x"$have_flexdll_h" = 'xno'],
[OCAML_TEST_FLEXLINK_WHERE([$flexlink])
AS_IF([test "x$have_flexdll_h" = 'xyes'],
[internal_cppflags="$internal_cppflags -I \"$flexlink_where\""])
])
])
AS_CASE([$have_flexdll_h,$supports_shared_libraries,$host],
[no,true,*-*-cygwin*],
[supports_shared_libraries=false
AC_MSG_WARN([flexdll.h not found: shared library support disabled.])],
[no,*,*-w64-mingw32|no,*,*-pc-windows],
[AC_MSG_ERROR([flexdll.h is required for native Win32])])
AS_CASE([$flexdir,$supports_shared_libraries,$flexlink,$host],
[,true,,*-*-cygwin*],
[supports_shared_libraries=false
AC_MSG_WARN([flexlink not found: shared library support disabled.])],
[,*,,*-w64-mingw32|,*,,*-pc-windows],
[AC_MSG_ERROR([flexlink is required for native Win32])])
AS_CASE([$cc_basename,$host],
[*,*-*-darwin*],
[mkexe="$mkexe -Wl,-no_compact_unwind";
AC_DEFINE([HAS_ARCH_CODE32], [1])],
[*,*-*-haiku*], [mathlib=""],
[*,*-*-cygwin*],
[common_cppflags="$common_cppflags -U_WIN32"
AS_IF([$supports_shared_libraries],
[mkexe='$(FLEXLINK) -exe $(if $(OC_LDFLAGS),-link "$(OC_LDFLAGS)")'
mkexedebugflag="-link -g"],
[mkexe="$mkexe -Wl,--stack,16777216"
oc_ldflags="-Wl,--stack,16777216"]
)
ostype="Cygwin"],
[*,*-*-mingw32],
[AS_CASE([$host],
[i686-*-*], [oc_dll_ldflags="-static-libgcc"])
mkexedebugflag="-link -g"
ostype="Win32"
toolchain="mingw"
mkexe='$(FLEXLINK) -exe $(if $(OC_LDFLAGS),-link "$(OC_LDFLAGS)")'
oc_ldflags='-municode'
SO="dll"],
[*,*-pc-windows],
[toolchain=msvc
ostype="Win32"
mkexe='$(FLEXLINK) -exe $(if $(OC_LDFLAGS),-link "$(OC_LDFLAGS)")'
oc_ldflags='/ENTRY:wmainCRTStartup'
mkexedebugflag=''],
[*,x86_64-*-linux*],
AC_DEFINE([HAS_ARCH_CODE32], [1]),
[[*,i[3456]86-*]],
# Explicitly disable PIE executables on Linux and *BSD x86_32
[mkexe="$mkexe -no-pie "],
[xlc*,powerpc-ibm-aix*],
[mkexe="$mkexe "
oc_ldflags="-brtl -bexpfull"
AC_DEFINE([HAS_ARCH_CODE32], [1])],
[gcc*,powerpc-*-linux*],
[oc_ldflags="-mbss-plt"],
)
## Program to use to install files
AC_PROG_INSTALL
# Checks for libraries
## Mathematical library
AC_CHECK_LIB([m],[cos])
AS_IF([test "x$ac_cv_lib_m_cos" = xyes ], [mathlib="-lm"], [mathlib=""])
# Checks for header files
AC_CHECK_HEADER([math.h])
AC_CHECK_HEADERS([unistd.h],[AC_DEFINE([HAS_UNISTD])])
AC_CHECK_HEADER([stdint.h],[AC_DEFINE([HAS_STDINT_H])])
AC_CHECK_HEADER([dirent.h], [AC_DEFINE([HAS_DIRENT])], [],
[#include <sys/types.h>])
AC_CHECK_HEADER([sys/select.h], [AC_DEFINE([HAS_SYS_SELECT_H])], [],
[#include <sys/types.h>])
# Checks for types
## off_t
AC_TYPE_OFF_T
# Checks for structures
# Checks for compiler characteristics
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(long *)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(long long)
AS_IF(
[test "x$ac_cv_sizeof_long_p" = "x4" ],
[bits=32; arch64=false],
[test "x$ac_cv_sizeof_long_p" = "x8" ],
[bits=64; arch64=true
AC_DEFINE([ARCH_SIXTYFOUR], [1])],
[AC_MSG_ERROR([Neither 32 nor 64 bits architecture.])]
)
AS_IF([test "x$ac_cv_sizeof_int" != "x4" && test "x$ac_cv_sizeof_long" != "x4" \
&& test "x$ac_cv_sizeof_short" != "x4"],
[AC_MSG_ERROR([Sorry, we can't find a 32-bit integer type.])]
)
AS_IF(
[test "x$ac_cv_sizeof_long" != "x8" &&
test "x$ac_cv_sizeof_long_long" != "x8"],
[AC_MSG_ERROR([Sorry, we can't find a 64-bit integer type.])]
)
AC_DEFINE_UNQUOTED([SIZEOF_PTR], [$ac_cv_sizeof_long_p])
AC_DEFINE_UNQUOTED([SIZEOF_LONGLONG], [$ac_cv_sizeof_long_long])
AC_MSG_NOTICE([Target is a $bits bits architecture])
AC_C_BIGENDIAN(
[
AC_DEFINE([ARCH_BIG_ENDIAN], [1])
[endianness="be"]
],
[endianness="le"],
[AC_MSG_ERROR([could not determine endianness.])],
[AC_MSG_ERROR([unable to handle universal endianness])]
)
AC_CHECK_ALIGNOF([double])
AC_CHECK_ALIGNOF([long])
AC_CHECK_ALIGNOF([long long])
AS_IF([! $arch64],
[AS_CASE([$target_cpu],
[i686], [],
[AS_IF([test "$ac_cv_alignof_double" -gt 4],
[AC_DEFINE([ARCH_ALIGN_DOUBLE], [1])])
AS_IF([test "x$ac_cv_sizeof_long" = "x8" &&
test "$ac_cv_alignof_long" -gt 4],
[AC_DEFINE([ARCH_ALIGN_INT64], [1])],
[AS_IF([test "x$ac_cv_sizeof_long_long" = "x8" &&
test "$ac_cv_alignof_long_long" -gt 4],
[AC_DEFINE([ARCH_ALIGN_INT64], [1])])])
])])
# Shared library support
sharedlib_cflags=''
mksharedlib='shared-libs-not-available'
rpath=''
mksharedlibrpath=''
natdynlinkopts=""
AS_IF([test x"$enable_shared" != "xno"],
[AS_CASE([$host],
[*-apple-darwin*],
[mksharedlib="$CC -shared \
-undefined dynamic_lookup -Wl,-no_compact_unwind -Wl,-w \
\$(LDFLAGS)"
supports_shared_libraries=true],
[*-*-mingw32],
[mksharedlib='$(FLEXLINK)'
mkmaindll='$(FLEXLINK) -maindll'
AS_IF([test -n "$oc_dll_ldflags"],[
mksharedlib="$mksharedlib -link \"$oc_dll_ldflags\""
mkmaindll="$mkmaindll -link \"$oc_dll_ldflags\""])],
[*-pc-windows],
[mksharedlib='$(FLEXLINK)'
mkmaindll='$(FLEXLINK) -maindll'],
[*-*-cygwin*],
[mksharedlib='$(FLEXLINK)'
mkmaindll='$(FLEXLINK) -maindll'],
[powerpc-ibm-aix*],
[AS_CASE([$ocaml_cv_cc_vendor],
[xlc*],
[mksharedlib="$CC -qmkshrobj -G \$(LDFLAGS)"
supports_shared_libraries=true])],
[*-*-solaris*],
[sharedlib_cflags="-fPIC"
mksharedlib="$CC -shared"
rpath="-Wl,-rpath,"
mksharedlibrpath="-Wl,-rpath,"
supports_shared_libraries=true],
[[*-*-linux*|*-*-freebsd[3-9]*|*-*-freebsd[1-9][0-9]*\
|*-*-openbsd*|*-*-netbsd*|*-*-dragonfly*|*-*-gnu*|*-*-haiku*]],
[sharedlib_cflags="-fPIC"
AS_CASE([$cc_basename,$host],
[*gcc*,powerpc-*-linux*],
[mksharedlib="$CC -shared -mbss-plt \$(LDFLAGS)"],
[[*,i[3456]86-*]],
# Disable DT_TEXTREL warnings on Linux and BSD i386
# See https://github.com/ocaml/ocaml/issues/9800
[mksharedlib="$CC -shared \$(LDFLAGS) -Wl,-z,notext"],
[mksharedlib="$CC -shared \$(LDFLAGS)"])
AS_CASE([$host],
[[*-*-openbsd7.[3-9]|*-*-openbsd[89].*]],
[mkdll_flags="${mkdll_flags} -Wl,--no-execute-only"])
oc_ldflags="$oc_ldflags -Wl,-E"
rpath="-Wl,-rpath,"
mksharedlibrpath="-Wl,-rpath,"
natdynlinkopts="-Wl,-E"
supports_shared_libraries=true])])
AS_IF([test -z "$mkmaindll"], [mkmaindll=$mksharedlib])
# Make sure code sections in OCaml-generated executables are readable
# (required for marshaling of function closures)