Add cmake build system

CMakeLists.txt

@@ -0,0 +1,117 @@
+cmake_minimum_required(VERSION 3.5)
+
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
+
+project(rrcc VERSION 0.8.2 LANGUAGES C CXX)
+
+include(GNUInstallDirs)
+
+# Find includes in corresponding build directories
+set(CMAKE_INCLUDE_CURRENT_DIR ON)
+# Instruct CMake to run moc automatically when needed
+set(CMAKE_AUTOMOC ON)
+# Create code from a list of Qt designer ui files
+#set(CMAKE_AUTOUIC ON)
+
+find_package(Qt5Core CONFIG REQUIRED)
+find_package(Qt5Widgets CONFIG REQUIRED)
+find_package(Qt5Network CONFIG REQUIRED)
+find_package(Qt5Concurrent CONFIG REQUIRED)
+find_package(Qt5LinguistTools CONFIG REQUIRED)
+
+find_package(libssh CONFIG REQUIRED)
+find_package(libarchive REQUIRED)
+
+# Checks for config.h
+include(ConfigureChecks.cmake)
+configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
+
+set(rrcc_SRCS
+    mainwindow.cpp
+    history.cpp
+    timer.cpp
+    setup.cpp
+    logger.cpp
+    upload.cpp
+    packager.cpp
+    unpackager.cpp
+    converter.cpp
+    about.cpp
+    zones.cpp
+    installer.cpp
+    uninstaller.cpp
+    update.cpp
+    download.cpp)
+
+set(qarchive_SRCS
+    ext/qarchive/qarchive.cpp)
+
+set(qaes_SRCS
+    ext/qaes/qaesencryption.cpp)
+
+set(qsshsocket_SRCS
+    ext/qsshsocket/qsshsocket.cpp)
+
+set(ccrypt_SRCS
+    ext/ccrypt/ccryptlib.c
+    ext/ccrypt/rijndael.c
+    ext/ccrypt/tables.c
+    ext/ccrypt/platform.c)
+
+qt5_wrap_ui(rrcc_FORMS
+    res/ui/about.ui
+    res/ui/converter.ui
+    res/ui/download.ui
+    res/ui/history.ui
+    res/ui/installer.ui
+    res/ui/logger.ui
+    res/ui/mainwindow.ui
+    res/ui/packager.ui
+    res/ui/setup.ui
+    res/ui/timer.ui
+    res/ui/uninstaller.ui
+    res/ui/unpackager.ui
+    res/ui/update.ui
+    res/ui/upload.ui
+    res/ui/zones.ui)
+
+qt5_add_resources(rrcc_RSCS
+    res/rrcc.qrc)
+
+add_executable(rrcc
+               ${rrcc_SRCS}
+               ${qarchive_SRCS}
+               ${qaes_SRCS}
+               ${qsshsocket_SRCS}
+               ${ccrypt_SRCS}
+               ${rrcc_FORMS}
+               ${rrcc_RSCS})
+
+target_include_directories(rrcc
+                           PRIVATE
+                               ext/ccrypt
+                               ext/qaes
+                               ext/qarchive
+                               ext/qsshsocket
+                               ${LIBSSH_INCLUDE_DIR}
+                               ${LIBARCHIVE_INCLUDE_DIR})
+
+target_link_libraries(rrcc
+    Qt5::Core
+    Qt5::Widgets
+    Qt5::Concurrent
+    Qt5::Network
+    ${LIBSSH_LIBRARIES}
+    ${LIBARCHIVE_LIBRARIES})
+
+install(TARGETS
+            rrcc
+        ARCHIVE DESTINATION
+            ${CMAKE_INSTALL_LIBDIR}
+        LIBRARY DESTINATION
+            ${CMAKE_INSTALL_LIBDIR}
+        RUNTIME DESTINATION
+            ${CMAKE_INSTALL_BINDIR}
+        COMPONENT ${PROJECT_NAME})
+
+add_subdirectory(res)

ConfigureChecks.cmake

