build.gradle

plugins {
    id 'java'
    id 'eclipse'
    id 'idea'
    id 'application'
    id 'java-library-distribution'
    id 'com.google.protobuf' version '0.9.1'
    id 'com.github.johnrengelman.shadow' version '7.1.2'
    id 'com.palantir.docker' version '0.25.0'
}
startScripts.enabled = false

repositories {
    mavenCentral()
}

def grpcVersion = '1.66.0'
def protobufVersion = '3.24.4'
def slf4jVersion = '1.7.36'
def log4jVersion = '2.19.0'

dependencies {
    implementation "org.slf4j:slf4j-api:${slf4jVersion}"
    implementation "org.apache.logging.log4j:log4j-core:${log4jVersion}"
    implementation "org.apache.logging.log4j:log4j-slf4j-impl:${log4jVersion}"
    implementation 'info.picocli:picocli:4.0.1'
    implementation 'javax.json:javax.json-api:1.1.4'
    implementation 'org.glassfish:javax.json:1.1.4'
    implementation 'com.google.api.grpc:proto-google-common-protos:1.0.0'
    implementation 'com.google.api.grpc:googleapis-common-protos:0.0.3'
    implementation "io.grpc:grpc-alts:${grpcVersion}"
    implementation "io.grpc:grpc-netty:${grpcVersion}"
    implementation "io.grpc:grpc-protobuf:${grpcVersion}"
    implementation "io.grpc:grpc-stub:${grpcVersion}"
    implementation "com.google.protobuf:protobuf-java-util:${protobufVersion}"
    implementation 'dnsjava:dnsjava:3.6.1'
    implementation 'javax.annotation:javax.annotation-api:1.2'
    testImplementation 'junit:junit:4.12'
    testImplementation 'org.assertj:assertj-core:3.9.1'
    testImplementation 'org.mockito:mockito-core:2.16.0'
    testImplementation "io.grpc:grpc-testing:${grpcVersion}"
}

protobuf {
    protoc { artifact = "com.google.protobuf:protoc:${protobufVersion}" }
    plugins {
        grpc { artifact = "io.grpc:protoc-gen-grpc-java:${grpcVersion}" }
    }
    generateProtoTasks {
        all()*.plugins { grpc {} }
    }
    generatedFilesBaseDir = "$projectDir/src"
}

// The processResources task needs to depend on the generateProto task because it uses the output
// of the the generateProto task
processResources {
    dependsOn generateProto
}

task AdminCommand(type: CreateStartScripts) {
    mainClassName = 'com.scalar.admin.AdminCommand'
    applicationName = 'scalar-admin'
    outputDir = new File(project.buildDir, 'tmp')
    classpath = jar.outputs.files + project.configurations.runtimeClasspath
}

applicationDistribution.into('bin') {
    from(AdminCommand)
    fileMode = 0755
}

application {
    mainClassName = 'com.scalar.admin.AdminCommand'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

distZip {
    archiveFileName = "${project.name}.zip"
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

distTar {
    archiveFileName = "${project.name}.tar"
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

installDist {
    duplicatesStrategy DuplicatesStrategy.EXCLUDE
}

sourcesJar {
    duplicatesStrategy DuplicatesStrategy.EXCLUDE
}

docker {
    name "${project.name}"
    files tasks.distTar.outputs
}

shadowJar {
    mergeServiceFiles()
}

java {
    withJavadocJar()
    withSourcesJar()
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

group = "com.scalar-labs"
archivesBaseName = "scalar-admin"
version = "2.2.1"

// for archiving and uploading to maven central
if (!project.gradle.startParameter.taskNames.isEmpty() &&
    (project.gradle.startParameter.taskNames[0].endsWith('publish') ||
     project.gradle.startParameter.taskNames[0].endsWith('publishToMavenLocal'))) {
    apply from: 'archive.gradle'
}