#203 Add netplan defines

manifests/netplan.pp

@@ -0,0 +1,48 @@
+# Define network::netplan
+#
+# Define to manage a netplan configuration file
+#
+define network::netplan (
+  String $config_file_name = "50-${title}-yaml",
+  Enum['present','absent'] $ensure = 'present',
+  String $renderer = 'networkd',
+  Numeric $version         = 2,
+
+  Stdlib::Absolutepath $config_dir_path  = '/etc/netplan',
+
+  Hash $ethernets          = {},
+  Hash $wifis              = {},
+  Hash $bridges            = {},
+  Hash $bonds              = {},
+  Hash $tunnels            = {},
+  Hash $vlans              = {},
+
+  Optional[String] $file_content                = undef,
+  Optional[String] $file_source                 = undef,
+
+) {
+
+  $netplan_data = {
+    'network' => {
+      'version'   => $version,
+      'renderer'  => $renderer,
+      'ethernets' => $ethernets,
+      'wifis'     => $wifis,
+      'bridges'   => $bridges,
+      'bonds'     => $bonds,
+      'tunnels'   => $tunnels,
+      'vlans'     => $vlans,
+    }
+  }
+
+  $real_file_content = $file_source ? {
+    undef   => pick($file_content,to_yaml($netplan_data)),
+    default => undef,
+  }
+
+  file { "${config_dir_path}/${config_file_name}":
+    ensure  => $ensure,
+    content => $real_file_content,
+    source  => $file_source,
+  }
+}

manifests/netplan/interface.pp

@@ -0,0 +1,75 @@
+# Define network::netplan::interface
+#
+# Define to manage an interface via netplan
+#
+define network::netplan::interface (
+  Enum['present','absent'] $ensure = 'present',
+
+  String $interface_name    = $title,
+  String $config_file_name  = "50-${title}-yaml",
+  String $interface_type    = 'ethernet',
+  Hash   $interface_options = {},
+
+  Stdlib::Absolutepath $config_dir_path = '/etc/netplan',
+
+  String $renderer = 'networkd',
+  Numeric $version = 2,
+
+  Boolean $dhcp4        = false,
+  Boolean $dhcp6        = false,
+
+  Optional[Stdlib::MAC]             $macaddress = undef,
+  Variant[Undef,Array]              $addresses  = undef,
+  Variant[Undef,Array]              $routes     = undef,
+  Optional[Stdlib::IP::Address::V4] $gateway4   = undef,
+  Optional[Stdlib::IP::Address::V6] $gateway6   = undef,
+  Optional[Array]        $nameservers_addresses = undef,
+  Optional[Array]           $nameservers_search = undef,
+
+  Optional[String] $file_content                = undef,
+  Optional[String] $file_source                 = undef,
+
+) {
+
+  $match_values = $macaddress ? {
+    undef => undef,
+    default => {
+      match => {
+        macaddress => $macaddress,
+      }
+    }
+  }
+
+  $default_values = {
+    dhcp4     => $dhcp4,
+    dhcp6     => $dhcp6,
+    addresses => $addresses,
+    gateway4  => $gateway4,
+    gateway6  => $gateway6,
+    nameservers => {
+      addresses => $nameservers_addresses,
+      search    => $nameservers_search,
+    },
+    routes    => $routes,
+  }
+
+  $netplan_data = {
+    'network' => {
+      'version'            => $version,
+      "${interface_type}s" => {
+        $interface_name => delete_undef_values($default_values + $match_values + $interface_options),
+      }
+    }
+  }
+
+  $real_file_content = $file_source ? {
+    undef   => pick($file_content,to_yaml($netplan_data)),
+    default => undef,
+  }
+  file { "${config_dir_path}/${config_file_name}":
+    ensure  => $ensure,
+    content => $real_file_content,
+    source  => $file_source,
+  }
+
+}

spec/defines/netplan/interface_spec.rb

@@ -0,0 +1,16 @@
+require 'spec_helper'
+
+describe 'network::netplan::interface' do
+  let(:title) { 'namevar' }
+  let(:params) do
+    {}
+  end
+
+  on_supported_os.each do |os, os_facts|
+    context "on #{os}" do
+      let(:facts) { os_facts }
+
+      it { is_expected.to compile }
+    end
+  end
+end

spec/defines/netplan_spec.rb

@@ -0,0 +1,16 @@
+require 'spec_helper'
+
+describe 'network::netplan' do
+  let(:title) { 'namevar' }
+  let(:params) do
+    {}
+  end
+
+  on_supported_os.each do |os, os_facts|
+    context "on #{os}" do
+      let(:facts) { os_facts }
+
+      it { is_expected.to compile }
+    end
+  end
+end