@@ -0,0 +1,3 @@
+# in-tree and installation resource directories
+set(RRCC_INSOURCE_RESOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/res")
+set(RRCC_INSTALL_RESOURCE_DIR ${CMAKE_INSTALL_FULL_DATADIR}/resources)

cmake/Modules/Findlibarchive.cmake

@@ -0,0 +1,54 @@
+# - Try to find libarchive
+# Once done this will define
+#
+#  LIBARCHIVE_FOUND - system has libarchive
+#  LIBARCHIVE_INCLUDE_DIR - the libarchive include directory
+#  LIBARCHIVE_LIBRARIES - Link these to use libarchive
+#  LIBARCHIVE_DEFINITIONS - Compiler switches required for using libarchive
+#
+#=============================================================================
+#  Copyright (c) 2018 Andreas Schneider <[email protected]>
+#
+#  Distributed under the OSI-approved BSD License (the "License");
+#  see accompanying file Copyright.txt for details.
+#
+#  This software is distributed WITHOUT ANY WARRANTY; without even the
+#  implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+#  See the License for more information.
+#=============================================================================
+#
+
+if (UNIX)
+  find_package(PkgConfig)
+  if (PKG_CONFIG_FOUND)
+    pkg_check_modules(_LIBARCHIVE libarchive)
+  endif (PKG_CONFIG_FOUND)
+endif (UNIX)
+
+find_path(LIBARCHIVE_INCLUDE_DIR
+    NAMES
+        archive.h
+    PATHS
+        ${_LIBARCHIVE_INCLUDEDIR}
+)
+
+find_library(ARCHIVE_LIBRARY
+    NAMES
+        archive
+    PATHS
+        ${_LIBARCHIVE_LIBDIR}
+)
+
+if (ARCHIVE_LIBRARY)
+    set(LIBARCHIVE_LIBRARIES
+        ${LIBARCHIVE_LIBRARIES}
+        ${ARCHIVE_LIBRARY}
+    )
+endif (ARCHIVE_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(libarchive DEFAULT_MSG LIBARCHIVE_LIBRARIES LIBARCHIVE_INCLUDE_DIR)
+
+# show the LIBARCHIVE_INCLUDE_DIR and LIBARCHIVE_LIBRARIES variables only in the advanced view
+mark_as_advanced(LIBARCHIVE_INCLUDE_DIR LIBARCHIVE_LIBRARIES)
+

config.h.cmake

@@ -0,0 +1,2 @@
+#cmakedefine RRCC_INSOURCE_RESOURCE_DIR "${RRCC_INSOURCE_RESOURCE_DIR}"
+#cmakedefine RRCC_INSTALL_RESOURCE_DIR  "${RRCC_INSTALL_RESOURCE_DIR}"

mainwindow.cpp

@@ -1,4 +1,5 @@
 #include "mainwindow.h"
+#include "config.h"
 
 int main(int argc, char *argv[])
 {
@@ -17,15 +18,25 @@ MainWindow::MainWindow(QWidget *parent) : QMainWindow(parent)
 
 	if(!QLocale::system().name().startsWith("en_"))
 	{
-		if(appTranslator.load("rrcc_" + QLocale::system().name(), QApplication::applicationDirPath() + "/lng"))
+		QString resource_dir;
+
+		resource_dir = QString::fromUtf8(RRCC_INSOURCE_RESOURCE_DIR);
+		if (!QDir(resource_dir).exists()) {
+			resource_dir = QString::fromUtf8(RRCC_INSTALL_RESOURCE_DIR);
+			if (!QDir(resource_dir).exists()) {
+				resource_dir = QApplication::applicationDirPath();
+			}
+		}
+
+		if(appTranslator.load("rrcc_" + QLocale::system().name(), resource_dir + "/lang"))
 		{
 			QApplication::installTranslator(&appTranslator);
 
 			if(baseTranslator.load("qtbase_" + QLocale::system().name(), QLibraryInfo::location(QLibraryInfo::TranslationsPath)))
 			{
 				QApplication::installTranslator(&baseTranslator);
 			}
-			else if(baseTranslator.load("qtbase_" + QLocale::system().name(), QApplication::applicationDirPath() + "/lng"))
+			else if(baseTranslator.load("qtbase_" + QLocale::system().name(), resource_dir + "/lang"))
 			{
 				QApplication::installTranslator(&baseTranslator);
 			}
@@ -34,7 +45,7 @@ MainWindow::MainWindow(QWidget *parent) : QMainWindow(parent)
 			{
 				QApplication::installTranslator(&helpTranslator);
 			}
-			else if(helpTranslator.load("qt_help_" + QLocale::system().name(), QApplication::applicationDirPath() + "/lng"))
+			else if(helpTranslator.load("qt_help_" + QLocale::system().name(), resource_dir + "/lang"))
 			{
 				QApplication::installTranslator(&helpTranslator);
 			}

res/CMakeLists.txt

@@ -0,0 +1,2 @@
+add_subdirectory(ico)
+add_subdirectory(lang)

res/ico/CMakeLists.txt

@@ -0,0 +1,11 @@
+install(FILES
+            app.png
+        DESTINATION
+            ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/resources/icons)
+
+install(FILES
+            app.png
+        RENAME
+            ${PROJECT_NAME}.png
+        DESTINATION
+            ${CMAKE_INSTALL_DATADIR}/icons/hicolor/256x256/apps)

res/lang/CMakeLists.txt

@@ -0,0 +1,8 @@
+qt5_add_translation(rrcc_QM_FILES
+    rrcc_de.ts)
+add_custom_target(translations ALL DEPENDS ${rrcc_QM_FILES})
+
+install(FILES
+            ${rrcc_QM_FILES}
+        DESTINATION
+            ${CMAKE_INSTALL_DATADIR}/rrcc/resources/lang)

rrcc.pro

@@ -27,7 +27,7 @@ LIBS        += -lssh
 FORMS       += res/ui/mainwindow.ui res/ui/history.ui res/ui/timer.ui res/ui/setup.ui res/ui/logger.ui res/ui/upload.ui res/ui/packager.ui res/ui/unpackager.ui res/ui/converter.ui res/ui/about.ui res/ui/zones.ui res/ui/installer.ui res/ui/uninstaller.ui res/ui/update.ui res/ui/download.ui
 RESOURCES   += res/rrcc.qrc
 
-TRANSLATIONS+= lng/rrcc_de.ts
+TRANSLATIONS+= res/lang/rrcc_de.ts
 
 unix:!macx {
 QMAKE_LFLAGS+= -Wl,-rpath=.