Add era-independent "debug transaction view" command

cardano-cli/cardano-cli.cabal

@@ -60,6 +60,7 @@ library
     Cardano.CLI.Commands
     Cardano.CLI.Commands.Debug
     Cardano.CLI.Commands.Debug.LogEpochState
+    Cardano.CLI.Commands.Debug.TransactionView
     Cardano.CLI.Commands.Hash
     Cardano.CLI.Commands.Ping
     Cardano.CLI.Environment
@@ -155,6 +156,7 @@ library
     Cardano.CLI.Run
     Cardano.CLI.Run.Debug
     Cardano.CLI.Run.Debug.LogEpochState
+    Cardano.CLI.Run.Debug.TransactionView
     Cardano.CLI.Run.Hash
     Cardano.CLI.Run.Ping
     Cardano.CLI.TopHandler
@@ -164,6 +166,7 @@ library
     Cardano.CLI.Types.Errors.BootstrapWitnessError
     Cardano.CLI.Types.Errors.CardanoAddressSigningKeyConversionError
     Cardano.CLI.Types.Errors.CmdError
+    Cardano.CLI.Types.Errors.DebugCmdError
     Cardano.CLI.Types.Errors.DelegationError
     Cardano.CLI.Types.Errors.GenesisCmdError
     Cardano.CLI.Types.Errors.GovernanceActionsError

cardano-cli/src/Cardano/CLI/Commands/Debug.hs

@@ -4,6 +4,8 @@ module Cardano.CLI.Commands.Debug
 where
 
 import           Cardano.CLI.Commands.Debug.LogEpochState
+import           Cardano.CLI.Commands.Debug.TransactionView
 
-newtype DebugCmds
+data DebugCmds
   = DebugLogEpochStateCmd LogEpochStateCmdArgs
+  | DebugTransactionViewCmd TransactionViewCmdArgs

cardano-cli/src/Cardano/CLI/Commands/Debug/TransactionView.hs

@@ -0,0 +1,12 @@
+{-# LANGUAGE DataKinds #-}
+
+module Cardano.CLI.Commands.Debug.TransactionView where
+
+import           Cardano.CLI.Types.Common
+
+data TransactionViewCmdArgs = TransactionViewCmdArgs
+  { outputFormat :: !ViewOutputFormat
+  , mOutFile :: !(Maybe (File () Out))
+  , inputTxBodyOrTxFile :: !InputTxBodyOrTxFile
+  }
+  deriving Show

cardano-cli/src/Cardano/CLI/Options/Debug.hs

@@ -15,6 +15,7 @@ import           Cardano.Api.Shelley hiding (QueryInShelleyBasedEra (..))
 
 import           Cardano.CLI.Commands.Debug
 import           Cardano.CLI.Commands.Debug.LogEpochState
+import           Cardano.CLI.Commands.Debug.TransactionView
 import           Cardano.CLI.Environment
 import           Cardano.CLI.EraBased.Options.Common
 
@@ -45,6 +46,13 @@ pDebugCmds envCli =
               , " The log file format is line delimited JSON."
               , " The command will not terminate."
               ]
+    , subParser "transaction" $
+        Opt.info
+          ( asum
+              [ subParser "view" (Opt.info pTransactionView $ Opt.progDesc "Print a transaction.")
+              ]
+          )
+          (Opt.progDesc "Transaction commands")
     ]
  where
   pLogEpochStateCmdArgs :: Parser DebugCmds
@@ -56,6 +64,13 @@ pDebugCmds envCli =
         <*> pFileOutDirection
           "out-file"
           "Output filepath of the log file.  The log file format is line delimited JSON."
+  pTransactionView :: Parser DebugCmds
+  pTransactionView =
+    fmap DebugTransactionViewCmd $
+      TransactionViewCmdArgs
+        <$> pTxViewOutputFormat
+        <*> pMaybeOutputFile
+        <*> pInputTxOrTxBodyFile
 
 pNodeConfigurationFileIn :: Parser (NodeConfigFile In)
 pNodeConfigurationFileIn =

cardano-cli/src/Cardano/CLI/Run.hs

@@ -80,7 +80,7 @@ renderClientCommandError = \case
   PingClientError err ->
     renderPingClientCmdError err
   DebugCmdError err ->
-    renderDebugCmdError err
+    prettyError err
 
 runDisplayVersion :: ExceptT ClientCommandErrors IO ()
 runDisplayVersion = do

cardano-cli/src/Cardano/CLI/Run/Debug.hs

