eglot only displays the first line of the doc string provided by LSP server

[zino23]

• Server used: rust-analyzer

• Emacs version: GNU Emacs 29.1 (build 1, x86₆₄-apple-darwin22.1.0, Carbon Version 169 AppKit 2299) of 2024-02-05

• Operating system: Mac OS 13.7

• Eglot version: b014bca833a17f5b2258e88115f03cffa983d0bd

• Eglot installation method: eglot-upgrade-eglot

• Using Doom: No

• Relevant Emacs settings

  (setq eldoc-documentation-strategy 'eldoc-documentation-compose)
  (setq eldoc-echo-area-use-multiline-p 'truncate-sym-name-if-fit)
  (setq eldoc-documentation-functions 'eglot-hover-eldoc-function)
  

After upgrading eglot from 1.12 to 1.17, the doc string in echo area is incomplete for eglot-hover-eldoc-function backend.

For example, when hoverring on a variant of RustAnalyzerCmd, only the complete path to the enum rust_analyzer::cli::flags::RustAnalyzer is displayed:

Definition of RustAnalyzerCmd:

#[derive(Debug)]
pub enum RustAnalyzerCmd {
    LspServer(LspServer),
    Parse(Parse),
    Symbols(Symbols),
    Highlight(Highlight),
    AnalysisStats(AnalysisStats),
    RunTests(RunTests),
    RustcTests(RustcTests),
    Diagnostics(Diagnostics),
    UnresolvedReferences(UnresolvedReferences),
    Ssr(Ssr),
    Search(Search),
    Lsif(Lsif),
    Scip(Scip),
}

eldoc-box displays the complete documentation, including size hint and alignment. I am expecting to see all the info displayed by eldoc-box in the echo area by eglot.

I first checked if rust-analyzer responds with incomplete info. Turns out rust-analyzer is innocent.

[jsonrpc] e[20:41:28.501] <-- textDocument/hover[27]
(:jsonrpc "2.0" :id 27 :result
          (:contents
           (:kind "markdown" :value "\n```rust\nrust_analyzer::cli::flags::RustAnalyzerCmd\n```\n\n```rust\n// size = 56 (0x38), align = 0x8\nRustcTests(RustcTests)\n```")
           :range
           (:start
            (:line 92 :character 32)
            :end
            (:line 92 :character 42))))

So I figured it could be either eldoc or eglot that chooses to only show the first line.

After glimpsing through the eldoc package, especially functions like eldoc-documentation-compose, and variables like eldoc-documentation-function, plus some edebugging, it seems to me eldoc-hover-eldoc-function is called by eldoc-documentation-compose, where eldoc-hover-eldoc-function asynchronously calls the callback provided by eldoc-documentation-compose.

The interesting part is eldoc-hover-eldoc-function specifies the value to :echo as the first index of newline in info. Now the problem becomes what info is when the callback is invoked. Being a emacs-lisp beginner, I printed info to the *Message* buffer, and can verify info contains all the information rust-analyzer sends back. (I tried use edebug to see the value of info, but eglot--lambda is a macro, and edebugging a macro takes more work so I took the easy route. If you have better debugging technique, and would be so kind to inform me, please do :))

This is the modified version of eldoc-hover-eldoc-function

(defun eglot-hover-eldoc-function (cb)
  "A member of `eldoc-documentation-functions', for hover."
  (when (eglot-server-capable :hoverProvider)
    (let ((buf (current-buffer)))
      (jsonrpc-async-request
       (eglot--current-server-or-lose)
       :textDocument/hover (eglot--TextDocumentPositionParams)
       :success-fn (eglot--lambda ((Hover) contents range)
                     (eglot--when-buffer-window buf
                       (let ((info (unless (seq-empty-p contents)
                                     (eglot--hover-info contents range))))
                         (message "Check info: %s" info) ; <--- Added logging.
                         (funcall cb info
                                  :echo (and info (string-match "\n" info))))))
       :deferred :textDocument/hover))
    (eglot--highlight-piggyback cb)
    t))

After replacing :echo (and info (string-match "\n" info)) to :echo info, everything work as expected!

Now I am curious why the choice is made to only display the doc string until the first newline?

Finally, many thanks for your great package! I use it everyday, and I mean to study it to get more familiar with the LSP protocol, and maybe contribute to eglot someday :).

[joaotavora]

The echo area is a hotly contested small space. Maybe eldoc documentation functions live there, and eldoc will ask for the "oneliner" :echo property of each if it is present. So this is by design. If you're cool with a particular documentation function to be a fat space hog, the look at this discussion for a customization #1458

[joaotavora]

You should use something like this (taken from that discussion):

(defun my/special-eglot-hover-function (cb)
  "Same as `eglot-hover-eldoc-function`, but throw away its short :echo cookie"
  (eglot-hover-eldoc-function (lambda (info &rest _ignore)
                                ;; ignore the :echo cookie that eglot-hover-eldoc-function offers
                                (funcall cb info))))

(add-hook
 'eglot-managed-mode-hook
 (lambda ()
   (setq-local eldoc-documentation-functions 
               (cl-substitute #'my/special-eglot-hover-function
                              'eglot-hover-eldoc-function 
                              eldoc-documentation-functions)))

[joaotavora]

Of course, remove your customization of eldoc-documentation-functions for the above to work, or at least don't set it to a non-list (that's deprecated). Notice the plural "functions"

[zino23]

Thanks for your quick reply. I tried your suggesion and it works and is much cleaner than redefining the function.