kde-frameworks/purpose: 6.10.0 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

kde-frameworks/purpose/Manifest

@@ -0,0 +1 @@
+DIST purpose-6.10.0.tar.xz 188940 BLAKE2B a51200beca1dad78b164f276b1b4333455cc8af8f805fb9be4873789879e1f3edd2cbb69614ca4b192e036fa1bd4746bd7f4114e12cc1751e0877e4914dd6b6f SHA512 b6d847e4715a5779c10da92179db9d0a858c62582b729bcc25fc1d2e9796cfa634d4cb1cf49283c3d0364f96f97fc3420895ab4aad526920d65fcf2518e4b39f

kde-frameworks/purpose/purpose-6.10.0.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bluetooth webengine"
+
+# requires running environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	=kde-frameworks/kconfig-${KDE_CATV}*:6
+	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
+	=kde-frameworks/ki18n-${KDE_CATV}*:6
+	=kde-frameworks/kio-${KDE_CATV}*:6
+	=kde-frameworks/kirigami-${KDE_CATV}*:6
+	=kde-frameworks/knotifications-${KDE_CATV}*:6
+	=kde-frameworks/kservice-${KDE_CATV}*:6
+	=kde-frameworks/prison-${KDE_CATV}*:6
+	webengine? (
+		kde-apps/kaccounts-integration:6
+		>=net-libs/accounts-qt-1.17[qt6(+)]
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kdeclarative-${KDE_CATV}:6
+	bluetooth? ( =kde-frameworks/bluez-qt-${KDE_CATV}*:6 )
+	webengine? (
+		>=kde-frameworks/purpose-kaccounts-services-${KDE_CATV}
+		>=net-libs/accounts-qml-0.7_p20231028[qt6(+)]
+	)
+"
+BDEPEND="webengine? ( dev-util/intltool )"
+
+src_prepare() {
+	ecm_src_prepare
+
+	use bluetooth ||
+		cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package webengine KAccounts6)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	# Shipped by kde-frameworks/purpose-kaccounts-services package for shared use w/ SLOT 5
+	use webengine && ECM_REMOVE_FROM_INSTALL=(
+		/usr/share/accounts/services/kde/{google-youtube,nextcloud-upload}.service
+	)
+	ecm_src_install
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Send through KDE Connect" kde-misc/kdeconnect
+	fi
+	ecm_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}