Provided the instructions on how to install the PWMServoDriver library.

Adafruit PWMServoDriver/.github/ISSUE_TEMPLATE.md

@@ -0,0 +1,46 @@
+Thank you for opening an issue on an Adafruit Arduino library repository.  To
+improve the speed of resolution please review the following guidelines and
+common troubleshooting steps below before creating the issue:
+
+- **Do not use GitHub issues for troubleshooting projects and issues.**  Instead use
+  the forums at http://forums.adafruit.com to ask questions and troubleshoot why
+  something isn't working as expected.  In many cases the problem is a common issue
+  that you will more quickly receive help from the forum community.  GitHub issues
+  are meant for known defects in the code.  If you don't know if there is a defect
+  in the code then start with troubleshooting on the forum first.
+
+- **If following a tutorial or guide be sure you didn't miss a step.** Carefully
+  check all of the steps and commands to run have been followed.  Consult the
+  forum if you're unsure or have questions about steps in a guide/tutorial.
+
+- **For Arduino projects check these very common issues to ensure they don't apply**:
+
+  - For uploading sketches or communicating with the board make sure you're using
+    a **USB data cable** and **not** a **USB charge-only cable**.  It is sometimes
+    very hard to tell the difference between a data and charge cable!  Try using the
+    cable with other devices or swapping to another cable to confirm it is not
+    the problem.
+
+  - **Be sure you are supplying adequate power to the board.**  Check the specs of
+    your board and plug in an external power supply.  In many cases just
+    plugging a board into your computer is not enough to power it and other
+    peripherals.
+
+  - **Double check all soldering joints and connections.**  Flakey connections
+    cause many mysterious problems.  See the [guide to excellent soldering](https://learn.adafruit.com/adafruit-guide-excellent-soldering/tools) for examples of good solder joints.
+
+  - **Ensure you are using an official Arduino or Adafruit board.** We can't
+    guarantee a clone board will have the same functionality and work as expected
+    with this code and don't support them.
+
+If you're sure this issue is a defect in the code and checked the steps above
+please fill in the following fields to provide enough troubleshooting information.
+You may delete the guideline and text above to just leave the following details:
+
+- Arduino board:  **INSERT ARDUINO BOARD NAME/TYPE HERE**
+
+- Arduino IDE version (found in Arduino -> About Arduino menu):  **INSERT ARDUINO
+  VERSION HERE**
+
+- List the steps to reproduce the problem below (if possible attach a sketch or
+  copy the sketch code in too): **LIST REPRO STEPS BELOW**

Adafruit PWMServoDriver/.github/PULL_REQUEST_TEMPLATE.md

@@ -0,0 +1,26 @@
+Thank you for creating a pull request to contribute to Adafruit's GitHub code!
+Before you open the request please review the following guidelines and tips to
+help it be more easily integrated:
+
+- **Describe the scope of your change--i.e. what the change does and what parts
+  of the code were modified.**  This will help us understand any risks of integrating
+  the code.
+
+- **Describe any known limitations with your change.**  For example if the change
+  doesn't apply to a supported platform of the library please mention it.
+
+- **Please run any tests or examples that can exercise your modified code.**  We
+  strive to not break users of the code and running tests/examples helps with this
+  process.
+
+Thank you again for contributing!  We will try to test and integrate the change
+as soon as we can, but be aware we have many GitHub repositories to manage and
+can't immediately respond to every request.  There is no need to bump or check in
+on a pull request (it will clutter the discussion of the request).
+
+Also don't be worried if the request is closed or not integrated--sometimes the
+priorities of Adafruit's GitHub code (education, ease of use) might not match the
+priorities of the pull request.  Don't fret, the open source community thrives on
+forks and GitHub makes it easy to keep your changes in a forked repo.
+
+After reviewing the guidelines above you can delete this text from the pull request.

Adafruit PWMServoDriver/Adafruit_PWMServoDriver.cpp

@@ -0,0 +1,132 @@
+/*************************************************** 
+  This is a library for our Adafruit 16-channel PWM & Servo driver
+
+  Pick one up today in the adafruit shop!
+  ------> http://www.adafruit.com/products/815
+
+  These displays use I2C to communicate, 2 pins are required to  
+  interface. For Arduino UNOs, thats SCL -> Analog 5, SDA -> Analog 4
+
+  Adafruit invests time and resources providing this open source code, 
+  please support Adafruit and open-source hardware by purchasing 
+  products from Adafruit!
+
+  Written by Limor Fried/Ladyada for Adafruit Industries.  
+  BSD license, all text above must be included in any redistribution
+ ****************************************************/
+
+#include <Adafruit_PWMServoDriver.h>
+#include <Wire.h>
+#if defined(ARDUINO_SAM_DUE)
+ #define WIRE Wire1
+#else
+ #define WIRE Wire
+#endif
+
+
+// Set to true to print some debug messages, or false to disable them.
+#define ENABLE_DEBUG_OUTPUT false
+
+Adafruit_PWMServoDriver::Adafruit_PWMServoDriver(uint8_t addr) {
+  _i2caddr = addr;
+}
+
+void Adafruit_PWMServoDriver::begin(void) {
+ WIRE.begin();
+ reset();
+}
+
+
+void Adafruit_PWMServoDriver::reset(void) {
+ write8(PCA9685_MODE1, 0x0);
+}
+
+void Adafruit_PWMServoDriver::setPWMFreq(float freq) {
+  //Serial.print("Attempting to set freq ");
+  //Serial.println(freq);
+  freq *= 0.9;  // Correct for overshoot in the frequency setting (see issue #11).
+  float prescaleval = 25000000;
+  prescaleval /= 4096;
+  prescaleval /= freq;
+  prescaleval -= 1;
+  if (ENABLE_DEBUG_OUTPUT) {
+    //Serial.print("Estimated pre-scale: "); Serial.println(prescaleval);
+  }
+  uint8_t prescale = floor(prescaleval + 0.5);
+  if (ENABLE_DEBUG_OUTPUT) {
+    //Serial.print("Final pre-scale: "); Serial.println(prescale);
+  }
+
+  uint8_t oldmode = read8(PCA9685_MODE1);
+  uint8_t newmode = (oldmode&0x7F) | 0x10; // sleep
+  write8(PCA9685_MODE1, newmode); // go to sleep
+  write8(PCA9685_PRESCALE, prescale); // set the prescaler
+  write8(PCA9685_MODE1, oldmode);
+  delay(5);
+  write8(PCA9685_MODE1, oldmode | 0xa1);  //  This sets the MODE1 register to turn on auto increment.
+                                          // This is why the beginTransmission below was not working.
+  //  Serial.print("Mode now 0x"); Serial.println(read8(PCA9685_MODE1), HEX);
+}
+
+void Adafruit_PWMServoDriver::setPWM(uint8_t num, uint16_t on, uint16_t off) {
+  //Serial.print("Setting PWM "); Serial.print(num); Serial.print(": "); Serial.print(on); Serial.print("->"); Serial.println(off);
+
+  WIRE.beginTransmission(_i2caddr);
+  WIRE.write(LED0_ON_L+4*num);
+  WIRE.write(on);
+  WIRE.write(on>>8);
+  WIRE.write(off);
+  WIRE.write(off>>8);
+  WIRE.endTransmission();
+}
+
+// Sets pin without having to deal with on/off tick placement and properly handles
+// a zero value as completely off.  Optional invert parameter supports inverting
+// the pulse for sinking to ground.  Val should be a value from 0 to 4095 inclusive.
+void Adafruit_PWMServoDriver::setPin(uint8_t num, uint16_t val, bool invert)
+{
+  // Clamp value between 0 and 4095 inclusive.
+  val = min(val, 4095);
+  if (invert) {
+    if (val == 0) {
+      // Special value for signal fully on.
+      setPWM(num, 4096, 0);
+    }
+    else if (val == 4095) {
+      // Special value for signal fully off.
+      setPWM(num, 0, 4096);
+    }
+    else {
+      setPWM(num, 0, 4095-val);
+    }
+  }
+  else {
+    if (val == 4095) {
+      // Special value for signal fully on.
+      setPWM(num, 4096, 0);
+    }
+    else if (val == 0) {
+      // Special value for signal fully off.
+      setPWM(num, 0, 4096);
+    }
+    else {
+      setPWM(num, 0, val);
+    }
+  }
+}
+
+uint8_t Adafruit_PWMServoDriver::read8(uint8_t addr) {
+  WIRE.beginTransmission(_i2caddr);
+  WIRE.write(addr);
+  WIRE.endTransmission();
+
+  WIRE.requestFrom((uint8_t)_i2caddr, (uint8_t)1);
+  return WIRE.read();
+}
+
+void Adafruit_PWMServoDriver::write8(uint8_t addr, uint8_t d) {
+  WIRE.beginTransmission(_i2caddr);
+  WIRE.write(addr);
+  WIRE.write(d);
+  WIRE.endTransmission();
+}

Adafruit PWMServoDriver/Adafruit_PWMServoDriver.h

@@ -0,0 +1,62 @@
+/*************************************************** 
+  This is a library for our Adafruit 16-channel PWM & Servo driver
+
+  Pick one up today in the adafruit shop!
+  ------> http://www.adafruit.com/products/815
+
+  These displays use I2C to communicate, 2 pins are required to  
+  interface. For Arduino UNOs, thats SCL -> Analog 5, SDA -> Analog 4
+
+  Adafruit invests time and resources providing this open source code, 
+  please support Adafruit and open-source hardware by purchasing 
+  products from Adafruit!
+
+  Written by Limor Fried/Ladyada for Adafruit Industries.  
+  BSD license, all text above must be included in any redistribution
+ ****************************************************/
+
+#ifndef _ADAFRUIT_PWMServoDriver_H
+#define _ADAFRUIT_PWMServoDriver_H
+
+#if ARDUINO >= 100
+ #include "Arduino.h"
+#else
+ #include "WProgram.h"
+#endif
+
+
+#define PCA9685_SUBADR1 0x2
+#define PCA9685_SUBADR2 0x3
+#define PCA9685_SUBADR3 0x4
+
+#define PCA9685_MODE1 0x0
+#define PCA9685_PRESCALE 0xFE
+
+#define LED0_ON_L 0x6
+#define LED0_ON_H 0x7
+#define LED0_OFF_L 0x8
+#define LED0_OFF_H 0x9
+
+#define ALLLED_ON_L 0xFA
+#define ALLLED_ON_H 0xFB
+#define ALLLED_OFF_L 0xFC
+#define ALLLED_OFF_H 0xFD
+
+
+class Adafruit_PWMServoDriver {
+ public:
+  Adafruit_PWMServoDriver(uint8_t addr = 0x40);
+  void begin(void);
+  void reset(void);
+  void setPWMFreq(float freq);
+  void setPWM(uint8_t num, uint16_t on, uint16_t off);
+  void setPin(uint8_t num, uint16_t val, bool invert=false);
+
+ private:
+  uint8_t _i2caddr;
+
+  uint8_t read8(uint8_t addr);
+  void write8(uint8_t addr, uint8_t d);
+};
+
+#endif

Adafruit PWMServoDriver/README.md

@@ -0,0 +1,51 @@
+This is a library for our Adafruit 16-channel PWM & Servo driver
+
+  Pick one up today in the adafruit shop!
+  ------> http://www.adafruit.com/products/815
+
+These displays use I2C to communicate, 2 pins are required to  
+interface. For Arduinos, thats SCL -> Analog 5, SDA -> Analog 4
+
+Adafruit invests time and resources providing this open source code, 
+please support Adafruit and open-source hardware by purchasing 
+products from Adafruit!
+
+Written by Limor Fried/Ladyada  for Adafruit Industries.  
+BSD license, check license.txt for more information
+All text above must be included in any redistribution
+
+To download. click the DOWNLOADS button in the top right corner, rename the uncompressed folder Adafruit_PWMServoDriver. Check that the Adafruit_PWMServoDriver folder contains Adafruit_PWMServoDriver.cpp and Adafruit_PWMServoDriver.h
+
+Place the Adafruit_PWMServoDriver library folder your <arduinosketchfolder>/libraries/ folder. You may need to create the libraries subfolder if its your first library. Restart the IDE.
+
+<!-- START COMPATIBILITY TABLE -->
+
+## Compatibility
+
+MCU                | Tested Works | Doesn't Work | Not Tested  | Notes
+------------------ | :----------: | :----------: | :---------: | -----
+Atmega328 @ 16MHz  |      X       |             |            | 
+Atmega328 @ 12MHz  |      X       |             |            | 
+Atmega32u4 @ 16MHz |      X       |             |            | 
+Atmega32u4 @ 8MHz  |      X       |             |            | 
+ESP8266            |      X       |             |            | 
+Atmega2560 @ 16MHz |      X       |             |            | 
+ATSAM3X8E          |      X       |             |            | Use SDA1/SCL1
+ATSAM21D           |      X       |             |            | 
+ATtiny85 @ 16MHz   |      X       |             |            | 
+ATtiny85 @ 8MHz    |      X       |             |            | 
+Intel Curie @ 32MHz |             |             |     X       | 
+STM32F2            |             |             |     X       | 
+
+  * ATmega328 @ 16MHz : Arduino UNO, Adafruit Pro Trinket 5V, Adafruit Metro 328, Adafruit Metro Mini
+  * ATmega328 @ 12MHz : Adafruit Pro Trinket 3V
+  * ATmega32u4 @ 16MHz : Arduino Leonardo, Arduino Micro, Arduino Yun, Teensy 2.0
+  * ATmega32u4 @ 8MHz : Adafruit Flora, Bluefruit Micro
+  * ESP8266 : Adafruit Huzzah
+  * ATmega2560 @ 16MHz : Arduino Mega
+  * ATSAM3X8E : Arduino Due
+  * ATSAM21D : Arduino Zero, M0 Pro
+  * ATtiny85 @ 16MHz : Adafruit Trinket 5V
+  * ATtiny85 @ 8MHz : Adafruit Gemma, Arduino Gemma, Adafruit Trinket 3V
+
+<!-- END COMPATIBILITY TABLE -->

Adafruit PWMServoDriver/examples/pwmtest/pwmtest.pde

@@ -0,0 +1,61 @@
+/*************************************************** 
+  This is an example for our Adafruit 16-channel PWM & Servo driver
+  PWM test - this will drive 16 PWMs in a 'wave'
+
+  Pick one up today in the adafruit shop!
+  ------> http://www.adafruit.com/products/815
+
+  These displays use I2C to communicate, 2 pins are required to  
+  interface. For Arduino UNOs, thats SCL -> Analog 5, SDA -> Analog 4
+
+  Adafruit invests time and resources providing this open source code, 
+  please support Adafruit and open-source hardware by purchasing 
+  products from Adafruit!
+
+  Written by Limor Fried/Ladyada for Adafruit Industries.  
+  BSD license, all text above must be included in any redistribution
+ ****************************************************/
+
+#include <Wire.h>
+#include <Adafruit_PWMServoDriver.h>
+
+// called this way, it uses the default address 0x40
+Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver();
+// you can also call it with a different address you want
+//Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver(0x41);
+
+#if defined(ARDUINO_ARCH_SAMD)  
+// for Zero, output on USB Serial console, remove line below if using programming port to program the Zero!
+   #define Serial SerialUSB
+#endif
+
+void setup() {
+#ifdef ESP8266
+  Wire.pins(2, 14);   // ESP8266 can use any two pins, such as SDA to #2 and SCL to #14
+#endif
+
+  Serial.begin(9600);
+  Serial.println("16 channel PWM test!");
+
+  pwm.begin();
+  pwm.setPWMFreq(1600);  // This is the maximum PWM frequency
+
+  // if you want to really speed stuff up, you can go into 'fast 400khz I2C' mode
+  // some i2c devices dont like this so much so if you're sharing the bus, watch
+  // out for this!
+#ifdef TWBR    
+  // save I2C bitrate
+  uint8_t twbrbackup = TWBR;
+  // must be changed after calling Wire.begin() (inside pwm.begin())
+  TWBR = 12; // upgrade to 400KHz!
+#endif
+}
+
+void loop() {
+  // Drive each PWM in a 'wave'
+  for (uint16_t i=0; i<4096; i += 8) {
+    for (uint8_t pwmnum=0; pwmnum < 16; pwmnum++) {
+      pwm.setPWM(pwmnum, 0, (i + (4096/16)*pwmnum) % 4096 );
+    }
+  }
+}