@@ -4,22 +4,17 @@ module Cardano.CLI.Run.Debug
   ( DebugCmdError (..)
   , runLogEpochStateCmd
   , runDebugCmds
-  , renderDebugCmdError
   )
 where
 
+import           Cardano.Api
+
 import           Cardano.CLI.Commands.Debug
 import           Cardano.CLI.Run.Debug.LogEpochState
-
-import           Control.Monad.IO.Class
-import           Control.Monad.Trans.Except
-import           Prettyprinter
-
-data DebugCmdError = DebugCmdFailed
+import           Cardano.CLI.Run.Debug.TransactionView (runTransactionViewCmd)
+import           Cardano.CLI.Types.Errors.DebugCmdError
 
 runDebugCmds :: DebugCmds -> ExceptT DebugCmdError IO ()
 runDebugCmds = \case
   DebugLogEpochStateCmd cmd -> liftIO $ runLogEpochStateCmd cmd
-
-renderDebugCmdError :: DebugCmdError -> Doc ann
-renderDebugCmdError DebugCmdFailed = "Debug command failed"
+  DebugTransactionViewCmd cmd -> firstExceptT DebugTxCmdError $ runTransactionViewCmd cmd

cardano-cli/src/Cardano/CLI/Run/Debug/TransactionView.hs

@@ -0,0 +1,50 @@
+{-# LANGUAGE NamedFieldPuns #-}
+
+module Cardano.CLI.Run.Debug.TransactionView
+  ( runTransactionViewCmd
+  )
+where
+
+import           Cardano.Api
+
+import           Cardano.CLI.Commands.Debug.TransactionView
+import           Cardano.CLI.Json.Friendly (FriendlyFormat (..), friendlyTx, friendlyTxBody)
+import           Cardano.CLI.Read
+import           Cardano.CLI.Types.Common
+import           Cardano.CLI.Types.Errors.TxCmdError
+
+import           Data.Function ((&))
+
+runTransactionViewCmd
+  :: ()
+  => TransactionViewCmdArgs
+  -> ExceptT TxCmdError IO ()
+runTransactionViewCmd
+  TransactionViewCmdArgs
+    { outputFormat
+    , mOutFile
+    , inputTxBodyOrTxFile
+    } =
+    case inputTxBodyOrTxFile of
+      InputTxBodyFile (File txbodyFilePath) -> do
+        txbodyFile <- liftIO $ fileOrPipe txbodyFilePath
+        unwitnessed <-
+          firstExceptT TxCmdTextEnvCddlError . newExceptT $
+            readFileTxBody txbodyFile
+        InAnyShelleyBasedEra era txbody <- pure $ unIncompleteCddlTxBody unwitnessed
+        -- Why are we differentiating between a transaction body and a transaction?
+        -- In the case of a transaction body, we /could/ simply call @makeSignedTransaction []@
+        -- to get a transaction which would allow us to reuse friendlyTxBS. However,
+        -- this would mean that we'd have an empty list of witnesses mentioned in the output, which
+        -- is arguably not part of the transaction body.
+        firstExceptT TxCmdWriteFileError . newExceptT $
+          case outputFormat of
+            ViewOutputFormatYaml -> friendlyTxBody FriendlyYaml mOutFile (toCardanoEra era) txbody
+            ViewOutputFormatJson -> friendlyTxBody FriendlyJson mOutFile (toCardanoEra era) txbody
+      InputTxFile (File txFilePath) -> do
+        txFile <- liftIO $ fileOrPipe txFilePath
+        InAnyShelleyBasedEra era tx <- lift (readFileTx txFile) & onLeft (left . TxCmdTextEnvCddlError)
+        firstExceptT TxCmdWriteFileError . newExceptT $
+          case outputFormat of
+            ViewOutputFormatYaml -> friendlyTx FriendlyYaml mOutFile (toCardanoEra era) tx
+            ViewOutputFormatJson -> friendlyTx FriendlyJson mOutFile (toCardanoEra era) tx

cardano-cli/src/Cardano/CLI/Types/Errors/DebugCmdError.hs

@@ -0,0 +1,19 @@
+{-# LANGUAGE LambdaCase #-}
+
+module Cardano.CLI.Types.Errors.DebugCmdError
+  ( DebugCmdError (..)
+  )
+where
+
+import           Cardano.Api
+
+import           Cardano.CLI.Types.Errors.TxCmdError
+
+data DebugCmdError
+  = DebugCmdFailed
+  | DebugTxCmdError !TxCmdError
+
+instance Error DebugCmdError where
+  prettyError = \case
+    DebugCmdFailed -> "Debug command failed"
+    DebugTxCmdError err -> renderTxCmdError err