flakify & other amenities

.envrc

@@ -0,0 +1,17 @@
+#! /bin/sh
+
+# reload when these files change
+watch_file flake.nix
+watch_file flake.lock
+
+{
+  # shell gc root dir
+  mkdir -p "$(direnv_layout_dir)"
+  eval "$(
+    nix print-dev-env . \
+      --no-update-lock-file \
+      --no-write-lock-file \
+      --profile $(direnv_layout_dir)/flake-profile
+  )"
+} || use nix
+

.gitignore

@@ -3,3 +3,6 @@
 
 # nix-build symlinks
 /result
+
+# direnv
+.direnv

Cargo.toml

@@ -4,9 +4,7 @@ version = "0.1.0"
 edition = "2021"
 
 [workspace]
-exclude = [
-  "recordaccess",
-]
+exclude = ["recordaccess"]
 
 [[bin]]
 name = "nix-eval-cache"
@@ -17,3 +15,4 @@ tempfile = "3.3.0"
 nix = "0.23.1"
 blake2 = "0.10.4"
 hex = "0.4.3"
+lazy_static = "1.4.0"

default.nix

@@ -1,10 +1,11 @@
-with import <nixpkgs> {};
-mkShell {
-  nativeBuildInputs = [
-    bashInteractive
-    rustc
-    cargo
-    cargo-watch
-    rust-analyzer
-  ];
-}
+let
+  lockData = builtins.readFile ./flake.lock;
+  lock = builtins.fromJSON lockData;
+  flakeCompat = lock.nodes.flakeCompat.locked;
+  flakeCompatSrc = builtins.fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${flakeCompat.rev}.tar.gz";
+    sha256 = flakeCompat.narHash;
+  };
+  flake = import flakeCompatSrc {src = ./.;};
+in
+  flake.defaultNix

flake.nix

@@ -0,0 +1,134 @@
+{
+  description = "The More Aggressive Nix Eval Cache";
+
+  inputs = {
+    flakeCompat.url = github:edolstra/flake-compat;
+    flakeCompat.flake = false;
+
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+  };
+
+  outputs = inputs: let
+    commit = inputs.self.shortRev or "dirty";
+    date = inputs.self.lastModifiedDate or inputs.self.lastModified or "19700101";
+    version = "1.2.0+${builtins.substring 0 8 date}.${commit}";
+
+    nixpkgsForHost = host:
+      import inputs.nixpkgs {
+        overlays = [
+          (self: super: {
+            nix-eval-cache = self.rustPlatform.buildRustPackage {
+              pname = "nix-eval-cache";
+              inherit version;
+              src = ./.;
+              cargoLock.lockFile = ./Cargo.lock;
+
+              passthru.tests = {
+                version = self.testVersion {package = super.nix-eval-cache;};
+              };
+
+              meta = {
+                description = "The More Aggressive Nix Eval Cache.";
+                homepage = "https://github.com/numtide/nix-eval-cache";
+                license = self.lib.licenses.mit;
+                maintainers = [self.lib.maintainers.mic92];
+                platforms = self.lib.systems.doubles.all;
+              };
+            };
+          })
+        ];
+        system = host;
+      };
+
+    # nixpkgs."aarch64-darwin" = nixpkgsForHost "aarch64-darwin";
+    nixpkgs."aarch64-linux" = nixpkgsForHost "aarch64-linux";
+    nixpkgs."i686-linux" = nixpkgsForHost "i686-linux";
+    # nixpkgs."x86_64-darwin" = nixpkgsForHost "x86_64-darwin";
+    nixpkgs."x86_64-linux" = nixpkgsForHost "x86_64-linux";
+
+    buildBinariesForHost = host: pkgs: let
+      binaries = builtins.listToAttrs (
+        builtins.map (pkg: {
+          name = "nix-eval-cache-${pkg.stdenv.targetPlatform.config}";
+          value = pkg;
+        })
+        pkgs
+      );
+    in
+      binaries
+      // {
+        "nix-eval-cache-binaries" = nixpkgs.${host}.linkFarm "nix-eval-cache-binaries" (
+          nixpkgs.${host}.lib.mapAttrsToList
+          (name: binary: {
+            inherit name;
+            path = "${binary}/bin/nix-eval-cache";
+          })
+          binaries
+        );
+        "default" = builtins.elemAt pkgs 0;
+      };
+  in rec {
+    # checks."aarch64-darwin" = packages."aarch64-darwin";
+    checks."aarch64-linux" = packages."aarch64-linux";
+    checks."i686-linux" = packages."i686-linux";
+    # checks."x86_64-darwin" = packages."x86_64-darwin";
+    checks."x86_64-linux" = packages."x86_64-linux";
+
+    # defaultPackage."aarch64-darwin" = packages."aarch64-darwin"."nix-eval-cache-aarch64-apple-darwin";
+    defaultPackage."aarch64-linux" = packages."aarch64-linux"."nix-eval-cache-aarch64-unknown-linux-gnu";
+    defaultPackage."i686-linux" = packages."i686-linux"."nix-eval-cache-i686-unknown-linux-gnu";
+    # defaultPackage."x86_64-darwin" = packages."x86_64-darwin"."nix-eval-cache-x86_64-apple-darwin";
+    defaultPackage."x86_64-linux" = packages."x86_64-linux"."nix-eval-cache-x86_64-unknown-linux-gnu";
+
+    devShell."x86_64-linux" = with nixpkgs."x86_64-linux";
+      mkShell {
+        name = "nix-eval-cache";
+        packages = [
+          cargo
+          cargo-bloat
+          cargo-license
+          cargo-tarpaulin
+          cargo-watch
+          rust-analyzer
+          clippy
+          alejandra
+          nodejs
+          nodePackages.prettier
+          nodePackages.prettier-plugin-toml
+          rustc
+          shfmt
+          treefmt
+        ];
+      };
+
+    # packages."aarch64-darwin" = with nixpkgs."aarch64-darwin";
+    #   buildBinariesForHost "aarch64-darwin" [
+    #     nix-eval-cache
+    #   ];
+    packages."aarch64-linux" = with nixpkgs."aarch64-linux";
+      buildBinariesForHost "aarch64-linux" [
+        nix-eval-cache
+        pkgsStatic.nix-eval-cache
+      ];
+    packages."i686-linux" = with nixpkgs."i686-linux";
+      buildBinariesForHost "i686-linux" [
+        nix-eval-cache
+      ];
+    # packages."x86_64-darwin" = with nixpkgs."x86_64-darwin";
+    #   buildBinariesForHost "x86_64-darwin" [
+    #     nix-eval-cache
+    #   ];
+    packages."x86_64-linux" = with nixpkgs."x86_64-linux"; (buildBinariesForHost "x86_64-linux" [
+      nix-eval-cache
+      pkgsStatic.nix-eval-cache
+
+      pkgsCross.aarch64-multiplatform.pkgsStatic.nix-eval-cache
+
+      pkgsCross.armv7l-hf-multiplatform.pkgsStatic.nix-eval-cache
+
+      pkgsCross.gnu32.pkgsStatic.nix-eval-cache
+
+      pkgsCross.raspberryPi.pkgsStatic.nix-eval-cache
+    ]);
+  };
+}

