build.gradle

/*
 * Copyright (c) 2020-2021, Koninklijke Philips N.V., https://www.philips.com
 * SPDX-License-Identifier: MIT
 */
buildscript {
  repositories {
    mavenCentral()
  }
  dependencies {
    classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.24.14"
  }
}

plugins {
    id 'application'
    id 'com.adarshr.test-logger' version '3.0.0'
}

repositories {
    maven { url 'https://plugins.gradle.org/m2/' }
    mavenCentral()
}

ext {
    jacksonVersion = '2.12.4'
    junitVersion = '5.7.2'
    mockWebServerVersion = '4.9.1'
    retrofitVersion = '2.9.0'
}

dependencies {
    implementation "info.picocli:picocli:4.6.1"
    implementation "pl.tlinkowski.annotation:pl.tlinkowski.annotation.basic:0.2.0"
    implementation 'com.google.code.findbugs:jsr305:3.0.2'
    implementation "com.squareup.retrofit2:retrofit:${retrofitVersion}"
    implementation "com.squareup.retrofit2:converter-jackson:${retrofitVersion}"
    implementation "com.fasterxml.jackson.core:jackson-databind:${jacksonVersion}"
    implementation "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:${jacksonVersion}"
    implementation "com.github.package-url:packageurl-java:1.4.0"

    testImplementation "com.squareup.okhttp3:mockwebserver:${mockWebServerVersion}"
    testImplementation "org.json:json:20210307"
    testImplementation "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
    testImplementation "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
    testImplementation "org.assertj:assertj-core:3.20.2"
    testImplementation "org.mockito:mockito-core:3.11.2"
    testImplementation "nl.jqno.equalsverifier:equalsverifier:3.7"
}

testlogger {
    theme 'mocha'
}

test {
    useJUnitPlatform()
}

application {
    mainClass = 'com.philips.research.spdxbuilder.SpdxBuilder'
}

jar {
    manifest {
        attributes(
                'Main-Class': 'com.philips.research.spdxbuilder.SpdxBuilder',
                'Implementation-Title': 'SPDX-Builder',
                'Implementation-Version': 'v0.8.0'
        )
    }
    from { configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) } }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
}

version = 'v0.8.0'