build.gradle

/*
 * Copyright 2013 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'groovy'
apply from: 'gradle/vertx.gradle'
apply from: 'gradle/setup.gradle'

defaultTasks = ['assemble']

sourceCompatibility = '1.7'
targetCompatibility = '1.7'

jar.enabled = false // We don't produce a jar

repositories {
  maven { url 'https://repo.eclipse.org/content/repositories/snapshots' }
  maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
  mavenCentral()
}

configurations {
  provided
  compile.extendsFrom provided
}

dependencies {
  provided    "io.vertx:vertx-core:$vertxVersion"
  provided    "io.vertx:vertx-platform:$vertxVersion"
  provided    "io.vertx:lang-groovy:$vertxVersion@jar"
  provided    "org.codehaus.groovy:groovy-all:$groovyVersion"

  compile     "org.slf4j:slf4j-log4j12:$slf4jVersion"
  compile     "log4j:log4j:$log4jVersion"
  compile     "org.eclipse.paho:mqtt-client:$pahoVersion"

  testCompile "junit:junit:$junitVersion"
  testCompile "io.vertx:testtools:$vertxToolsVersion"

}

test {
  systemProperty 'vertx.mods', 'build/mods'
  systemProperty 'vertx.test.timeout', 60
  
  // classpath -= configurations.provided
  outputs.upToDateWhen { false }

  // Show output
  testLogging.showStandardStreams = true
  testLogging { exceptionFormat "full" }
}

task publishSnapshot(dependsOn: ['clean','check','publishMavenPublicationToSnapshotsRepository']) {
  description = 'Publish to Maven Central (Snapshot) Repo'
  group = 'vert.x'
}

task publishRelease(dependsOn: ['clean','check','publishMavenPublicationToStagingRepository']) {
  description = 'Publish to Maven Central (Staging) Repo'
  group = 'vert.x'

}