recordaccess/Cargo.toml

@@ -1,7 +1,7 @@
 [package]
 name = "recordaccess"
 version = "0.0.1"
-authors = [ "Jörg Thalheim <[email protected]>" ]
+authors = ["Jörg Thalheim <[email protected]>"]
 edition = "2021"
 
 [lib]

rustfmt.toml

@@ -0,0 +1,18 @@
+edition = "2021"
+enum_discrim_align_threshold = 999
+format_code_in_doc_comments = true
+format_generated_files = true
+format_macro_bodies = true
+format_macro_matchers = true
+format_strings = true
+hex_literal_case = "Lower"
+imports_granularity = "Item"
+imports_layout = "Vertical"
+max_width = 80
+normalize_comments = true
+normalize_doc_attributes = true
+reorder_impl_items = true
+struct_field_align_threshold = 999
+unstable_features = true
+use_small_heuristics = "Max"
+version = "Two"

shell.nix

@@ -0,0 +1,11 @@
+let
+  lockData = builtins.readFile ./flake.lock;
+  lock = builtins.fromJSON lockData;
+  flakeCompat = lock.nodes.flakeCompat.locked;
+  flakeCompatSrc = builtins.fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${flakeCompat.rev}.tar.gz";
+    sha256 = flakeCompat.narHash;
+  };
+  flake = import flakeCompatSrc {src = ./.;};
+in
+  flake.shellNix

treefmt.toml

@@ -0,0 +1,19 @@
+[formatter]
+
+[formatter.nix]
+command = "alejandra"
+includes = ["*.nix"]
+
+[formatter.prettier]
+command = "prettier"
+includes = ["*.html", "*.js", "*.json", "*.md", "*.toml", "*.yaml"]
+options = ["--plugin", "prettier-plugin-toml", "--write"]
+
+[formatter.rust]
+command = "rustfmt"
+includes = ["*.rs"]
+
+[formatter.shell]
+command = "shfmt"
+includes = ["*.sh"]
+options = ["-bn", "-ci", "-sr", "-i", "2", "-s", "-w"]