-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathgame_fpga.asm
1278 lines (1041 loc) · 38.1 KB
/
game_fpga.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
.eqv VGA 0xFF000000
.eqv NUMX 320
.eqv NUMY 240
# IRDA
.eqv IRDA_CONTROL 0xFFFF0500
.eqv IRDA_READ 0xFFFF0504
#system
.eqv STOPWATCH_ADDRESS 0xFFFF050C
.eqv LFSR_ADDRESS 0xFFFF0510
# Lado do quadrado
.eqv SIDE 7
# Parametros fixos
.eqv PAR_X1 70
.eqv PAR_Y0 50
.eqv PAR_Y1 140
# Cores
.eqv BLACK 0x00
.eqv RED 0x0F #0x03
.eqv ORANGE 0x1F
.eqv GREEN 0x30
.eqv YELLOW 0x3F
.eqv DARK_BLUE 0x99
.eqv CYAN 0xF0
.eqv WHITE 0xFF
.eqv PURPLE 0xCC #0x86
# Pecas iniciais
.eqv INIT_PIECE 0x600
# Offset players
.eqv OFFSET_X1 125
.eqv OFFSET_Y1 29
.data
# Matrizes para plotar as peças em suas 4 possíveis rotações
L0: .half 0x2e00, 0x88c0, 0xe800, 0xc440
I0: .half 0xf000, 0x8888, 0xf000, 0x8888
J0: .half 0x8e00, 0xc880, 0xe200, 0x44c0
T0: .half 0x4e00, 0x8c80, 0xe400, 0x4c40
S0: .half 0x8c40, 0x6c00, 0x8c40, 0x6c00
Z0: .half 0x4c80, 0xc600, 0x4c80, 0xc600
Q0: .half 0xcc00, 0xcc00, 0xcc00, 0xcc00
# Mensagens para display
MSG0:.asciiz "Insira o numero de jogadores (1-4): "
PTS: .asciiz "Score"
GAME_OVER: .asciiz "GAME OVER"
# Parametros dependentes do número de jogadores
PAR_4P: .word 0x00081D4E # 4 jogadores
PAR_3P: .word 0x001c3162 # 3 jogadores
PAR_2P: .word 0x003C5182 # 2 jogadores
PAR_1P: .word 0x007d92c3 # 1 jogador
# Pontuações
SCORE1: .half 0x0
SCORE2: .half 0x0
SCORE3: .half 0x0
SCORE4: .half 0x0
# Label
ARG_LABEL1: .word 0x0 # Argumento que vai conter a label para possiveis jumps incondicionais
ARG_LABEL2: .word 0x0 # Argumento que vai conter a label para possiveis jumps incondicionais
ARG_LABEL3: .word 0x0 # Argumento que vai conter a label para possiveis jumps incondicionais
# Matriz do jogo
PRE_2: .word 0x0
PRE_1: .word 0x0
LINE_0: .word 0x0
LINE_1: .word 0x0
LINE_2: .word 0x0
LINE_3: .word 0x0
LINE_4: .word 0x0
LINE_5: .word 0x0
LINE_6: .word 0x0
LINE_7: .word 0x0
LINE_8: .word 0x0
LINE_9: .word 0x0
LINE_10: .word 0x0
LINE_11: .word 0x0
LINE_12: .word 0x0
LINE_13: .word 0x0
LINE_14: .word 0x0
LINE_15: .word 0x0
LINE_16: .word 0x0
LINE_17: .word 0x0
LINE_18: .word 0x0
LINE_19: .word 0x0
# Contadores da matriz do jogo
I_0: .byte 0x0
I_1: .byte 0x0
I_2: .byte 0x0
I_3: .byte 0x0
I_4: .byte 0x0
I_5: .byte 0x0
I_6: .byte 0x0
I_7: .byte 0x0
I_8: .byte 0x0
I_9: .byte 0x0
I_10: .byte 0x0
I_11: .byte 0x0
I_12: .byte 0x0
I_13: .byte 0x0
I_14: .byte 0x0
I_15: .byte 0x0
I_16: .byte 0x0
I_17: .byte 0x0
I_18: .byte 0x0
I_19: .byte 0x0
#Beeps da música
BEEP: .byte 76 #E6
BEEP1: .byte 71 #B5
BEEP2: .byte 72 #C6
BEEP3: .byte 74 #D6
BEEP4: .byte 72 #C6
BEEP5: .byte 71 #B5
BEEP6: .byte 69 #A5
BEEP7: .byte 69 #A5
BEEP8: .byte 72 #C6
BEEP9: .byte 76 #E6
BEEP10: .byte 74 #D6
BEEP11: .byte 72 #C6
BEEP12: .byte 71 #B5
BEEP13: .byte 71 #B5
BEEP14: .byte 72 #C6
BEEP15: .byte 74 #D6
BEEP16: .byte 76 #E6
BEEP17: .byte 72 #C6
BEEP18: .byte 69 #A5
BEEP19: .byte 69 #A5
BEEP20: .byte 74 #D6
BEEP21: .byte 77 #F6
BEEP22: .byte 81 #A6
BEEP23: .byte 79 #G6
BEEP24: .byte 77 #F6
BEEP25: .byte 76 #E6
BEEP26: .byte 72 #C6
BEEP27: .byte 76 #E6
BEEP28: .byte 74 #D6
BEEP29: .byte 72 #C6
BEEP30: .byte 71 #B5
BEEP31: .byte 71 #B5
BEEP32: .byte 74 #D6
BEEP33: .byte 76 #E6
BEEP34: .byte 72 #C6
BEEP35: .byte 69 #A5
BEEP36: .byte 69 #A5
#Posição atual da musica
MUSIC_POSITION: .word 0x0
#Duração da nota
DURATION: .byte 255
#Volume da nota
VOLUME: .byte 127
.text
MAIN:
li $a0, WHITE
li $v0, 48
syscall
move $s3, $zero
la $a0, MSG0 # Pergunta quantidade de jogadores
li $a1, 3
li $a2, 3
li $a3, 0xFF00
li $v0, 104
syscall
# Le do controle a quantidade de jogadores
la $t0, IRDA_CONTROL
li $t1, 1
sw $t1,0($t0)
la $t0, IRDA_READ
input_players:
lw $t1,0($t0)
beq $t1,$zero, input_players
srl $t1,$t1,16
li $t2,0xFB04
beq $t1,$t2,P4
li $t2,0xFC03
beq $t1,$t2,P3
li $t2,0xFD02
beq $t1,$t2,P2
li $t2,0xFE01
beq $t1,$t2,P1
P4: la $t0, PAR_4P
j pass_main
P3: la $t0, PAR_3P
j pass_main
P2: la $t0, PAR_2P
j pass_main
P1: la $t0, PAR_1P
pass_main: lw $s7, 0($t0) # Carrega parâmetros da memória
andi $a0, $s7, 0x00FF0000
srl $a0, $a0, 16
andi $a1, $s7, 0x0000FF00
srl $a1, $a1, 8
andi $a2, $s7, 0x000000FF
li $a3, NUMX
jal show_initial # Plota tela inicial de jogo
lw $s6, SCORE1 # Carrega da memória as pontuações dos jogadores
lw $s5, SCORE2
andi $a0, $s6, 0xFFFF0000
srl $a0, $a0, 16
li $a1, 0
jal write_score # Escreve a pontuação do jogador 1
game_loop: jal sys_time #pega o tempo do sistema em ms
addiu $s1, $v0, 0 #coloca o tempo do sistema no registrador s1
beq $s2,0xFFFFFFFF,continue_gl2#se esta no fim do jogo, vai pro fim do loop
bne $s2, $zero, continue_gl0 #checa se tem uma peca movel em jogo
jal rand7 #se sim, randomiza o tipo da peca
li $s2, INIT_PIECE #inicializa uma nova peca
addiu $s2, $s2, 1
addu $s2, $s2, $v0 #seta o tipo da peca
li $s0, 501 #acumula tempo suficiente pra ciclo
continue_gl0: jal keyboard #verifica teclado por uma tecla
beq $v0, 0, continue_gl1 #se nao teve input, continua o loop
add $a0, $v0, $zero #seta o codigo da tecla pressionada como argumento
jal input #senao, trata input
continue_gl1: ble $s0, 300,continue_gl2 #checa se há tempo acumulado suficiente para o ciclo de movimento da peca
addu $s0, $zero, $zero #reseta o acumulador de tempo
la $t0, update_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL1 #salva o valor do endereco da label no endereco ARG_LABEL1
la $t0, after_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL2 #salva o valor do endereco da label no endereco ARG_LABEL2
la $t0, reset_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL3 #salva o valor do endereco da label no endereco ARG_LABEL3
jal play_music #toca um beep da musica
jal cycle
beqz $v0, continue_gl2 #se nao houver colisao, vai para continue_gl2
jal collision
continue_gl2: jal sys_time #pega o tempo do sistema em ms
subu $t0, $v0, $s1 #calcula o tempo que o ciclo demorou
addu $s0, $s0, $t0 #incrementa o acumulador de tempo
j game_loop #volta para o inicio do loop
#################################################################################################
keyboard: la $t1,IRDA_CONTROL
li $t0,1
sw $t0,0($t1)
la $t1,IRDA_READ
lw $t0,0($t1)
beq $t0,$zero, not_pressed # Se nao ha tecla pressionada, finaliza
srl $v0,$t0,16 # Tecla lida
j keyboard_end
not_pressed: add $v0, $zero, $zero # se tecla nao pressionada, coloca zero no registrador v0
keyboard_end: jr $ra
#################################################################################################
input: beq $a0, 0xF50A, rotate #verifica se a tecla de rotacao (w) foi pressionada
beq $a0, 0xF20D, left #verifica se a tecla de esquerda (a) foi pressionada
beq $a0, 0XF30C, right #verifica se a tecla de esquerda (d) foi pressionada
beq $a0, 0XF40B, down #verifica se a tecla de esquerda (s) foi pressionada
jr $ra
#-----------------------------------------------------------------------------------------------#
rotate: la $t0, update_rotate #seta label a ser usada como argumento
sw $t0, ARG_LABEL1 #salva o valor do endereco da label no endereco ARG_LABEL1
la $t0, after_rotate #seta label a ser usada como argumento
sw $t0, ARG_LABEL2 #salva o valor do endereco da label no endereco ARG_LABEL2
la $t0, reset_rotate #seta label a ser usada como argumento
sw $t0, ARG_LABEL3 #salva o valor do endereco da label no endereco ARG_LABEL3
addi $sp, $sp, -4
sw $ra, 0($sp)
jal cycle
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
#-----------------------------------------------------------------------------------------------#
left: la $t0, update_left #seta label a ser usada como argumento
sw $t0, ARG_LABEL1 #salva o valor do endereco da label no endereco ARG_LABEL1
la $t0, after_left #seta label a ser usada como argumento
sw $t0, ARG_LABEL2 #salva o valor do endereco da label no endereco ARG_LABEL2
la $t0, reset_left #seta label a ser usada como argumento
sw $t0, ARG_LABEL3 #salva o valor do endereco da label no endereco ARG_LABEL3
addi $sp, $sp, -4
sw $ra, 0($sp)
jal cycle
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
#-----------------------------------------------------------------------------------------------#
right: la $t0, update_right #seta label a ser usada como argumento
sw $t0, ARG_LABEL1 #salva o valor do endereco da label no endereco ARG_LABEL1
la $t0, after_right #seta label a ser usada como argumento
sw $t0, ARG_LABEL2 #salva o valor do endereco da label no endereco ARG_LABEL2
la $t0, reset_right #seta label a ser usada como argumento
sw $t0, ARG_LABEL3 #salva o valor do endereco da label no endereco ARG_LABEL3
addi $sp, $sp, -4
sw $ra, 0($sp)
jal cycle
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
#-----------------------------------------------------------------------------------------------#
down: la $t0, update_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL1 #salva o valor do endereco da label no endereco ARG_LABEL1
la $t0, after_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL2 #salva o valor do endereco da label no endereco ARG_LABEL2
la $t0, reset_down #seta label a ser usada como argumento
sw $t0, ARG_LABEL3 #salva o valor do endereco da label no endereco ARG_LABEL3
addi $sp, $sp, -4
sw $ra, 0($sp)
jal cycle
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
#################################################################################################
cycle: addi $sp, $sp, -4
sw $ra, 0($sp)
jal set_arguments #seta os argumentos com os valores relativos a peca
lw $ra, 0($sp)
addi $sp, $sp, 4
lw $t0, ARG_LABEL1 #carrega metodo de atualizacao a ser chamado
addi $sp, $sp, -4
sw $ra, 0($sp)
jal jal1
jal1: addi $ra, $ra, 8
jr $t0
lw $ra, 0($sp)
addi $sp, $sp, 4
addi $sp, $sp, -20
sw $ra, 16($sp)
sw $a0, 12($sp)
sw $a1, 8($sp)
sw $a2, 4($sp)
sw $a3, 0($sp)
jal collision_check #vai para checagem de colisao
lw $a3, 0($sp)
lw $a2, 4($sp)
lw $a1, 8($sp)
lw $a0, 12($sp)
lw $ra, 16($sp)
addi $sp, $sp, 20
bnez $v0, c_collided #se houver colisao, acaba o ciclo
lw $t0, ARG_LABEL2 #carrega metodo que seta a peca nova de a ser chamado
addi $sp, $sp, -4
sw $ra, 0($sp)
jal jal2
jal2: addi $ra, $ra, 8
jr $t0
lw $ra, 0($sp)
addi $sp, $sp, 4
sll $a3, $a3, 1 #da shift de 1 para esquerda pois o primeiro bit simboliza o tipo do plot
addi $sp, $sp, -20
sw $ra, 16($sp)
sw $a0, 12($sp)
sw $a1, 8($sp)
sw $a2, 4($sp)
sw $a3, 0($sp)
jal plot_piece #plota negativo da peca com valores antigos
lw $a3, 0($sp)
lw $a2, 4($sp)
lw $a1, 8($sp)
lw $a0, 12($sp)
lw $ra, 16($sp)
addi $sp, $sp, 20
lw $t0, ARG_LABEL3 #carrega metodo que seta a peca nova de a ser chamado
addi $sp, $sp, -4
sw $ra, 0($sp)
jal jal3
jal3: addi $ra, $ra, 8
jr $t0
lw $ra, 0($sp)
addi $sp, $sp, 4
addi $sp, $sp, -4
sw $ra, 0($sp)
jal plot_piece #plota o positivo da peca nova
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
c_collided: addiu $v0, $zero, 1
jr $ra
#################################################################################################
update_down: addiu $a1, $a1, 1 #incrementa a posicao y da peca e coloca no registrador a1
jr $ra
#################################################################################################
after_down: addi $t1, $a1, -1 #coloca posicao y anterior em t1
sll $t2, $t1, 3 #coloca a posicao y antiga da peca nos bits certos da abstracao
subu $t2, $s2, $t2 #remove a posicao y antiga da peca
sll $t3, $a1, 3 #coloca a posicao y nova da peca nos bits certos da abstracao
addu $s2, $t2, $t3 #atualiza a peca na posicao certa
jr $ra
#################################################################################################
reset_down: addiu $a1, $a1, 1 #seta a nova posicao y da peca com offset
addiu $a3, $a3, 1 #seta os bits do plot como positivo
jr $ra
#################################################################################################
update_rotate: addiu $a3, $a3, 1 #incrementa a rotacao da peca e coloca no registrador a3
addiu $a1, $a1, 1 #incrementa a posicao y da peca e coloca no registrador a1
jr $ra
#################################################################################################
after_rotate: addi $a3, $a3, -1 #incrementa a rotacao da peca e coloca no registrador a3
addiu $s2, $s2, 16384 #incrementa rotacao
sll $s2, $s2, 16
srl $s2, $s2, 16
jr $ra
#################################################################################################
reset_rotate: addiu $a3, $a3, 3 #nova rotacao com plot positivo
sll $a3, $a3, 29
srl $a3, $a3, 29
jr $ra
#################################################################################################
update_left: addi $a0, $a0, -1 #decrementa a posicao x da peca e coloca no registrador a1
addiu $a1, $a1, 1 #incrementa a posicao y da peca e coloca no registrador a1
jr $ra
#################################################################################################
after_left: addiu $a0, $a0, 1 #incrementa a posicao x
addiu $t1, $a0, 1 #coloca posicao x anterior em t1
sll $t2, $t1, 9 #coloca a posicao x antiga da peca nos bits certos da abstracao
subu $t2, $s2, $t2 #remove a posicao x antiga da peca
sll $t3, $a0, 9 #coloca a posicao x nova da peca nos bits certos da abstracao
addu $s2, $t2, $t3 #atualiza a peca na posicao certa
jr $ra
#################################################################################################
reset_left: subi $a0, $a0, 1 #seta a nova posicao x da peca com offset
addiu $a3, $a3, 1 #seta os bits do plot como positivo
jr $ra
#################################################################################################
update_right: addiu $a0, $a0, 1 #decrementa a posicao x da peca e coloca no registrador a1
addiu $a1, $a1, 1 #incrementa a posicao y da peca e coloca no registrador a1
jr $ra
#################################################################################################
after_right: addi $a0, $a0, -1 #incrementa a posicao x
addi $t1, $a0, -1 #coloca posicao x anterior em t1
sll $t2, $t1, 9 #coloca a posicao x antiga da peca nos bits certos da abstracao
subu $t2, $s2, $t2 #remove a posicao x antiga da peca
sll $t3, $a0, 9 #coloca a posicao x nova da peca nos bits certos da abstracao
addu $s2, $t2, $t3 #atualiza a peca na posicao certa
jr $ra
#################################################################################################
reset_right: addiu $a0, $a0, 1 #seta a nova posicao x da peca com offset
addiu $a3, $a3, 1 #seta os bits do plot como positivo
jr $ra
#################################################################################################
set_arguments: sll $a2, $s2, 29 #isola o tipo da peca no registrador a2 (mais significativo)
srl $a2, $a2, 29 #isola o tipo da peca no registrador a2 (menos significativo)
srl $t0, $s2, 3 #remove o tipo da peca da abstracao de peca
sll $a1, $t0, 26 #isola a posicao y da peca no registrador a1 (mais significativo)
srl $a1, $a1, 26 #isola a posicao y da peca no registrador a1 (menos significativo)
srl $t0, $t0, 6 #remove a posicao y da peca da abstracao de peca
sll $a0, $t0, 27 #isola a posicao x da peca no registrador a0 (mais significativo)
srl $a0, $a0, 27 #isola a posicao x da peca no registrador a0 (menos significativo)
sll $a3, $t0, 25 #isola a rotacao da peca na esquerda
srl $a3, $a3, 30 #isola a rotacao da peca na direita
jr $ra
#################################################################################################
collision_check:addu $v0, $zero, $zero
bltz $a0, collided #se ultrapassou o limite da parede da esquerda, vai para collided
addi $t0, $a2, -1 #decrementa o tipo da peca
sll $t0, $t0, 3 #calcula o offset do endereco da matriz de peca a ser utilizada
sll $t1, $a3, 1 #(offset = 8*tipo_peça + 2*rotação)
addu $t0, $t0, $t1 #offset das half words das pecas
la $t1, L0 #carrega o inicio da matriz das pecas
addu $t1, $t1, $t0 #soma o endereco do inicio da matriz com o offset
lhu $t0, 0($t1) #carrega matriz da peca no registrador t0
addu $t3, $zero, $zero #inicializa contador da peca
addi $t2, $a1, -2 #retira posicoes fantasma
sll $t2, $t2, 2 #calcula offset da linha da matriz do jogo
la $t1, LINE_0 #carrega o inicio da matriz do jogo
add $t1, $t1, $t2 #coloca o endereco da posicao da matriz no registrador t1
li $t2, 3 #seta registrador t3 como 3
mult $a0, $t2 #calcula offset da coluna da matriz do jogo
mflo $t2 #move o resultado do offset para o registrador t2
la $t8, LINE_19 #carrega o endereco da ultima linha da matriz
loop_check: bgeu $t3, 15, end_check #se contador de colunas >= que 16, sai do loop
li $t4, 16 #carrega o imediato 16 no registrador t4
subu $t4, $t4, $t3 #calcula o bit a ser analisado da peca
addi $t4, $t4, -1 #decrementa registrador t4
li $t5, 1 #coloca o imediato 1 no registrador t5
sllv $t4, $t5, $t4 #seta como 1 so o bit a ser analisado da peca
and $t5, $t4, $t0 #checa se a posicao atual na abstracao da peca e' um
beqz $t5, loop_check_1 #se a posicao atual e'nula, continua sem colisao
bgt $t1, $t8, collided #se collidiu com o chão, vai para collided
bgeu $t2, 30, collided #se ultrapassou o limite da parede da esquerda, vai para collided
lw $t6, 0($t1) #carrega linha da matriz
li $t7, 29 #carrega 29 no registrador t7
subu $t7, $t7, $t2 #calcula shift left offset
sllv $t6, $t6, $t7 #limpa valores pra esquerda
srlv $t6, $t6, $t7 #limpa valores pra esquerda
srlv $t6, $t6, $t2 #acaba de isolar bits que salvam se tem uma peca no lugar checado
bnez $t6, collided #se tem uma peca naquele lugar, vai para collided
loop_check_1: addiu $t3, $t3, 1 #incrementa contador da peca
addiu $t2, $t2, 3 #incrementa o offset da coluna na matriz
li $t6, 4 #carrega 4 no registrador $t6
div $t3, $t6 #divide para checar qual linha da peca esta
mfhi $t6 #pega reminder
bnez $t6, loop_check_2 #se nao esta na proxima linha da peca, continua
addiu $t1, $t1, 4 #incrementa endereco t1
li $t2, 3 #seta registrador t3 como 3
mult $a0, $t2 #calcula offset da coluna da matriz do jogo
mflo $t2 #move o resultado do offset para o registrador t2
loop_check_2: j loop_check #vai pra inicio do loop
end_check:
jr $ra
collided: addiu $v0, $zero, 1
jr $ra
#################################################################################################
collision: addi $sp, $sp, -4
sw $ra, 0($sp)
jal set_arguments #seta os argumentos com os valores relativos a peca
lw $ra, 0($sp)
addi $sp, $sp, 4
addi $t0, $a2, -1 #decrementa o tipo da peca
sll $t0, $t0, 3 #calcula o offset do endereco da matriz de peca a ser utilizada
sll $t1, $a3, 1 #(offset = 8*tipo_peça + 2*rotação)
addu $t0, $t0, $t1 #offset das half words das pecas
la $t1, L0 #carrega o inicio da matriz das pecas
addu $t1, $t1, $t0 #soma o endereco do inicio da matriz com o offset
lhu $t0, 0($t1) #carrega matriz da peca no registrador t0
addu $t3, $zero, $zero #inicializa contador da peca
ble $a1, 1, game_end #se a peca esta acima do teto da arena, vai para game_end
addi $a1, $a1, -2 #retira posicoes fantasma
sll $t2, $a1, 2 #calcula offset da linha da matriz do jogo
la $t1, LINE_0 #carrega o inicio da matriz do jogo
add $t1, $t1, $t2 #coloca o endereco da posicao da matriz no registrador t1
la $t8, I_0 #carrega o endereco do inicio dos indexes da matriz
add $t8, $t8, $a1 #coloca o endereco da posicao da matriz no registrador t8
li $t2, 3 #seta registrador t3 como 3
mult $a0, $t2 #calcula offset da coluna da matriz do jogo
mflo $t2 #move o resultado do offset para o registrador t2
loop_save: bgeu $t3, 15, end_loop_save #se contador de colunas >= que 16, sai do loop
li $t4, 16 #carrega o imediato 16 no registrador t4
subu $t4, $t4, $t3 #calcula o bit a ser analisado da peca
addi $t4, $t4, -1 #decrementa registrador t4
li $t5, 1 #coloca o imediato 1 no registrador t5
sllv $t4, $t5, $t4 #seta como 1 so o bit a ser analisado da peca
and $t5, $t4, $t0 #checa se a posicao atual na abstracao da peca e' um
beqz $t5, loop_save_1 #se a posicao atual e'nula, continua sem salvar
addu $t6, $a2, $zero #coloca o valor do tipo da peca no registrador t7
sllv $t6, $t6, $t2 #coloca o valor do tipo no local onde ta o quadrado da peca
lw $t7, 0($t1) #carrega linha da matriz
addu $t7, $t7, $t6 #salva quadrado da peca
sw $t7, 0($t1) #salva linha atualizada na memoria
lbu $t9, 0($t8) #carrega index da linha da matriz
addiu $t9, $t9, 1 #incrementa o index
sb $t9, 0($t8) #salva o index da linha da matriz
loop_save_1: addiu $t3, $t3, 1 #incrementa contador da peca
addiu $t2, $t2, 3 #incrementa o offset da coluna na matriz
li $t6, 4 #carrega 4 no registrador $t6
div $t3, $t6 #divide para checar qual linha da peca esta
mfhi $t6 #pega reminder
bnez $t6, loop_save_2 #se nao esta na proxima linha da peca, continua
addiu $t1, $t1, 4 #incrementa endereco t1
addiu $t8, $t8, 1 #incrementa endereco t8
li $t2, 3 #seta registrador t3 como 3
mult $a0, $t2 #calcula offset da coluna da matriz do jogo
mflo $t2 #move o resultado do offset para o registrador t2
loop_save_2: j loop_save #vai pra inicio do loop
end_loop_save:
addu $s2, $zero, $zero #reseta peca movel
la $t0, I_19 #carrega o endereco do ultimo index da matriz
la $t1, I_0 #carrega o endereco do primeiro index da matriz
la $t2, LINE_19 #carrega o endereco da ultima linha da matriz
la $t3, LINE_0 #carrega o endereco da primeira linha da matriz
loop_l: blt $t0, $t1, collision_end #se ja percorreu os indices da matriz toda, sai do loop
lbu $t4, 0($t0) #carrega o index
bne $t4, 10, loop_l_1 #se a linha nao esta completa, continua sem modificar
addi $sp, $sp, -4
sw $ra, 0($sp) #salva $ra na pilha
jal play_break_line #toca o beep
lw $ra, 0($sp) #pega da pilha
addi $sp, $sp, 4
lhu $t5, SCORE1
addiu $t5, $t5, 100
sh $t5, SCORE1
addiu $t4, $t2, 0 #copia o endereco da linha da matriz
addiu $t5, $t0, 0 #copia o index da linha da matriz
loop_u: bleu $t4, $t3, loop_u_end #se ja percorreu a matriz toda, sai do loop
lw $t6, 0($t4) #carrega linha a ser atualizada
beqz $t6, loop_u_end #se a linha a ser atualizada ja e nula, sai do loop
lw $t6, -4($t4) #carrega linha a ser copiada
sw $t6, 0($t4) #atualiza linha atual
lbu $t6, -1($t5) #carrega index a ser copiado
sb $t6, 0($t5) #atualiza index atual
subu $t7, $t4, $t3 #calcula as diferencas dos enderecos
div $a0, $t7, 4 #seta o argumento com a linha modificada
li $a1, 0 #seta o player
addi $sp, $sp, -28
sw $ra, 0($sp)
sw $t0, 4($sp)
sw $t1, 8($sp)
sw $t2, 12($sp)
sw $t3, 16($sp)
sw $t4, 20($sp)
sw $t5, 24($sp)
jal plot_line
lw $t5, 24($sp)
lw $t4, 20($sp)
lw $t3, 16($sp)
lw $t2, 12($sp)
lw $t1, 8($sp)
lw $t0, 4($sp)
lw $ra, 0($sp)
addi $sp, $sp, 28
loop_u_1: addi $t4, $t4, -4 #seta o endereco da linha pra um acima
addi $t5, $t5, -1 #seta o endereco do index pra um acima
j loop_u
loop_u_end: addiu $t0, $t0, 2 #compensa pela linha que sumiu
addiu $t2, $t2, 8 #compensa pela linha que sumiu
loop_l_1: addi $t0, $t0, -1 #vai para o endereco do index anterior
addi $t2, $t2, -4 #vai para o endereco da linha anterior
j loop_l
collision_end: lhu $a0, SCORE1
li $a1, 0
addi $sp, $sp, -4
sw $ra, 0($sp)
jal write_score
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
game_end: li $a0, 0
addi $sp, $sp, -4
sw $ra, 0($sp)
jal game_over
lw $ra, 0($sp)
addi $sp, $sp, 4
li $s2, 0xFFFFFFFF
jr $ra
#################################################################################################
sys_time: la $v0, STOPWATCH_ADDRESS #seta o codigo do syscall para system time
lw $v0, 0($v0) #chamada do systema para colocar o tempo do sistema no registrador a0
#coloca o valor do retorno no registrador v0
jr $ra
#################################################################################################
rand7: la $v0, STOPWATCH_ADDRESS
lw $a0, 0($v0)
li $t0,7
nop
div $a0,$t0
nop
mfhi $v0
jr $ra
#################################################################################################
######### $a0 = x, $a1 = y, $a2 = tipo, $a3 = rotacao | positivo/negativo
#################################################################################################
plot_piece: li $t1, SIDE
mult $a0, $t1 #calcula a posicao x da peca considerando o tamanho do quadrado
mflo $a0
andi $t0, $s7, 0x00FF0000
srl $t0, $t0, 16 #offset da peca x
add $a0, $a0, $t0
andi $t0, $s7, 0x000000FF
mult $t0, $s3
mflo $t0
add $a0, $a0, $t0
mult $a1, $t1 #calcula posicao y da peca considerando o tamanho do quadrado
mflo $a1
addiu $a1, $a1, OFFSET_Y1 #adiciona offset de inicio da area de jogo
addi $sp, $sp, -20
sw $ra, 16($sp)
sw $a0, 12($sp)
sw $a1, 8($sp)
sw $a2, 4($sp)
sw $a3, 0($sp)
jal plot #plota o negativo da peca antiga (para apagar os vestigios dela)
lw $a3, 0($sp)
lw $a2, 4($sp)
lw $a1, 8($sp)
lw $a0, 12($sp)
lw $ra, 16($sp)
addi $sp, $sp, 20
jr $ra
#################################################################################################
######### A rotina abaixo plota uma peça. Recebe como argumento a localização (x,y),
######### o tipo da peça, a rotação, e o tipo de cor (branca ou colorida).
#################################################################################################
plot: addi $sp, $sp, -16 # Salva os argumentos na pilha
sw $a3, 12($sp)
sw $a2, 8($sp)
sw $a1, 4($sp)
sw $a0, 0($sp)
sll $t3, $a3, 31 # Extrai o bit de codificacao da cor
srl $t3, $t3, 31 # Extrai o bit de codificacao da cor
srl $a3, $a3, 1 # Remove bit de codificacao
addi $t6, $a2, -1 # Decrementa tipo
sll $t6, $t6, 3 # Calcula o offset do endereco da matriz a ser utilizada
sll $a3, $a3, 1 # (offset = 8*tipo_peça + 2*rotação)
add $t6, $t6, $a3
la $t7, L0 # Carrega endereço inicial das matrizes das peças
add $t7, $t7, $t6 # Faz end = end_inicial + offset
lhu $t6, 0($t7) # Carrega a matriz a ser utilizada
li $t2, 4 # Tamanho da matriz
move $t7, $zero # Inicializa i
move $t0, $zero # Inicializa contador
# Os blocos abaixo definem a cor do plot
beqz $t3, color_black
beqz $a2, sai_plot0
beq $a2, 1, color_orange
beq $a2, 2, color_cyan
beq $a2, 3, color_blue
beq $a2, 4, color_purple
beq $a2, 5, color_green
beq $a2, 6, color_red
beq $a2, 7, color_yellow
color_red: li $a3, RED
j loop_plot0
color_cyan: li $a3, CYAN
j loop_plot0
color_green: li $a3, GREEN
j loop_plot0
color_yellow: li $a3, YELLOW
j loop_plot0
color_blue: li $a3, DARK_BLUE
j loop_plot0
color_purple: li $a3, PURPLE
j loop_plot0
color_orange: li $a3, ORANGE
j loop_plot0
color_black: li $a3, BLACK
# Loop de plot da matriz
loop_plot0: beq $t0, $t2, sai_plot0 # Se i = 4, sai
move $t1, $zero # Inicializa j
loop_plot1: beq $t1, $t2, sai_plot1 # Se j = 4, sai
sllv $t5, $t6, $t7 # Extrai o bit na posição (i,j) da matriz
sll $t5, $t5, 16
srl $t5, $t5, 31
beq $t5, $zero, pass0 # Se bit = 0, pula o proximo bloco
addi $sp, $sp, -16 # Salva na pilha as variáveis que estão sendo utilizadas
sw $ra, 12($sp)
sw $t0, 8($sp)
sw $t1, 4($sp)
sw $t2, 0($sp)
jal plot_square # Plota quadrado
lw $t2, 0($sp) # Recupera as variáveis temporárias da pilha
lw $t1, 4($sp)
lw $t0, 8($sp)
lw $ra, 12($sp)
addi $sp, $sp, 16
pass0: addi $t1, $t1, 1 # Incrementa j
addi $a0, $a0, SIDE # Incrementa posição de plot em x
addi $t7, $t7, 1 # Incrementa contador
j loop_plot1
sai_plot1: addi $t0, $t0, 1 # Incrementa i
addi $a1, $a1, SIDE # Incrementa posição de plot em y
addi $a0, $a0, -28 # Volta para a posição inicial de plot em x
j loop_plot0
sai_plot0: lw $a0, 0($sp)
lw $a1, 4($sp)
lw $a2, 8($sp)
lw $a3, 12($sp)
addi $sp, $sp, 16
jr $ra
#################################################################################################
######### A rotina abaixo plota uma linha da matriz de jogo. Recebe como argumento a
######### linha que vai ser plotada e o player.
#################################################################################################
plot_line: addi $sp, $sp, -16 # Salva os argumentos na pilha
sw $a3, 12($sp)
sw $a2, 8($sp)
sw $a1, 4($sp)
sw $a0, 0($sp)
sll $t0, $a0, 2
la $t9, LINE_0
add $t0, $t0, $t9 # endereco da linha a ser plotada
lw $t0, 0($t0) # carrega a linha a ser plotada
andi $t3, $s7, 0x00FF0000
srl $t3, $t3, 16
andi $t4, $s7, 0x000000FF
mult $t4, $s3
mflo $t4
add $t3, $t3, $t4
addi $t4, $zero, SIDE # calcula a posição da linha em y
mult $t4, $a0
mflo $t4
addi $a1, $t4, PAR_Y0
move $t1, $zero # inicializa o contador de pixels
loop_line: bge $t1, 70, end_line
andi $t2, $t0, 0x07
srl $t0, $t0, 3
beq $t2, $zero, lcolor_black
beq $t2, 1, lcolor_orange
beq $t2, 2, lcolor_cyan
beq $t2, 3, lcolor_blue
beq $t2, 4, lcolor_purple
beq $t2, 5, lcolor_green
beq $t2, 6, lcolor_red
beq $t2, 7, lcolor_yellow
lcolor_black: li $a3, BLACK
j loop_plot_line
lcolor_red: li $a3, RED
j loop_plot_line
lcolor_cyan: li $a3, CYAN
j loop_plot_line
lcolor_green: li $a3, GREEN
j loop_plot_line
lcolor_yellow: li $a3, YELLOW
j loop_plot_line
lcolor_blue: li $a3, DARK_BLUE
j loop_plot_line
lcolor_purple: li $a3, PURPLE
j loop_plot_line
lcolor_orange: li $a3, ORANGE
loop_plot_line: addi $sp, $sp, -24 # Salva na pilha as variáveis que estão sendo utilizadas
sw $a0, 20($sp)
sw $ra, 16($sp)
sw $t0, 12($sp)
sw $t1, 8($sp)
sw $t2, 4($sp)
sw $t3, 0($sp)
add $a0, $t3, $t1
jal plot_square # Plota quadrado
lw $t3, 0($sp)
lw $t2, 4($sp) # Recupera as variáveis temporárias da pilha
lw $t1, 8($sp)
lw $t0, 12($sp)
lw $ra, 16($sp)
lw $a0, 20($sp)
addi $sp, $sp, 24
addi $t1, $t1, SIDE
j loop_line
end_line: lw $a0, 0($sp)
lw $a1, 4($sp)
lw $a2, 8($sp)
lw $a3, 12($sp)
addi $sp, $sp, 16
jr $ra
#################################################################################################
######### A rotina abaixo plota uma matriz de jogo. Recebe como argumentos
######### $a0 = endereco da linha inicial, $a1 = jogador (0 a 3), $a2 = endereco da linha final
#################################################################################################
plot_matrix: bgt $a0, $a2, fim_plot_mat
addi $sp, $sp, -4
sw $ra, 0($sp)
jal plot_line
lw $ra, 0($sp)
addi $sp, $sp, 4
addi, $a0, $a0, 1