rollback mutter-x11-scaling to 44.5

manifest

@@ -219,7 +219,6 @@ export AUR_PACKAGES="\
 	libretro-stella2014-git \
 	libretro-virtualjaguar-git \
 	libextest-git \
-	mutter-x11-scaling \
 	nintendo-udev \
 	opengamepadui-bin \
 	opengamepadui-session-git \

pkgs/mutter-x11-scaling/PKGBUILD

@@ -0,0 +1,126 @@
+# Maintainer: Georg Wagner <puxplaying_at_gmail_dot_com>
+# Contributor: @xabbu <https://github.com/xabbu>
+# Contributor: Stefano Capitani <stefano_at_manjaro_dot_org>
+# Contributor: Mark Wagie <mark_at_manjaro_dot_org>
+# Contributor: Jonathon Fernyhough
+# Contributor: realqhc <https://github.com/realqhc>
+
+# Archlinux credits:
+# Maintainer: Jan Alexander Steffens (heftig) <[email protected]>
+# Contributor: Ionut Biru <[email protected]>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+# Ubuntu credits:
+# Marco Trevisan: <https://salsa.debian.org/gnome-team/mutter/-/blob/ubuntu/master/debian/patches/ubuntu/x11-Add-support-for-fractional-scaling-using-Randr.patch>
+
+pkgname=mutter-x11-scaling
+pkgver=44.5
+pkgrel=1
+pkgdesc="Window manager and compositor for GNOME with X11 fractional scaling patch"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(
+  colord
+  dconf
+  gnome-desktop-4
+  gnome-settings-daemon
+  graphene
+  gsettings-desktop-schemas
+  iio-sensor-proxy
+  lcms2
+  libcanberra
+  libgudev
+  libinput
+  libsm
+  libsysprof-capture
+  libxkbcommon-x11
+  libxkbfile
+  pipewire
+  startup-notification
+  xorg-xwayland
+)
+makedepends=(
+  egl-wayland
+  gi-docgen
+  git
+  gobject-introspection
+  gtk3
+  meson
+  sysprof
+  wayland-protocols
+  xorg-server
+  xorg-server-xvfb
+)
+checkdepends=(
+  python-dbusmock
+  wireplumber
+  zenity
+)
+provides=(mutter=$pkgver libmutter-12.so)
+conflicts=(mutter)
+_commit=1511e6e1cdc8fa1a84f6fbbb169777ac26ba7f44  # tags/44.5^0
+_scaling_commit=c71847d5e7f2e08e8bf4e81257c24bbcd422d355
+source=(
+  "git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit"
+  "https://salsa.debian.org/gnome-team/mutter/-/raw/$_scaling_commit/debian/patches/ubuntu/x11-Add-support-for-fractional-scaling-using-Randr.patch"
+)
+b2sums=('SKIP'
+        'b35c478f8cdf2cd47e70ce593ec1f36c1c8ba7756bf806ab9c1e94b75ac02ab828e9d11aea41c7b811e3496cc739d211c002ce35539b9b0ba71cbf447e4cfb3b')
+
+pkgver() {
+  cd mutter
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd mutter
+
+  # Unbreak tests with Mesa 23.1
+  # https://gitlab.gnome.org/GNOME/mutter/-/issues/2848
+  # https://gitlab.gnome.org/GNOME/mutter/-/merge_requests/3047
+  git cherry-pick -n '5a83e8ef8250526a40e8e69c^..d65883e0d7d70987e3888b86'
+
+  # Add scaling support using randr under x11
+  patch -p1 -i "${srcdir}/x11-Add-support-for-fractional-scaling-using-Randr.patch"
+}
+
+build() {
+  local meson_options=(
+    -D docs=false
+    -D egl_device=true
+    -D installed_tests=false
+    -D wayland_eglstream=true
+  )
+
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+
+  arch-meson mutter build "${meson_options[@]}"
+  meson compile -C build
+}
+
+_check() (
+  export XDG_RUNTIME_DIR="$PWD/rdir" GSETTINGS_SCHEMA_DIR="$PWD/build/data"
+  mkdir -p -m 700 "$XDG_RUNTIME_DIR"
+  glib-compile-schemas "$GSETTINGS_SCHEMA_DIR"
+
+  pipewire &
+  _p1=$!
+
+  wireplumber &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  #meson test -C build --print-errorlogs -t 3 || :
+)
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}