Add PacmanRules

lib/elixir_analyzer/constants.ex

@@ -21,7 +21,9 @@ defmodule ElixirAnalyzer.Constants do
     two_fer_wrong_specification: "elixir.two-fer.wrong_specification",
     two_fer_use_function_level_guard: "elixir.two_fer.use_function_level_guard",
     two_fer_use_of_aux_functions: "elixir.two_fer.use_of_aux_functions",
-    two_fer_use_of_function_header: "elixir.two_fer.use_of_function_header"
+    two_fer_use_of_function_header: "elixir.two_fer.use_of_function_header",
+    pacman_rules_use_strictly_boolean_operators:
+      "elixir.pacman_rules.use_strictly_boolean_operators"
   ]
 
   for {constant, markdown} <- @constants do

lib/elixir_analyzer/exercise_test/pacman_rules.ex

@@ -0,0 +1,40 @@
+defmodule ElixirAnalyzer.ExerciseTest.PacmanRules do
+  @dialyzer generated: true
+  @moduledoc """
+  This is an exercise analyzer extension module for the concept exercise Pacman Rules
+  """
+
+  alias ElixirAnalyzer.Constants
+
+  use ElixirAnalyzer.ExerciseTest
+
+  feature "requires using strictly boolean operators" do
+    find :none
+    on_fail :disapprove
+    comment Constants.pacman_rules_use_strictly_boolean_operators()
+
+    form do
+      _ignore && _ignore
+    end
+
+    form do
+      Kernel.&&(_ignore, _ignore)
+    end
+
+    form do
+      _ignore || _ignore
+    end
+
+    form do
+      Kernel.||(_ignore, _ignore)
+    end
+
+    form do
+      !_ignore
+    end
+
+    form do
+      Kernel.!(_ignore)
+    end
+  end
+end

test/elixir_analyzer/exercise_test/pacman_rules_test.exs

@@ -0,0 +1,104 @@
+defmodule ElixirAnalyzer.ExerciseTest.PacmanRulesTest do
+  use ElixirAnalyzer.ExerciseTestCase,
+    exercise_test_module: ElixirAnalyzer.ExerciseTest.PacmanRules
+
+  test_exercise_analysis "example solution",
+    comments: [],
+    status: :approve do
+    defmodule Rules do
+      def eat_ghost?(power_pellet_active, touching_ghost) do
+        power_pellet_active and touching_ghost
+      end
+
+      def score?(touching_power_pellet, touching_dot) do
+        touching_power_pellet or touching_dot
+      end
+
+      def lose?(power_pellet_active, touching_ghost) do
+        not power_pellet_active and touching_ghost
+      end
+
+      def win?(has_eaten_all_dots, power_pellet_active, touching_ghost) do
+        has_eaten_all_dots and not lose?(power_pellet_active, touching_ghost)
+      end
+    end
+  end
+
+  describe "requires strictly boolean operators" do
+    test_exercise_analysis "detects &&",
+      comments_include: [Constants.pacman_rules_use_strictly_boolean_operators()] do
+      [
+        defmodule Rules do
+          def eat_ghost?(power_pellet_active, touching_ghost) do
+            power_pellet_active && touching_ghost
+          end
+        end,
+        defmodule Rules do
+          def eat_ghost?(power_pellet_active, touching_ghost) do
+            power_pellet_active and touching_ghost
+          end
+
+          def lose?(power_pellet_active, touching_ghost) do
+            not power_pellet_active && touching_ghost
+          end
+        end,
+        defmodule Rules do
+          def eat_ghost?(power_pellet_active, touching_ghost) do
+            Kernel.&&(power_pellet_active, touching_ghost)
+          end
+        end
+      ]
+    end
+
+    test_exercise_analysis "detects ||",
+      comments_include: [Constants.pacman_rules_use_strictly_boolean_operators()] do
+      [
+        defmodule Rules do
+          def score?(touching_power_pellet, touching_dot) do
+            touching_power_pellet || touching_dot
+          end
+        end,
+        defmodule Rules do
+          def score?(touching_power_pellet, touching_dot) do
+            Kernel.||(touching_power_pellet, touching_dot)
+          end
+        end
+      ]
+    end
+
+    test_exercise_analysis "detects !",
+      comments_include: [Constants.pacman_rules_use_strictly_boolean_operators()] do
+      [
+        defmodule Rules do
+          def lose?(power_pellet_active, touching_ghost) do
+            !power_pellet_active and touching_ghost
+          end
+        end,
+        defmodule Rules do
+          def lose?(power_pellet_active, touching_ghost) do
+            touching_ghost and !power_pellet_active
+          end
+        end,
+        defmodule Rules do
+          def lose?(power_pellet_active, touching_ghost) do
+            not power_pellet_active and touching_ghost
+          end
+
+          def win?(has_eaten_all_dots, power_pellet_active, touching_ghost) do
+            has_eaten_all_dots and !lose?(power_pellet_active, touching_ghost)
+          end
+        end,
+        defmodule Rules do
+          def eat_ghost?(power_pellet_active, touching_ghost) do
+            !!power_pellet_active and !!touching_ghost
+          end
+        end,
+        defmodule Rules do
+          def lose?(power_pellet_active, touching_ghost) do
+            Kernel.!(power_pellet_active) and touching_ghost
+          end
+        end
+      ]
+    end
+  end
+end