add ghostty module

it could be removed when the module is backported to
nix-community/home-manager/release-24.11

modules/default.nix

@@ -1,5 +1,6 @@
 {
   imports = [
+    ./ghostty.nix
     ./kbdd.nix
     ./polybar-program.nix
     ./thermal-zone.nix

modules/ghostty.nix

@@ -0,0 +1,65 @@
+{
+  pkgs,
+  config,
+  inputs,
+  lib,
+  ...
+}:
+let
+  cfg = config.programs.ghostty;
+  keyValueSettings = {
+    listsAsDuplicateKeys = true;
+    mkKeyValue = lib.generators.mkKeyValueDefault { } " = ";
+  };
+  keyValue = pkgs.formats.keyValue keyValueSettings;
+in
+{
+  options.programs.ghostty = {
+    enable = lib.mkEnableOption "Enable ghostty";
+    package = lib.mkOption {
+      type = lib.types.package;
+      default =
+        let
+          ghosttyPkgs = builtins.getAttr pkgs.hostPlatform.system inputs.ghostty.packages;
+        in
+        ghosttyPkgs.ghostty;
+      defaultText = lib.literalExpression "pkgs.ghostty";
+      description = ''
+        Ghostty package to install.
+      '';
+    };
+    settings = lib.mkOption {
+      inherit (keyValue) type;
+      default =
+        let
+          inherit (config.stylix) fonts opacity;
+          inherit (config.lib.stylix) scheme;
+        in
+        {
+          font-family = [
+            fonts.monospace.name
+            fonts.emoji.name
+          ];
+          font-size = fonts.sizes.terminal;
+          background-opacity = opacity.terminal;
+          theme = scheme.slug;
+        };
+      example = lib.literalExpression ''
+        {
+          theme = "catppuccin-mocha";
+          font-size = 10;
+        }
+      '';
+      description = ''
+        Configuration written to {file}`$XDG_CONFIG_HOME/ghostty/config`.
+        See <https://ghostty.org/docs/config/reference> for more information.
+      '';
+    };
+  };
+  config = lib.mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+    xdg.configFile."ghostty/config" = lib.mkIf (cfg.settings != { }) {
+      source = keyValue.generate "ghostty-config" cfg.settings;
+    };
+  };
+}

profiles/gui/ghostty.nix

@@ -1,28 +1,24 @@
 {
-  pkgs,
   config,
-  inputs,
   lib,
   ...
 }:
 {
-  home.packages =
-    let
-      ghosttyPkgs = builtins.getAttr pkgs.hostPlatform.system inputs.ghostty.packages;
-    in
-    [ ghosttyPkgs.ghostty ];
-  xdg.configFile."ghostty/config".text =
-    let
-      inherit (config.stylix) fonts opacity;
-      inherit (config.lib.stylix) scheme;
-    in
-    ''
-      font-family = ${fonts.monospace.name}
-      font-family = ${fonts.emoji.name}
-      font-size = ${toString fonts.sizes.terminal}
-      background-opacity = ${toString opacity.terminal}
-      gtk-titlebar = false
-      window-decoration = false
-      theme = ${scheme.slug}
-    '';
+  programs.ghostty = {
+    enable = lib.mkDefault true;
+    settings =
+      let
+        inherit (config.stylix) fonts opacity;
+        inherit (config.lib.stylix) scheme;
+      in
+      {
+        font-family = [
+          fonts.monospace.name
+          fonts.emoji.name
+        ];
+        font-size = fonts.sizes.terminal;
+        background-opacity = opacity.terminal;
+        theme = scheme.slug;
+      };
+  };
 }

profiles/pc.nix

@@ -35,6 +35,8 @@
   home.sessionVariables = {
     BROWSER = "firefox";
   };
+  programs.ghostty.enable = true;
+
   stylix = {
     enable = true;
     targets.gtk.enable = false;

profiles/t14.nix

@@ -77,6 +77,12 @@
         };
       };
     };
+    ghostty = {
+      settings = {
+        gtk-titlebar = false;
+        window-decoration = false;
+      };
+    };
   };
   services.screen-locker = {
     # enable = true;

profiles/work-common.nix

@@ -268,6 +268,12 @@
           };
         };
     };
+    ghostty = {
+      settings = {
+        gtk-titlebar = false;
+        with-decoration = false;
+      };
+    };
     git.includes = [
       {
         condition = "gitdir:~/projektai/**";