[colmap] Add port for COLMAP 3.6

ports/colmap/portfile.cmake

@@ -0,0 +1,85 @@
+set(COLMAP_REF "3.6")
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO colmap/colmap
+    REF ${COLMAP_REF}
+    SHA512 9a4b4f2a49891ce8ac32ab1f2e9b859336326bada889e6de49c017a069884bb6c8ab8a2ae430d955e58fc22377c63e8fba9ce80ff959713e2878e29814d44632
+    HEAD_REF dev
+)
+
+# set GIT_COMMIT_ID and GIT_COMMIT_DATE
+if(DEFINED VCPKG_HEAD_VERSION)
+    set(GIT_COMMIT_ID "${VCPKG_HEAD_VERSION}")
+else()
+    set(GIT_COMMIT_ID "${COLMAP_REF}")
+endif()
+
+string(TIMESTAMP COLMAP_GIT_COMMIT_DATE "%Y-%m-%d")
+
+set(CUDA_ENABLED OFF)
+set(TESTS_ENABLED OFF)
+
+if("cuda" IN_LIST FEATURES)
+    set(CUDA_ENABLED ON)
+endif()
+
+if("cuda-redist" IN_LIST FEATURES)
+    set(CUDA_ENABLED ON)
+    set(CUDA_ARCHS "Common")
+endif()
+
+if("tests" IN_LIST FEATURES)
+    set(TESTS_ENABLED ON)
+endif()
+
+vcpkg_configure_cmake(
+    SOURCE_PATH ${SOURCE_PATH}
+    PREFER_NINJA
+    OPTIONS
+        -DCUDA_ENABLED=${CUDA_ENABLED}
+        -DCUDA_ARCHS=${CUDA_ARCHS}
+        -DTESTS_ENABLED=${TESTS_ENABLED}
+        -DGIT_COMMIT_ID=${GIT_COMMIT_ID}
+        -DGIT_COMMIT_DATE=${COLMAP_GIT_COMMIT_DATE}
+)
+
+vcpkg_install_cmake()
+
+vcpkg_fixup_cmake_targets()
+
+file(GLOB TOOL_FILENAMES "${CURRENT_PACKAGES_DIR}/bin/*")
+foreach(TOOL_FILENAME ${TOOL_FILENAMES})
+    get_filename_component(TEST_TOOL_NAME ${TOOL_FILENAME} NAME_WLE)
+    list(APPEND COLMAP_TOOL_NAMES "${TEST_TOOL_NAME}")
+endforeach()
+
+vcpkg_copy_tools(TOOL_NAMES ${COLMAP_TOOL_NAMES} AUTO_CLEAN)
+
+# remove empty folders and unused files
+file(REMOVE_RECURSE
+    ${CURRENT_PACKAGES_DIR}/debug/include
+    ${CURRENT_PACKAGES_DIR}/debug/share
+    ${CURRENT_PACKAGES_DIR}/debug/include/colmap/exe
+    ${CURRENT_PACKAGES_DIR}/debug/include/colmap/lib/Graclus/multilevelLib
+    ${CURRENT_PACKAGES_DIR}/debug/include/colmap/tools
+    ${CURRENT_PACKAGES_DIR}/debug/include/colmap/ui/media
+    ${CURRENT_PACKAGES_DIR}/debug/include/colmap/ui/shaders
+    ${CURRENT_PACKAGES_DIR}/include/colmap/exe
+    ${CURRENT_PACKAGES_DIR}/include/colmap/lib/Graclus/multilevelLib
+    ${CURRENT_PACKAGES_DIR}/include/colmap/tools
+    ${CURRENT_PACKAGES_DIR}/include/colmap/ui/media
+    ${CURRENT_PACKAGES_DIR}/include/colmap/ui/shaders
+    ${CURRENT_PACKAGES_DIR}/COLMAP.bat
+    ${CURRENT_PACKAGES_DIR}/RUN_TESTS.bat
+    ${CURRENT_PACKAGES_DIR}/debug/COLMAP.bat
+    ${CURRENT_PACKAGES_DIR}/debug/RUN_TESTS.bat
+    ${CURRENT_PACKAGES_DIR}/debug/bin
+)
+
+vcpkg_copy_pdbs()
+
+file(INSTALL     ${SOURCE_PATH}/COPYING.txt
+     DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT}
+     RENAME copyright
+)

ports/colmap/usage

@@ -0,0 +1,10 @@
+For example, under Windows, execute COLMAP as:
+
+    <VCPKG-ROOT>\packages\colmap_<TRIPLET>\tools\colmap\colmap.exe gui
+    <VCPKG-ROOT>\packages\colmap_<TRIPLET>\tools\colmap\colmap.exe mapper
+    <VCPKG-ROOT>\packages\colmap_<TRIPLET>\tools\colmap\colmap.exe ...
+
+The package colmap provides CMake integration:
+
+    find_package(COLMAP REQUIRED)
+    target_link_libraries(main ${COLMAP_LIBRARIES})

ports/colmap/vcpkg.json

@@ -0,0 +1,55 @@
+{
+  "name": "colmap",
+  "version-string": "3.6",
+  "description": "COLMAP is a general-purpose Structure-from-Motion (SfM) and Multi-View Stereo (MVS) pipeline with a graphical and command-line interface. It offers a wide range of features for reconstruction of ordered and unordered image collections. The software is licensed under the new BSD license.",
+  "license": "BSD-3-Clause",
+  "homepage": "https://colmap.github.io/",
+  "dependencies": [
+    "boost-program-options",
+    "boost-filesystem",
+    "boost-graph",
+    "boost-regex",
+    "boost-system",
+    "boost-test",
+    "eigen3",
+    "suitesparse",
+    "freeimage",
+    "glog",
+    "gflags",
+    "glew",
+    "qt5-base",
+    {
+      "name": "ceres",
+      "features": [
+        "suitesparse",
+        "lapack"
+      ]
+    },
+    {
+      "name": "cgal",
+      "features": [
+        "qt"
+      ]
+    }
+  ],
+  "features": [
+    {
+      "name": "cuda",
+      "dependencies": [
+        "cuda"
+      ],
+      "description": "CUDA support for current compute architecture of this machine."
+    },
+    {
+      "name": "cuda-redist",
+      "dependencies": [
+        "cuda"
+      ],
+      "description": "Redistributable CUDA support for common supported compute architectures."
+    },
+    {
+      "name": "tests",
+      "description": "Enable TESTS."
+    }
+  ]
+}