forked from Reference-LAPACK/lapack
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathchfrk.f
553 lines (553 loc) · 17.3 KB
/
chfrk.f
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
*> \brief \b CHFRK performs a Hermitian rank-k operation for matrix in RFP format.
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CHFRK + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chfrk.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chfrk.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chfrk.f">
*> [TXT]</a>
*> \endhtmlonly
*
* Definition:
* ===========
*
* SUBROUTINE CHFRK( TRANSR, UPLO, TRANS, N, K, ALPHA, A, LDA, BETA,
* C )
*
* .. Scalar Arguments ..
* REAL ALPHA, BETA
* INTEGER K, LDA, N
* CHARACTER TRANS, TRANSR, UPLO
* ..
* .. Array Arguments ..
* COMPLEX A( LDA, * ), C( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> Level 3 BLAS like routine for C in RFP Format.
*>
*> CHFRK performs one of the Hermitian rank--k operations
*>
*> C := alpha*A*A**H + beta*C,
*>
*> or
*>
*> C := alpha*A**H*A + beta*C,
*>
*> where alpha and beta are real scalars, C is an n--by--n Hermitian
*> matrix and A is an n--by--k matrix in the first case and a k--by--n
*> matrix in the second case.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] TRANSR
*> \verbatim
*> TRANSR is CHARACTER*1
*> = 'N': The Normal Form of RFP A is stored;
*> = 'C': The Conjugate-transpose Form of RFP A is stored.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*> UPLO is CHARACTER*1
*> On entry, UPLO specifies whether the upper or lower
*> triangular part of the array C is to be referenced as
*> follows:
*>
*> UPLO = 'U' or 'u' Only the upper triangular part of C
*> is to be referenced.
*>
*> UPLO = 'L' or 'l' Only the lower triangular part of C
*> is to be referenced.
*>
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*> TRANS is CHARACTER*1
*> On entry, TRANS specifies the operation to be performed as
*> follows:
*>
*> TRANS = 'N' or 'n' C := alpha*A*A**H + beta*C.
*>
*> TRANS = 'C' or 'c' C := alpha*A**H*A + beta*C.
*>
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> On entry, N specifies the order of the matrix C. N must be
*> at least zero.
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*> K is INTEGER
*> On entry with TRANS = 'N' or 'n', K specifies the number
*> of columns of the matrix A, and on entry with
*> TRANS = 'C' or 'c', K specifies the number of rows of the
*> matrix A. K must be at least zero.
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*> ALPHA is REAL
*> On entry, ALPHA specifies the scalar alpha.
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is COMPLEX array, dimension (LDA,ka)
*> where KA
*> is K when TRANS = 'N' or 'n', and is N otherwise. Before
*> entry with TRANS = 'N' or 'n', the leading N--by--K part of
*> the array A must contain the matrix A, otherwise the leading
*> K--by--N part of the array A must contain the matrix A.
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> On entry, LDA specifies the first dimension of A as declared
*> in the calling (sub) program. When TRANS = 'N' or 'n'
*> then LDA must be at least max( 1, n ), otherwise LDA must
*> be at least max( 1, k ).
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in] BETA
*> \verbatim
*> BETA is REAL
*> On entry, BETA specifies the scalar beta.
*> Unchanged on exit.
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*> C is COMPLEX array, dimension (N*(N+1)/2)
*> On entry, the matrix A in RFP Format. RFP Format is
*> described by TRANSR, UPLO and N. Note that the imaginary
*> parts of the diagonal elements need not be set, they are
*> assumed to be zero, and on exit they are set to zero.
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup complexOTHERcomputational
*
* =====================================================================
SUBROUTINE CHFRK( TRANSR, UPLO, TRANS, N, K, ALPHA, A, LDA, BETA,
$ C )
*
* -- LAPACK computational routine (version 3.7.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* December 2016
*
* .. Scalar Arguments ..
REAL ALPHA, BETA
INTEGER K, LDA, N
CHARACTER TRANS, TRANSR, UPLO
* ..
* .. Array Arguments ..
COMPLEX A( LDA, * ), C( * )
* ..
*
* =====================================================================
*
* ..
* .. Parameters ..
REAL ONE, ZERO
COMPLEX CZERO
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
PARAMETER ( CZERO = ( 0.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
LOGICAL LOWER, NORMALTRANSR, NISODD, NOTRANS
INTEGER INFO, NROWA, J, NK, N1, N2
COMPLEX CALPHA, CBETA
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. External Subroutines ..
EXTERNAL CGEMM, CHERK, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, CMPLX
* ..
* .. Executable Statements ..
*
*
* Test the input parameters.
*
INFO = 0
NORMALTRANSR = LSAME( TRANSR, 'N' )
LOWER = LSAME( UPLO, 'L' )
NOTRANS = LSAME( TRANS, 'N' )
*
IF( NOTRANS ) THEN
NROWA = N
ELSE
NROWA = K
END IF
*
IF( .NOT.NORMALTRANSR .AND. .NOT.LSAME( TRANSR, 'C' ) ) THEN
INFO = -1
ELSE IF( .NOT.LOWER .AND. .NOT.LSAME( UPLO, 'U' ) ) THEN
INFO = -2
ELSE IF( .NOT.NOTRANS .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
INFO = -3
ELSE IF( N.LT.0 ) THEN
INFO = -4
ELSE IF( K.LT.0 ) THEN
INFO = -5
ELSE IF( LDA.LT.MAX( 1, NROWA ) ) THEN
INFO = -8
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'CHFRK ', -INFO )
RETURN
END IF
*
* Quick return if possible.
*
* The quick return case: ((ALPHA.EQ.0).AND.(BETA.NE.ZERO)) is not
* done (it is in CHERK for example) and left in the general case.
*
IF( ( N.EQ.0 ) .OR. ( ( ( ALPHA.EQ.ZERO ) .OR. ( K.EQ.0 ) ) .AND.
$ ( BETA.EQ.ONE ) ) )RETURN
*
IF( ( ALPHA.EQ.ZERO ) .AND. ( BETA.EQ.ZERO ) ) THEN
DO J = 1, ( ( N*( N+1 ) ) / 2 )
C( J ) = CZERO
END DO
RETURN
END IF
*
CALPHA = CMPLX( ALPHA, ZERO )
CBETA = CMPLX( BETA, ZERO )
*
* C is N-by-N.
* If N is odd, set NISODD = .TRUE., and N1 and N2.
* If N is even, NISODD = .FALSE., and NK.
*
IF( MOD( N, 2 ).EQ.0 ) THEN
NISODD = .FALSE.
NK = N / 2
ELSE
NISODD = .TRUE.
IF( LOWER ) THEN
N2 = N / 2
N1 = N - N2
ELSE
N1 = N / 2
N2 = N - N1
END IF
END IF
*
IF( NISODD ) THEN
*
* N is odd
*
IF( NORMALTRANSR ) THEN
*
* N is odd and TRANSR = 'N'
*
IF( LOWER ) THEN
*
* N is odd, TRANSR = 'N', and UPLO = 'L'
*
IF( NOTRANS ) THEN
*
* N is odd, TRANSR = 'N', UPLO = 'L', and TRANS = 'N'
*
CALL CHERK( 'L', 'N', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 1 ), N )
CALL CHERK( 'U', 'N', N2, K, ALPHA, A( N1+1, 1 ), LDA,
$ BETA, C( N+1 ), N )
CALL CGEMM( 'N', 'C', N2, N1, K, CALPHA, A( N1+1, 1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( N1+1 ), N )
*
ELSE
*
* N is odd, TRANSR = 'N', UPLO = 'L', and TRANS = 'C'
*
CALL CHERK( 'L', 'C', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 1 ), N )
CALL CHERK( 'U', 'C', N2, K, ALPHA, A( 1, N1+1 ), LDA,
$ BETA, C( N+1 ), N )
CALL CGEMM( 'C', 'N', N2, N1, K, CALPHA, A( 1, N1+1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( N1+1 ), N )
*
END IF
*
ELSE
*
* N is odd, TRANSR = 'N', and UPLO = 'U'
*
IF( NOTRANS ) THEN
*
* N is odd, TRANSR = 'N', UPLO = 'U', and TRANS = 'N'
*
CALL CHERK( 'L', 'N', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( N2+1 ), N )
CALL CHERK( 'U', 'N', N2, K, ALPHA, A( N2, 1 ), LDA,
$ BETA, C( N1+1 ), N )
CALL CGEMM( 'N', 'C', N1, N2, K, CALPHA, A( 1, 1 ),
$ LDA, A( N2, 1 ), LDA, CBETA, C( 1 ), N )
*
ELSE
*
* N is odd, TRANSR = 'N', UPLO = 'U', and TRANS = 'C'
*
CALL CHERK( 'L', 'C', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( N2+1 ), N )
CALL CHERK( 'U', 'C', N2, K, ALPHA, A( 1, N2 ), LDA,
$ BETA, C( N1+1 ), N )
CALL CGEMM( 'C', 'N', N1, N2, K, CALPHA, A( 1, 1 ),
$ LDA, A( 1, N2 ), LDA, CBETA, C( 1 ), N )
*
END IF
*
END IF
*
ELSE
*
* N is odd, and TRANSR = 'C'
*
IF( LOWER ) THEN
*
* N is odd, TRANSR = 'C', and UPLO = 'L'
*
IF( NOTRANS ) THEN
*
* N is odd, TRANSR = 'C', UPLO = 'L', and TRANS = 'N'
*
CALL CHERK( 'U', 'N', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 1 ), N1 )
CALL CHERK( 'L', 'N', N2, K, ALPHA, A( N1+1, 1 ), LDA,
$ BETA, C( 2 ), N1 )
CALL CGEMM( 'N', 'C', N1, N2, K, CALPHA, A( 1, 1 ),
$ LDA, A( N1+1, 1 ), LDA, CBETA,
$ C( N1*N1+1 ), N1 )
*
ELSE
*
* N is odd, TRANSR = 'C', UPLO = 'L', and TRANS = 'C'
*
CALL CHERK( 'U', 'C', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 1 ), N1 )
CALL CHERK( 'L', 'C', N2, K, ALPHA, A( 1, N1+1 ), LDA,
$ BETA, C( 2 ), N1 )
CALL CGEMM( 'C', 'N', N1, N2, K, CALPHA, A( 1, 1 ),
$ LDA, A( 1, N1+1 ), LDA, CBETA,
$ C( N1*N1+1 ), N1 )
*
END IF
*
ELSE
*
* N is odd, TRANSR = 'C', and UPLO = 'U'
*
IF( NOTRANS ) THEN
*
* N is odd, TRANSR = 'C', UPLO = 'U', and TRANS = 'N'
*
CALL CHERK( 'U', 'N', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( N2*N2+1 ), N2 )
CALL CHERK( 'L', 'N', N2, K, ALPHA, A( N1+1, 1 ), LDA,
$ BETA, C( N1*N2+1 ), N2 )
CALL CGEMM( 'N', 'C', N2, N1, K, CALPHA, A( N1+1, 1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( 1 ), N2 )
*
ELSE
*
* N is odd, TRANSR = 'C', UPLO = 'U', and TRANS = 'C'
*
CALL CHERK( 'U', 'C', N1, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( N2*N2+1 ), N2 )
CALL CHERK( 'L', 'C', N2, K, ALPHA, A( 1, N1+1 ), LDA,
$ BETA, C( N1*N2+1 ), N2 )
CALL CGEMM( 'C', 'N', N2, N1, K, CALPHA, A( 1, N1+1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( 1 ), N2 )
*
END IF
*
END IF
*
END IF
*
ELSE
*
* N is even
*
IF( NORMALTRANSR ) THEN
*
* N is even and TRANSR = 'N'
*
IF( LOWER ) THEN
*
* N is even, TRANSR = 'N', and UPLO = 'L'
*
IF( NOTRANS ) THEN
*
* N is even, TRANSR = 'N', UPLO = 'L', and TRANS = 'N'
*
CALL CHERK( 'L', 'N', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 2 ), N+1 )
CALL CHERK( 'U', 'N', NK, K, ALPHA, A( NK+1, 1 ), LDA,
$ BETA, C( 1 ), N+1 )
CALL CGEMM( 'N', 'C', NK, NK, K, CALPHA, A( NK+1, 1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( NK+2 ),
$ N+1 )
*
ELSE
*
* N is even, TRANSR = 'N', UPLO = 'L', and TRANS = 'C'
*
CALL CHERK( 'L', 'C', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( 2 ), N+1 )
CALL CHERK( 'U', 'C', NK, K, ALPHA, A( 1, NK+1 ), LDA,
$ BETA, C( 1 ), N+1 )
CALL CGEMM( 'C', 'N', NK, NK, K, CALPHA, A( 1, NK+1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( NK+2 ),
$ N+1 )
*
END IF
*
ELSE
*
* N is even, TRANSR = 'N', and UPLO = 'U'
*
IF( NOTRANS ) THEN
*
* N is even, TRANSR = 'N', UPLO = 'U', and TRANS = 'N'
*
CALL CHERK( 'L', 'N', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK+2 ), N+1 )
CALL CHERK( 'U', 'N', NK, K, ALPHA, A( NK+1, 1 ), LDA,
$ BETA, C( NK+1 ), N+1 )
CALL CGEMM( 'N', 'C', NK, NK, K, CALPHA, A( 1, 1 ),
$ LDA, A( NK+1, 1 ), LDA, CBETA, C( 1 ),
$ N+1 )
*
ELSE
*
* N is even, TRANSR = 'N', UPLO = 'U', and TRANS = 'C'
*
CALL CHERK( 'L', 'C', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK+2 ), N+1 )
CALL CHERK( 'U', 'C', NK, K, ALPHA, A( 1, NK+1 ), LDA,
$ BETA, C( NK+1 ), N+1 )
CALL CGEMM( 'C', 'N', NK, NK, K, CALPHA, A( 1, 1 ),
$ LDA, A( 1, NK+1 ), LDA, CBETA, C( 1 ),
$ N+1 )
*
END IF
*
END IF
*
ELSE
*
* N is even, and TRANSR = 'C'
*
IF( LOWER ) THEN
*
* N is even, TRANSR = 'C', and UPLO = 'L'
*
IF( NOTRANS ) THEN
*
* N is even, TRANSR = 'C', UPLO = 'L', and TRANS = 'N'
*
CALL CHERK( 'U', 'N', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK+1 ), NK )
CALL CHERK( 'L', 'N', NK, K, ALPHA, A( NK+1, 1 ), LDA,
$ BETA, C( 1 ), NK )
CALL CGEMM( 'N', 'C', NK, NK, K, CALPHA, A( 1, 1 ),
$ LDA, A( NK+1, 1 ), LDA, CBETA,
$ C( ( ( NK+1 )*NK )+1 ), NK )
*
ELSE
*
* N is even, TRANSR = 'C', UPLO = 'L', and TRANS = 'C'
*
CALL CHERK( 'U', 'C', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK+1 ), NK )
CALL CHERK( 'L', 'C', NK, K, ALPHA, A( 1, NK+1 ), LDA,
$ BETA, C( 1 ), NK )
CALL CGEMM( 'C', 'N', NK, NK, K, CALPHA, A( 1, 1 ),
$ LDA, A( 1, NK+1 ), LDA, CBETA,
$ C( ( ( NK+1 )*NK )+1 ), NK )
*
END IF
*
ELSE
*
* N is even, TRANSR = 'C', and UPLO = 'U'
*
IF( NOTRANS ) THEN
*
* N is even, TRANSR = 'C', UPLO = 'U', and TRANS = 'N'
*
CALL CHERK( 'U', 'N', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK*( NK+1 )+1 ), NK )
CALL CHERK( 'L', 'N', NK, K, ALPHA, A( NK+1, 1 ), LDA,
$ BETA, C( NK*NK+1 ), NK )
CALL CGEMM( 'N', 'C', NK, NK, K, CALPHA, A( NK+1, 1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( 1 ), NK )
*
ELSE
*
* N is even, TRANSR = 'C', UPLO = 'U', and TRANS = 'C'
*
CALL CHERK( 'U', 'C', NK, K, ALPHA, A( 1, 1 ), LDA,
$ BETA, C( NK*( NK+1 )+1 ), NK )
CALL CHERK( 'L', 'C', NK, K, ALPHA, A( 1, NK+1 ), LDA,
$ BETA, C( NK*NK+1 ), NK )
CALL CGEMM( 'C', 'N', NK, NK, K, CALPHA, A( 1, NK+1 ),
$ LDA, A( 1, 1 ), LDA, CBETA, C( 1 ), NK )
*
END IF
*
END IF
*
END IF
*
END IF
*
RETURN
*
* End of CHFRK
*
END