Object Lookups / Assossication

[rawkode]

I was reading through #165 and it seems that what I'm trying to do may come later, but one comment caught my attention that made me think it was already possible. Given the following:

#Profile: {
  id: string
  first_name: "David" | "Brian"
  last_name:  string
  // cat_id:     categories[=~".*"]
  cat_id:     string
}

#Category: {
  id: string
  name: string
}

profiles: [string]: #Profile
categories: [string]: #Category

I was hoping that I could enforce a category to exist when a cat_id is provided.

Is this currently possible with 0.3.0?

[myitcv]

One way is to use or() with a comprehension.

package x

#Profile: {
	id:         string
	first_name: "David" | "Brian"
	last_name:  string
	// cat_id:     categories[=~".*"]
	cat_id: or([ for k, _ in categories {k}])
}

#Category: {
	id:   string
	name: string
}

profiles: [x=string]: #Profile & {
	id: x
}
categories: [x=string]: #Category & {
	id: x
}

profiles: p1: {
	first_name: "David"
	last_name:  "Bowie"
	cat_id:     "c1"
}

categories: c1: {
	name: "DevRel"
}

Note also that I've also assumed profiles and categories need to be keyed by their respective ids.

or() is really powerful because it allows you to "invert" the constraint your are looking to apply. Instead of saying "check that this value is valid", you instead say "this field can be any of these values". Comprehensions are in many respects, as you have observed, a very limited form of query.

[rawkode]

Thank you!

[cueckoo]

This discussion has been migrated to cue-lang/cue#875.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.