build.gradle

plugins {
    id("groovy") 
    id("com.github.johnrengelman.shadow") version "7.0.0"
    id("io.micronaut.application") version "2.0.8"
}

version="0.0.2"
group = "codes.recursive"

repositories {
    mavenCentral()
    maven {
        url "https://s01.oss.sonatype.org/content/repositories/snapshots"
    }
}

micronaut {
    testRuntime("spock2")
    processing {
        incremental(true)
        annotations("codes.recursive.*")
    }
}

dependencies {
    annotationProcessor("io.micronaut:micronaut-inject-java")
    annotationProcessor("info.picocli:picocli-codegen")
    implementation("info.picocli:picocli")
    implementation("io.micronaut:micronaut-runtime")
    implementation("io.micronaut.picocli:micronaut-picocli")
    implementation("javax.annotation:javax.annotation-api")
    implementation("ch.qos.logback:logback-classic")
    compileOnly("org.graalvm.nativeimage:svm")

    implementation("io.micronaut:micronaut-validation")

    implementation("io.micronaut.jms:micronaut-jms-core")
    implementation("javax.transaction:jta:1.1")
    implementation("com.oracle.database.messaging:aqapi:19.3.0.0")
    implementation("io.micronaut.sql:micronaut-jdbc-ucp:4.1.0-SNAPSHOT")
    implementation("io.micronaut.oraclecloud:micronaut-oraclecloud-sdk")
    implementation("io.micronaut.oraclecloud:micronaut-oraclecloud-atp:2.0.0")
    implementation("com.oracle.database.jdbc:ojdbc11-production:21.1.0.0")
    testImplementation("io.micronaut:micronaut-http-client")
}

nativeImage {
    imageName("aq")
    args = [
            '-H:+ReportExceptionStackTraces',
            '-H:+AddAllCharsets',
            '-H:IncludeResources=logback.xml|application.yml|bootstrap.yml',
            '--initialize-at-build-time=oracle.i18n.text.converter,oracle.xml.parser.v2,oracle.xml.util,oracle.sql',
            '--initialize-at-run-time=io.micronaut.oraclecloud.atp.jdbc.upc,oracle.xml.util.UnicodeUtil,oracle.jdbc,oracle.jdbc.pool,oracle.ucp.admin',
            '--report-unsupported-elements-at-runtime'
    ]
}


application {
    mainClass.set("codes.recursive.AqCliCommand")
}
java {
    sourceCompatibility = JavaVersion.toVersion("11")
    targetCompatibility = JavaVersion.toVersion("11")
}

task bumpVersion  {
    doLast {
        def v = buildFile.getText().find(version)
        String minor = v.substring(v.lastIndexOf('.')+1)
        int m = minor.toInteger()+1
        String major = v.substring(0,v.length()-1)
        String s=buildFile.getText().replaceFirst("version=\"$version\"","version=\"${major+m}\"")
        buildFile.setText(s)
    }
}