noconfig.pri

CONFIG += c++17

CONFIG += release

PREFIX_PATH = /usr/local

INCLUDEPATH += $$PWD/vamp-plugin-sdk

win32-msvc* {

    DEPLOYDIR = $$PWD/deploy/win64

    INCLUDEPATH += $$PWD/../boost_1_85_0/ $$PWD/sv-dependency-builds/win64-msvc/include
    LIBS += -L$$PWD -L$$PWD/sv-dependency-builds/win64-msvc/lib

    CONFIG(release) {
        LIBS += -NODEFAULTLIB:MSVCRT -Lrelease
    }

    DEFINES += NOMINMAX _USE_MATH_DEFINES HAVE_C99_VARARGS_MACROS

    DEFINES += AVOID_WINRT_DEPENDENCY
}

macx* {

    # All Mac builds are 64-bit these days.

    DEPLOYDIR = $$PWD/deploy/osx

    INCLUDEPATH += /opt/boost/include /usr/local/opt/boost/include $$PWD/sv-dependency-builds/osx/include
    LIBS += -L$$PWD -L$$PWD/sv-dependency-builds/osx/lib

    QMAKE_CXXFLAGS_RELEASE += -O3
    QMAKE_LFLAGS_RELEASE += -O3
}

linux* {

    DEPLOYDIR = $$PWD/deploy/linux

    INCLUDEPATH += $$PWD/sv-dependency-builds/src/serd-0.18.2 $$PWD/sv-dependency-builds/src/sord-0.12.0
    
    QMAKE_CXXFLAGS_RELEASE += -O3
    QMAKE_LFLAGS_RELEASE += -O3 -Wl,--no-undefined
}